Update the Terraform sample with SSL certificate example

[BzSpi]

Hello,

The Terraform sample does not include the SSL Certificate configuration.
Can you please add it since it's not trivial ?

Terraform sample file: https://github.com/Azure/AML-Kubernetes/blob/master/files/terraform-template.tf

Thanks

[BzSpi]

Here's the code for a private integration with latest Kubernetes version

data "azurerm_kubernetes_cluster" "aks" {
  name                = "{cluster-name}"
  resource_group_name = "{resource-group}"
}

data "azurerm_key_vault_certificate_data" "certificate" {
  key_vault_id = "{key-vault-id}"
  name         = "{certificate-name}"
}

resource "azurerm_kubernetes_cluster_extension" "machine_learning" {
  name           = "{extension-name}"
  cluster_id     = data.azurerm_kubernetes_cluster.aks.id
  extension_type = "Microsoft.AzureML.Kubernetes"

  release_namespace = "azureml" # Fixed value, do not change

  configuration_settings = {
    enableTraining                                          = true
    enableInference                                         = true
    inferenceRouterServiceType                              = "loadBalancer"
    allowInsecureConnections                                = false
    "scoringFe.serviceType.internalLoadBalancer"            = true
    privateEndpointILB                                      = true
    sslCname                                                = "{endpoint.contoso.com}"
    "servicebus.enabled"                                    = false
    "relayserver.enabled"                                   = false
    "nginxIngress.enabled"                                  = true
    cluster_name                                            = data.azurerm_kubernetes_cluster.aks.id
    domain                                                  = "${data.azurerm_kubernetes_cluster.aks.location}.cloudapp.azure.com"
    location                                                = data.azurerm_kubernetes_cluster.aks.location
    jobSchedulerLocation                                    = data.azurerm_kubernetes_cluster.aks.location
    cluster_name_friendly                                   = data.azurerm_kubernetes_cluster.aks.name
    clusterId                                               = data.azurerm_kubernetes_cluster.aks.id
    "prometheus.prometheusSpec.externalLabels.cluster_name" = data.azurerm_kubernetes_cluster.aks.id
  }
  configuration_protected_settings = {
    "scoringFe.sslKey"  = base64encode(data.azurerm_key_vault_certificate_data.certificate.key)
    "scoringFe.sslCert" = base64encode(data.azurerm_key_vault_certificate_data.certificate.pem)
  }
}