build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version "${springBootVersion}" apply false
    id 'io.spring.dependency-management' version "${springDependencyManagementVersion}" apply false
    id 'com.diffplug.spotless' version "${spotlessVersion}" apply false
    id 'com.google.cloud.tools.jib' version '3.5.3' apply false
}

group = projectGroup
version = "${projectVersion}-SNAPSHOT"
description = 'yogieat'

// Common configuration for all subprojects
subprojects {
    // Apply java-library plugin for library modules, java plugin for application modules
    if (project.path.startsWith(':apps:api')
            || project.path.startsWith(':apps:admin')
            || project.path.startsWith(':batch:sync')) {
        apply plugin: 'java'
    } else {
        apply plugin: 'java-library'
    }

    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'com.diffplug.spotless'

    group = rootProject.group
    version = rootProject.version

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(25)
        }
    }

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    repositories {
        mavenCentral()
    }

    // Common dependencies for ALL modules
    dependencies {
        // Lombok for all modules
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        // Testing for all modules
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

        // Configuration processor for @ConfigurationProperties
        annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
    }

    // Dependency management - Spring Boot BOM
    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
        }
    }

    // Spotless configuration for all subprojects
    spotless {
        java {
            target("**/*.java")
            targetExclude("**/generated/**", "**/build/generated/**")
            importOrder()
            removeUnusedImports()
            trimTrailingWhitespace()
            endWithNewline()
        }

        sql {
            target 'src/**/*.sql'
            targetExclude 'src/main/resources/db/migration/**/*.sql'
            dbeaver()
        }

        format 'misc', {
            target '*.md', '.gitignore', '*.yml', '*.yaml'
            trimTrailingWhitespace()
            endWithNewline()
        }
    }

    // Default: disable bootJar for all subprojects (enabled only in application modules)
    tasks.named('bootJar') {
        enabled = false
    }

    // Enable plain jar for libraries
    tasks.named('jar') {
        enabled = true
    }

    tasks.named('test') {
        useJUnitPlatform()
    }
}

// Git Hook installation at root level
tasks.register('installGitHook', Copy) {
    def hooksDir = layout.projectDirectory.dir('.git/hooks')
    from layout.projectDirectory.file('scripts/pre-commit')
    into hooksDir
    doFirst {
        hooksDir.asFile.mkdirs()
    }
}

// Apply git hook on build
allprojects {
    tasks.matching { it.name == 'build' }.configureEach {
        dependsOn rootProject.tasks.installGitHook
    }
}

def deployableModules = [
        ':apps:api',
        ':apps:admin',
        ':batch:sync'
]

tasks.register('validateJibPushEnv') {
    doLast {
        def requiredEnvNames = [
                'API_IMAGE_FULL_URL',
                'ADMIN_IMAGE_FULL_URL',
                'BATCH_IMAGE_FULL_URL',
                'DOCKERHUB_USERNAME',
                'DOCKERHUB_TOKEN'
        ]
        def missingEnvNames = requiredEnvNames.findAll { !System.getenv(it) }

        if (!missingEnvNames.isEmpty()) {
            throw new GradleException("Missing Jib push environment variables: ${missingEnvNames.join(', ')}")
        }
    }
}

tasks.register('jibPushAll') {
    group = 'container'
    description = 'Builds and pushes API, Admin, and Batch images with Jib.'
    dependsOn tasks.named('validateJibPushEnv')
    dependsOn deployableModules.collect { "${it}:jib" }
}

tasks.register('jibDockerBuildAll') {
    group = 'container'
    description = 'Builds API, Admin, and Batch images into the local Docker daemon with Jib.'
    dependsOn deployableModules.collect { "${it}:jibDockerBuild" }
}