libAPG/meson.build at main · NurOS-Linux/libAPG · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
# NurOS Ruzen42 2025
project('libapg', 'c',
  version: '1.1.0'
)

libapg_sources = files(
  'src/package.c',
  'src/util.c',
  'src/archive.c',
  'src/checksum/crc32.c',
  'src/checksum/md5.c',
  'src/checksum/sha256.c',
  'src/checksum/checksum.c',
  'src/install/copy.c',
  'src/install/install.c',
  'src/install/rollback.c',
  'src/install/scripts.c',
  'src/db/db.c',
  'src/db/write.c',
  'src/db/read.c',
  'src/db/journal.c',
  'src/json.c',
  'src/graph/graph.c',
  'src/graph/resolve.c',
  'src/graph/conflict.c',
)

add_project_arguments('-D_GNU_SOURCE', language: 'c')

libapg_inc = include_directories('include')

cc = meson.get_compiler('c')
cpu = host_machine.cpu_family()

# Architecture-specific ASM: SHA-256 (hardware crypto), CRC-32 and MD5 (optimized scalar).
# Assembled via Clang IAS: .S files compiled with -masm=intel on x86_64.
hw_args = []
if cpu == 'x86_64'
  libapg_sources += files(
    'arch/x86_64/sha256.S',
    'arch/x86_64/crc32.S',
    'arch/x86_64/md5.S',
  )
  hw_args = [
    '-DAPG_SHA256_HW_AVAILABLE=1',
    '-DAPG_CRC32_HW_AVAILABLE=1',
    '-DAPG_MD5_HW_AVAILABLE=1',
    '-msha', '-msse4.1', '-masm=intel',
  ]
elif cpu == 'aarch64'
  libapg_sources += files(
    'arch/aarch64/sha256.S',
    'arch/aarch64/crc32.S',
    'arch/aarch64/md5.S',
  )
  hw_args = [
    '-DAPG_SHA256_HW_AVAILABLE=1',
    '-DAPG_CRC32_HW_AVAILABLE=1',
    '-DAPG_MD5_HW_AVAILABLE=1',
    '-march=armv8-a+crypto+crc',
  ]
elif cpu == 'riscv64'
  libapg_sources += files(
    'arch/riscv64/sha256.S',
    'arch/riscv64/crc32.S',
    'arch/riscv64/md5.S',
  )
  hw_args = [
    '-DAPG_SHA256_HW_AVAILABLE=1',
    '-DAPG_CRC32_HW_AVAILABLE=1',
    '-DAPG_MD5_HW_AVAILABLE=1',
    '-march=rv64gc_zknh',
  ]
endif

if hw_args.length() > 0
  add_project_arguments(hw_args, language: 'c')
endif

threads_dep = dependency('threads')

libarchive_dep = dependency('libarchive', required: false)
lmdb_dep = dependency('lmdb', required: false)
libyyjson_dep = dependency('yyjson', required: false)
gpgme_dep = dependency('gpgme', required: false)
sodium_dep = dependency('libsodium', required: false)

if not libarchive_dep.found()
  libarchive_dep = cc.find_library('archive', required: true)
endif

if not lmdb_dep.found()
  lmdb_dep = cc.find_library('lmdb', required: true)
endif

if not libyyjson_dep.found()
  libyyjson_dep = cc.find_library('yyjson', required: true)
endif

sign_dep = []
if gpgme_dep.found()
  libapg_sources += files('src/sign/pgp/pgp.c')
  sign_dep = [gpgme_dep]
elif sodium_dep.found()
  libapg_sources += files('src/sign/sodium/sodium.c')
  sign_dep = [sodium_dep]
else
  error('Either gpgme or libsodium is required for package signing')
endif

libapg = library('apg', libapg_sources,
  include_directories: libapg_inc,
  dependencies: [
    libarchive_dep,
    lmdb_dep,
    libyyjson_dep,
    threads_dep,
  ] + sign_dep,
  install: true,
)

libapg_dep = declare_dependency(
  link_with: libapg,
  include_directories: libapg_inc,
)

pkg = import('pkgconfig')
pkg.generate(libapg)

subdir('test')