Ident/flake.nix at main · Ident-1090/Ident · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
{
  description = "Ident ADS-B receiver display development shell";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];
      forAllSystems = nixpkgs.lib.genAttrs systems;
      pkgsFor = system: import nixpkgs { inherit system; };
      toolsFor =
        pkgs:
        let
          goPkg = pkgs.go_1_26 or pkgs.go;
          nodePkg = pkgs.nodejs_24 or pkgs.nodejs;
          pnpmPkg = pkgs.pnpm_10 or pkgs.pnpm;
        in
        {
          inherit goPkg nodePkg pnpmPkg;
          common = [
            goPkg
            nodePkg
            pnpmPkg
            pkgs.git
            pkgs.nfpm
            pkgs.ripgrep
            pkgs.rsync
          ];
        };
    in
    {
      devShells = forAllSystems (
        system:
        let
          pkgs = pkgsFor system;
          tools = toolsFor pkgs;
        in
        {
          default = pkgs.mkShell {
            packages = tools.common;
            shellHook = ''
              export HUSKY=0
              echo "Ident dev shell: Go $(${tools.goPkg}/bin/go version | awk '{print $3}'), Node $(${tools.nodePkg}/bin/node --version)"
            '';
          };
        }
      );

      apps = forAllSystems (
        system:
        let
          pkgs = pkgsFor system;
          tools = toolsFor pkgs;
          buildIdentd = pkgs.writeShellApplication {
            name = "build-identd";
            runtimeInputs = tools.common;
            text = ''
              exec ./scripts/build-identd.sh "$@"
            '';
          };
          packageIdentd = pkgs.writeShellApplication {
            name = "package-identd";
            runtimeInputs = tools.common;
            text = ''
              exec ./scripts/package-identd.sh "$@"
            '';
          };
        in
        {
          build-identd = {
            type = "app";
            program = "${buildIdentd}/bin/build-identd";
          };
          package-identd = {
            type = "app";
            program = "${packageIdentd}/bin/package-identd";
          };
        }
      );
    };
}