Advanced-Recipe-Generator-Mod/build.gradle at master · Flow86/Advanced-Recipe-Generator-Mod · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'
apply plugin: 'java'

sourceCompatibility = JavaVersion.VERSION_1_6
targetCompatibility = JavaVersion.VERSION_1_6

///////////////////////////////////////////////////////////////////////////////

group = 'com.github.flow86'
ext.baseversion = '0.0.4'
archivesBaseName = 'advancedrecipegenerator'

minecraft {
    version = "1.7.2-10.12.1.1112"
}

///////////////////////////////////////////////////////////////////////////////

// set java compiler options to display warnings
tasks.withType(Compile) {
    options.compilerArgs << "-Xlint:unchecked"
}

// display files which get compiled
compileJava {
    options.listFiles = true
}

///////////////////////////////////////////////////////////////////////////////

// add build number to version
def env = System.getenv()
ext.buildnumber = ( env['BUILD_NUMBER'] ? env['BUILD_NUMBER'] : "custom" )

version=ext.baseversion + "-" + ext.buildnumber

logger.lifecycle "Building Advanced Recipe Generator " + ext.baseversion + "-" + ext.buildnumber + " for MC-Forge " + project.minecraft.apiVersion

// generate property file for jenkins
if(env['BUILD_NUMBER']) {
    ant.propertyfile(file:"jenkins.properties", comment:'Build Properties') {
        ant.entry(key:'version',value:version)
        ant.entry(key:'mc.version',value:project.minecraft.version)
        ant.entry(key:'forge.version',value:project.minecraft.apiVersion)
    }
}

///////////////////////////////////////////////////////////////////////////////

// change version etc in source file, this was a bit complicated
def filteredSourceDir = file("${buildDir}/filtered/java")

sourceSets {
    filtered {
        java {
            srcDirs = [ filteredSourceDir ]
        }
    }
}

// copy the main sources and filter any '$version' occurences.
task processVersion (type: Copy) {
    from sourceSets.main.java
    into filteredSourceDir

    expand 'version'       : project.ext.baseversion,
           'buildnumber'   : project.ext.buildnumber,
           'mc_version'    : project.minecraft.version,
           'mc_apiversion' : project.minecraft.apiVersion
}

// we have to change input of "sourceMainJava" here to use changed source dir
afterEvaluate {
    sourceMainJava {
        dependsOn processVersion
        source = sourceSets.filtered.java
    }
}

///////////////////////////////////////////////////////////////////////////////

// copy resource files
processResources {
    exclude "**/*.psd", "**/*.bak"

    // text resources which getting filtered
    from(sourceSets.main.resources.srcDirs) {
        include '**/*.lang'
        include '**/*.info'
        include '**/*.properties'

        expand 'version'       : project.ext.baseversion,
               'buildnumber'   : project.ext.buildnumber,
               'mc_version'    : project.minecraft.version,
               'mc_apiversion' : project.minecraft.apiVersion
    }

    // binary resources
    from(sourceSets.main.resources.srcDirs) {
        exclude '**/*.lang'
        exclude '**/*.info'
        exclude '**/*.properties'
    }
}

jar {
    appendix = 'universal'

    manifest {
        attributes 'MCVersion' : project.minecraft.version
        attributes 'Version'   : project.version
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    appendix = 'deobf'

    manifest {
        attributes 'MCVersion' : project.minecraft.version
        attributes 'Version'   : project.version
    }
}

artifacts {
    archives deobfJar
}