Co-authored-by: Crystalic <BlackCrystalic@users.noreply.github.com>

Author: fineks

code/controllers/subsystem/topic.dm

@@ -0,0 +1,49 @@
+GLOBAL_LIST_EMPTY(topic_tokens)
+GLOBAL_PROTECT(topic_tokens)
+
+GLOBAL_LIST_EMPTY(topic_commands)
+GLOBAL_PROTECT(topic_commands)
+
+SUBSYSTEM_DEF(topic)
+	name = "Topic"
+	init_stage = INITSTAGE_FIRST
+	flags = SS_NO_FIRE
+
+/datum/controller/subsystem/topic/Initialize(timeofday)
+	// Initialize topic datums
+	var/list/anonymous_functions = list()
+	for(var/path in subtypesof(/datum/world_topic))
+		var/datum/world_topic/T = new path()
+		if(T.anonymous)
+			anonymous_functions[T.key] = TRUE
+		GLOB.topic_commands[T.key] = T
+
+	// Setup the anonymous access token
+	GLOB.topic_tokens["anonymous"] = anonymous_functions
+	// Parse and setup authed tokens from config
+	var/list/tokens = CONFIG_GET(keyed_list/topic_tokens)
+	for(var/token in tokens)
+		var/list/keys = list()
+		if(tokens[token] == "all")
+			for(var/key in GLOB.topic_commands)
+				keys[key] = TRUE
+		else
+			for(var/key in splittext(tokens[token], ","))
+				keys[trim(key)] = TRUE
+			// Grant access to anonymous topic calls (version, authed functions etc.) by default
+			keys |= anonymous_functions
+		GLOB.topic_tokens[token] = keys
+
+	return ..()
+
+/datum/config_entry/number/topic_max_size
+	config_entry_value = 5000
+	protection = CONFIG_ENTRY_HIDDEN|CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/keyed_list/topic_tokens
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_TEXT
+	protection = CONFIG_ENTRY_HIDDEN|CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/keyed_list/topic_tokens/ValidateListEntry(key_name, key_value)
+	return key_value != "topic_token" && ..()

code/datums/world_topic.dm

@@ -1,5 +1,5 @@
 // SETUP
-
+/* OLD
 /proc/TopicHandlers()
 	. = list()
 	var/list/all_handlers = subtypesof(/datum/world_topic)
@@ -316,3 +316,240 @@
 
 	message_admins(span_adminnotice("Incoming cross-sector newscaster article by [author_key] in channel [channel_name]."))
 	GLOB.news_network.submit_article(msg, author, channel_name)
+*/
+
+
+
+
+
+/datum/world_topic
+	/// query key
+	var/key
+
+	/// can be used with anonymous authentication
+	var/anonymous = FALSE
+
+	var/list/required_params = list()
+	var/statuscode
+	var/response
+	var/data
+
+/datum/world_topic/proc/CheckParams(list/params)
+	var/list/missing_params = list()
+	var/errorcount = 0
+
+	for(var/param in required_params)
+		if(!params[param])
+			errorcount++
+			missing_params += param
+
+	if(errorcount)
+		statuscode = 400
+		response = "Bad Request - Missing parameters"
+		data = missing_params
+		return errorcount
+
+/datum/world_topic/proc/Run(list/input)
+	// Always returns true; actual details in statuscode, response and data variables
+	return TRUE
+
+// API INFO TOPICS
+
+/datum/world_topic/api_get_authed_functions
+	key = "api_get_authed_functions"
+	anonymous = TRUE
+
+/datum/world_topic/api_get_authed_functions/Run(list/input)
+	. = ..()
+	var/list/functions = GLOB.topic_tokens[input["auth"]]
+	if(functions)
+		statuscode = 200
+		response = "Authorized functions retrieved"
+		data = functions
+	else
+		statuscode = 401
+		response = "Unauthorized - No functions found"
+		data = null
+
+// TOPICS
+
+// If you modify the protocol for this, update tools/Tgstation.PRAnnouncer
+/datum/world_topic/pr_announce
+	key = "announce"
+	anonymous = TRUE
+	var/static/list/PRcounts = list() //PR id -> number of times announced this round
+
+/datum/world_topic/pr_announce/Run(list/input)
+	. = ..()
+	var/list/payload = json_decode(input["payload"])
+	var/id = "[payload["pull_request"]["id"]]"
+	if(!PRcounts[id])
+		PRcounts[id] = 1
+	else
+		++PRcounts[id]
+		if(PRcounts[id] > CONFIG_GET(number/pr_announcements_per_round))
+			return
+
+	var/final_composed = span_announce("PR: [input[key]]")
+	for(var/client/C in GLOB.clients)
+		C.AnnouncePR(final_composed)
+
+	statuscode = 200
+	response = "Received"
+
+/datum/world_topic/ping
+	key = "ping"
+	anonymous = TRUE
+
+/datum/world_topic/ping/Run(list/input)
+	. = ..()
+	statuscode = 200
+	response = "Pong!"
+	data = length(GLOB.clients)
+
+/datum/world_topic/status
+	key = "status"
+	anonymous = TRUE
+
+/datum/world_topic/status/Run(list/input)
+	. = ..()
+
+	data = list()
+
+	data["version"] = GLOB.game_version
+	data["respawn"] = config ? !!CONFIG_GET(flag/allow_respawn) : FALSE // show respawn as true regardless of "respawn as char" or "free respawn"
+	data["enter"] = !LAZYACCESS(SSlag_switch.measures, DISABLE_NON_OBSJOBS)
+	data["ai"] = CONFIG_GET(flag/allow_ai)
+	data["host"] = world.host ? world.host : null
+
+	data["round_id"] = GLOB.round_id
+
+	data["map_name"] = SSmapping.current_map?.map_name || "Loading..."
+
+	data["players"] = length(GLOB.clients)
+
+	data["identifier"] = CONFIG_GET(string/serversqlname)
+
+
+	var/public_address = CONFIG_GET(string/public_address)
+	if(public_address)
+		data["public_address"] = public_address
+
+	data["revision"] = GLOB.revdata.commit
+	data["revision_date"] = GLOB.revdata.date
+	data["hub"] = GLOB.hub_visibility
+
+	data["security_level"] = SSsecurity_level.get_current_level_as_text()
+	data["round_duration"] = SSticker ? round((world.time-SSticker.round_start_time)/10) : 0
+
+	//Time dilation stats.
+	data["time_dilation_current"] = SStime_track.time_dilation_current
+	data["time_dilation_avg"] = SStime_track.time_dilation_avg
+	data["time_dilation_avg_slow"] = SStime_track.time_dilation_avg_slow
+	data["time_dilation_avg_fast"] = SStime_track.time_dilation_avg_fast
+
+	data["soft_popcap"] = CONFIG_GET(number/soft_popcap) || 0
+	data["hard_popcap"] = CONFIG_GET(number/hard_popcap) || 0
+	data["extreme_popcap"] = CONFIG_GET(number/extreme_popcap) || 0
+	data["popcap"] = max(CONFIG_GET(number/soft_popcap), CONFIG_GET(number/hard_popcap), CONFIG_GET(number/extreme_popcap)) //generalized field for this concept for use across ss13 codebases
+	data["bunkered"] = CONFIG_GET(flag/panic_bunker) || FALSE
+	data["interviews"] = CONFIG_GET(flag/panic_bunker_interview) || FALSE
+	if(SSshuttle?.emergency)
+		data["shuttle_mode"] = SSshuttle.emergency.mode
+		// Shuttle status, see /__DEFINES/stat.dm
+		data["shuttle_timer"] = SSshuttle.emergency.timeLeft()
+		// Shuttle timer, in seconds
+
+	statuscode = 200
+	response = "Status retrieved"
+
+/datum/world_topic/status/authed
+	key = "status_authed"
+	anonymous = FALSE
+
+/datum/world_topic/status/authed/Run(list/input)
+	. = ..()
+
+	var/list/adm = get_admin_counts()
+	var/list/presentmins = adm["present"]
+	var/list/afkmins = adm["afk"]
+	data["admins"] = length(presentmins) + length(afkmins)
+	data["gamestate"] = SSticker.current_state
+
+	data["active_players"] = get_active_player_count()
+
+	data["mcpu"] = world.map_cpu
+	data["cpu"] = world.cpu
+
+GLOBAL_LIST_EMPTY(bot_event_sending_que)
+GLOBAL_LIST_EMPTY(bot_ooc_sending_que)
+GLOBAL_LIST_EMPTY(bot_asay_sending_que)
+
+/datum/world_topic/receive_info
+	key = "receive_info"
+
+/datum/world_topic/receive_info/Run(list/input)
+	data = list()
+	if(!length(GLOB.bot_event_sending_que) && !length(GLOB.bot_ooc_sending_que) && !length(GLOB.bot_asay_sending_que))
+		statuscode = 501
+		response = "No events pool."
+		return
+
+	//Yeah, we can use /datum/http_request, but nuh... it's less fun.
+	data["events"] = GLOB.bot_event_sending_que
+	data["ooc"] = GLOB.bot_ooc_sending_que
+	data["admin"] = GLOB.bot_asay_sending_que
+	GLOB.bot_event_sending_que = list()
+	GLOB.bot_ooc_sending_que = list()
+	GLOB.bot_asay_sending_que = list()
+	statuscode = 200
+	response = "Events sent."
+
+/datum/world_topic/send_info
+	key = "send_info"
+	required_params = list("data")
+
+/datum/world_topic/send_info/Run(list/input)
+	data = list()
+
+	var/list/bot_data = input["data"]
+	if(!istype(bot_data) || !length(bot_data))
+		statuscode = 403
+		response = "Wrong data"
+		return
+
+	if(bot_data["ooc"])
+		for(var/list/data in bot_data["ooc"])
+			var/msg = sanitize(data["message"])
+			for(var/client/C in GLOB.clients)
+				if(C.prefs.chat_toggles & CHAT_OOC)
+					to_chat(C, "<span class='ooc'><span class='prefix'>DISCORD OOC:</span> <EM>[data["author"]]:</EM> <span class='message linkify'>[msg]</span></span>")
+
+	if(bot_data["admin"])
+		for(var/list/data in bot_data["admin"])
+			to_chat(GLOB.admins, "<span class='adminsay'><span class='prefix'>DISCORD ADMIN:</span> <EM>[data["author"]]</EM>: <span class='message linkify'>[sanitize(data["message"])]</span></span>", confidential = TRUE)
+
+	statuscode = 200
+	response = "Events received."
+
+/datum/world_topic/delay
+	key = "set_delay"
+	required_params = list("delay")
+
+/datum/world_topic/delay/Run(list/input)
+	. = ..()
+
+	if(SSticker.timeLeft < 0 && input["delay"])
+		statuscode = 501
+		response = "Delay already set to same state."
+		return
+
+	SSticker.timeLeft = input["delay"] ? -1 : 300
+	message_admins(span_notice("[input["source"]] ([input["addr"]]) [SSticker.timeLeft < 0 ? "delayed the round start" : "has made the round start normally"]."))
+	to_chat(world, span_notice("The game start has been [SSticker.timeLeft < 0 ? "delayed" : "continued"]."))
+	if(SSticker.timeLeft < 0)
+		statuscode = 200
+		response = "Delay set."
+	else
+		statuscode = 200
+		response = "Delay removed."

code/game/world.dm

@@ -250,6 +250,7 @@ GLOBAL_VAR(restart_counter)
 		world.log = file("[GLOB.log_directory]/dd.log") //not all runtimes trigger world/Error, so this is the only way to ensure we can see all of them.
 #endif
 
+/* bot backdoor
 /world/Topic(T, addr, master, key)
 	TGS_TOPIC //redirect to server tools if necessary
 
@@ -270,6 +271,74 @@ GLOBAL_VAR(restart_counter)
 
 	handler = new handler()
 	return handler.TryRun(input)
+*/
+//REPLACED
+/world/Topic(T, addr, master, key)
+	TGS_TOPIC	//redirect to server tools if necessary
+
+	var/list/response = list()
+
+	if(length(T) > CONFIG_GET(number/topic_max_size))
+		response["statuscode"] = 413
+		response["response"] = "Payload too large"
+		return json_encode(response)
+
+	var/logging = CONFIG_GET(flag/log_world_topic)
+	var/topic_decoded = rustg_url_decode(T)
+	if(!rustg_json_is_valid(topic_decoded))
+		if(logging)
+			log_topic("(NON-JSON) \"[topic_decoded]\", from:[addr], master:[master], key:[key]")
+		// Fallback check for spacestation13.com requests
+		if(topic_decoded == "status")
+			return list2params(list("players" = length(GLOB.clients)))
+		response["statuscode"] = 400
+		response["response"] = "Bad Request - Invalid JSON format"
+		return json_encode(response)
+
+	var/list/params = json_decode(topic_decoded)
+	params["addr"] = addr
+	var/query = params["query"]
+	var/auth = params["auth"]
+	var/source = params["source"]
+
+	if(logging)
+		var/list/censored_params = params.Copy()
+		censored_params["auth"] = "***[copytext(params["auth"], -4)]"
+		log_topic("\"[json_encode(censored_params)]\", from:[addr], master:[master], auth:[censored_params["auth"]], key:[key], source:[source]")
+
+	if(!source)
+		response["statuscode"] = 400
+		response["response"] = "Bad Request - No source specified"
+		return json_encode(response)
+
+	if(!query)
+		response["statuscode"] = 400
+		response["response"] = "Bad Request - No endpoint specified"
+		return json_encode(response)
+
+	if(!LAZYACCESS(GLOB.topic_tokens["[auth]"], "[query]"))
+		response["statuscode"] = 401
+		response["response"] = "Unauthorized - Bad auth"
+		return json_encode(response)
+
+	var/datum/world_topic/command = GLOB.topic_commands["[query]"]
+	if(!command)
+		response["statuscode"] = 501
+		response["response"] = "Not Implemented"
+		return json_encode(response)
+
+	if(command.CheckParams(params))
+		response["statuscode"] = command.statuscode
+		response["response"] = command.response
+		response["data"] = command.data
+		return json_encode(response)
+	else
+		command.Run(params)
+		response["statuscode"] = command.statuscode
+		response["response"] = command.response
+		response["data"] = command.data
+		return json_encode(response)
+//YOUR MOM
 
 /world/proc/AnnouncePR(announcement, list/payload)
 	var/static/list/PRcounts = list() //PR id -> number of times announced this round

code/modules/admin/verbs/adminsay.dm

@@ -18,6 +18,7 @@ ADMIN_VERB(cmd_admin_say, R_NONE, "ASay", "Send a message to other admins", ADMI
 
 	user.mob.log_talk(message, LOG_ASAY)
 	message = keywords_lookup(message)
+	GLOB.bot_asay_sending_que += list(list("author" = user.ckey, "message" = message, "rank" = join_admin_ranks(user.holder.ranks)))
 	var/asay_color = user.prefs.read_preference(/datum/preference/color/asay_color)
 	var/custom_asay_color = (CONFIG_GET(flag/allow_admin_asaycolor) && asay_color) ? "<font color=[asay_color]>" : "<font color='[DEFAULT_ASAY_COLOR]'>"
 	message = "[span_adminsay("[span_prefix("ADMIN:")] <EM>[key_name_admin(user)]</EM> [ADMIN_FLW(user.mob)]: [custom_asay_color]<span class='message linkify'>[message]")]</span>[custom_asay_color ? "</font>":null]"

code/modules/client/verbs/ooc.dm

@@ -56,6 +56,8 @@ GLOBAL_VAR_INIT(normal_ooc_colour, "#002eb8")
 	if(!msg)
 		return
 
+	GLOB.bot_ooc_sending_que += list(list("author" = holder && holder.fakekey ? holder.fakekey : key, "message" = msg))
+
 	msg = emoji_parse(msg)
 
 	if(SSticker.HasRoundStarted() && ((msg[1] in list(".",";",":","#")) || findtext_char(msg, "say", 1, 5)))