forked from OSVVM/OSVVM
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathDelayCoveragePkg.vhd
846 lines (763 loc) · 42.4 KB
/
DelayCoveragePkg.vhd
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
--
-- File Name: DelayCoveragePkg.vhd
-- Design Unit Name: DelayCoveragePkg
-- Revision: STANDARD VERSION
--
-- Maintainer: Jim Lewis email: [email protected]
-- Contributor(s):
-- Jim Lewis SynthWorks
--
--
-- Description:
-- Implements a pattern for randomizing cycle based delays such as AXI's Valid and Ready
--
--
-- Developed for:
-- SynthWorks Design Inc.
-- VHDL Training Classes
-- 11898 SW 128th Ave. Tigard, Or 97223
-- http://www.SynthWorks.com
--
-- Revision History:
-- Date Version Description
-- 11/2024 2024.11 Added SetBurstLength. SetDelayCoverage randomizes BurstLength if RandomSalt is set.
-- 07/2024 2024.07 Added IsInitialized
-- 05/2023 2023.05 Initial revision.
--
--
-- This file is part of OSVVM.
--
-- Copyright (c) 2024 by SynthWorks Design Inc.
--
-- Licensed under the Apache License, Version 2.0 (the "License");
-- you may not use this file except in compliance with the License.
-- You may obtain a copy of the License at
--
-- https://www.apache.org/licenses/LICENSE-2.0
--
-- Unless required by applicable law or agreed to in writing, software
-- distributed under the License is distributed on an "AS IS" BASIS,
-- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-- See the License for the specific language governing permissions and
-- limitations under the License.
--
use std.textio.all ;
use work.IfElsePkg.all ;
use work.TextUtilPkg.all ;
use work.TbUtilPkg.all ;
use work.ResolutionPkg.all ;
use work.AlertLogPkg.all ;
use work.CoveragePkg.all ;
use work.NameStorePkg.all ;
use work.OsvvmScriptSettingsPkg.all ;
use work.RandomBasePkg.all ;
package DelayCoveragePkg is
type DelayCoverageIDType is record
ID : integer_max ;
BurstLengthCov : CoverageIDType ;
BurstDelayCov : CoverageIDType ;
BeatDelayCov : CoverageIDType ;
end record DelayCoverageIDType ;
type DelayCoverageIDArrayType is array (integer range <>) of DelayCoverageIDType ;
constant DELAYCOVERAGE_ID_UNINITIALZED : DelayCoverageIDType := (ID => integer'left, others => COVERAGE_ID_UNINITIALZED) ;
------------------------------------------------------------
--- ///////////////////////////////////////////////////////////////////////////
------------------------------------------------------------
-- DelayCoverageIDType Overloading
------------------------------------------------------------
impure function NewID (
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType ;
------------------------------------------------------------
impure function NewDelayCoverage (
ID : Integer ;
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType ;
------------------------------------------------------------
impure function IsInitialized (ID : DelayCoverageIDType) return boolean ;
------------------------------------------------------------
impure function GetDelayCoverage(ID : integer) return DelayCoverageIDType ;
procedure SetDelayCoverage ( ID : DelayCoverageIDType ) ;
procedure SetBurstLength ( ID : DelayCoverageIDType ; BurstLength : integer ) ;
impure function GetBurstLength ( ID : DelayCoverageIDType ) return integer ;
------------------------------------------------------------
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer ;
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer_vector ;
------------------------------------------------------------
procedure DeallocateBins ( ID : DelayCoverageIDType ) ;
------------------------------------------------------------
--- ///////////////////////////////////////////////////////////////////////////
------------------------------------------------------------
------------------------------------------------------------
-- The following items currently in ALPHA development mode
-- They may be part of a future implementation, but they also may be removed.
-- They were anticipated as needed for Axi4 VC, but an alternate path was used.
-- They were removed for the official release.
------------------------------------------------------------
--! -- DelayCoverageIDArrayType Overloading
--! ------------------------------------------------------------
--! -- experimental
--! impure function NewID (
--! Name : string ;
--! Size : positive ;
--! ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
--! Name1 : string := "" ;
--! Name2 : string := "" ;
--! Name3 : string := "" ;
--! Name4 : string := "" ;
--! Name5 : string := "" ;
--! Name6 : string := "" ;
--! Name7 : string := "" ;
--! Name8 : string := "" ;
--! Name9 : string := "" ;
--! Name10 : string := "" ;
--! ReportMode : AlertLogReportModeType := DISABLED ;
--! Search : NameSearchType := PRIVATE_NAME ;
--! PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
--! ) return DelayCoverageIDArrayType ;
--!
--! ------------------------------------------------------------
--! -- experimental
--! impure function NewDelayCoverage (
--! ID : Integer ; -- Starting ID, and the ID's are consecutive
--! Name : String ;
--! Size : positive ;
--! ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
--! Name1 : string := "" ;
--! Name2 : string := "" ;
--! Name3 : string := "" ;
--! Name4 : string := "" ;
--! Name5 : string := "" ;
--! Name6 : string := "" ;
--! Name7 : string := "" ;
--! Name8 : string := "" ;
--! Name9 : string := "" ;
--! Name10 : string := "" ;
--! ReportMode : AlertLogReportModeType := DISABLED ;
--! Search : NameSearchType := PRIVATE_NAME ;
--! PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
--! ) return DelayCoverageIDArrayType ;
--!
--! -- experimental, Removed during dev as it assumes the IDs are consecutive - which they may or may not be.
--! -- impure function GetDelayCoverage(ID : integer; Size : positive ) return DelayCoverageIDArrayType ;
--! -- experimental
--! procedure SetDelayCoverage ( ID : DelayCoverageIDArrayType ) ;
--!
--! ------------------------------------------------------------
--! procedure DeallocateBins ( ID : DelayCoverageIDArrayType ) ;
-- Backward compatible with Beta Dev names
subtype BurstCoverageIDType is DelayCoverageIDType ;
subtype BurstCoverageIDArrayType is DelayCoverageIDArrayType ;
alias NewBurstCoverage is NewDelayCoverage [
Integer, String, AlertLogIDType, AlertLogReportModeType, NameSearchType, AlertLogPrintParentType return DelayCoverageIDType] ;
alias GetBurstCoverage is GetDelayCoverage[integer return DelayCoverageIDType] ;
alias SetBurstCoverage is SetDelayCoverage[DelayCoverageIDType] ;
alias GetRandBurstDelay is GetRandDelay [DelayCoverageIDType return integer] ;
alias GetRandBurstDelay is GetRandDelay [DelayCoverageIDType return integer_vector] ;
end package DelayCoveragePkg ;
--- ///////////////////////////////////////////////////////////////////////////
--- ///////////////////////////////////////////////////////////////////////////
--- ///////////////////////////////////////////////////////////////////////////
package body DelayCoveragePkg is
type DelayCoveragePType is protected
------------------------------------------------------------
--- ///////////////////////////////////////////////////////////////////////////
------------------------------------------------------------
-- DelayCoverageIDType Overloading
------------------------------------------------------------
impure function NewID (
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType ;
------------------------------------------------------------
impure function NewDelayCoverage (
ID : Integer ;
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType ;
------------------------------------------------------------
impure function IsInitialized (ID : DelayCoverageIDType) return boolean ;
impure function GetDelayCoverage(ID : integer) return DelayCoverageIDType ;
procedure SetDelayCoverage ( ID : DelayCoverageIDType ) ;
procedure SetBurstLength ( ID : DelayCoverageIDType ; BurstLength : integer ) ;
impure function GetBurstLength ( ID : DelayCoverageIDType ) return integer ;
------------------------------------------------------------
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer ;
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer_vector ;
------------------------------------------------------------
procedure DeallocateBins ( ID : DelayCoverageIDType ) ;
------------------------------------------------------------
--- ///////////////////////////////////////////////////////////////////////////
------------------------------------------------------------
-- DelayCoverageIDArrayType Overloading
------------------------------------------------------------
impure function NewID (
Name : string ;
Size : positive ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
Name1 : string := "" ;
Name2 : string := "" ;
Name3 : string := "" ;
Name4 : string := "" ;
Name5 : string := "" ;
Name6 : string := "" ;
Name7 : string := "" ;
Name8 : string := "" ;
Name9 : string := "" ;
Name10 : string := "" ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDArrayType ;
------------------------------------------------------------
impure function NewDelayCoverage (
ID : Integer ; -- Starting ID, and the ID's are consecutive
Name : String ;
Size : positive ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
Name1 : string := "" ;
Name2 : string := "" ;
Name3 : string := "" ;
Name4 : string := "" ;
Name5 : string := "" ;
Name6 : string := "" ;
Name7 : string := "" ;
Name8 : string := "" ;
Name9 : string := "" ;
Name10 : string := "" ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDArrayType ;
impure function GetDelayCoverage(ID : integer; Size : positive ) return DelayCoverageIDArrayType ;
procedure SetDelayCoverage ( ID : DelayCoverageIDArrayType ) ;
------------------------------------------------------------
procedure DeallocateBins ( ID : DelayCoverageIDArrayType ) ;
end protected DelayCoveragePType ;
type DelayCoveragePType is protected body
type SingletonStructType is record
BurstLengthCov : CoverageIDType ;
BurstDelayCov : CoverageIDType ;
BeatDelayCov : CoverageIDType ;
BurstLength : integer ;
end record SingletonStructType ;
type SingletonArrayType is array (integer range <>) of SingletonStructType ;
type SingletonArrayPtrType is access SingletonArrayType ;
variable SingletonArrayPtr : SingletonArrayPtrType ;
variable NumItems : integer := 0 ;
constant MIN_NUM_ITEMS : integer := 32 ; -- Min amount to resize array
variable LocalNameStore : NameStorePType ;
------------------------------------------------------------
-- Package Local
function NormalizeArraySize( NewNumItems, MinNumItems : integer ) return integer is
------------------------------------------------------------
variable NormNumItems : integer ;
variable ModNumItems : integer ;
begin
NormNumItems := NewNumItems ;
ModNumItems := NewNumItems mod MinNumItems ;
if ModNumItems > 0 then
NormNumItems := NormNumItems + (MinNumItems - ModNumItems) ;
end if ;
return NormNumItems ;
end function NormalizeArraySize ;
------------------------------------------------------------
-- Package Local
procedure GrowNumberItems (
------------------------------------------------------------
variable SingletonArrayPtr : InOut SingletonArrayPtrType ;
variable NumItems : InOut integer ;
constant GrowAmount : in integer ;
constant MinNumItems : in integer
) is
variable oldSingletonArrayPtr : SingletonArrayPtrType ;
variable NewNumItems : integer ;
variable NewSize : integer ;
begin
NewNumItems := NumItems + GrowAmount ;
NewSize := NormalizeArraySize(NewNumItems, MinNumItems) ;
if SingletonArrayPtr = NULL then
SingletonArrayPtr := new SingletonArrayType(1 to NewSize) ;
elsif NewNumItems > SingletonArrayPtr'length then
oldSingletonArrayPtr := SingletonArrayPtr ;
SingletonArrayPtr := new SingletonArrayType(1 to NewSize) ;
SingletonArrayPtr.all(1 to NumItems) := oldSingletonArrayPtr.all(1 to NumItems) ;
deallocate(oldSingletonArrayPtr) ;
end if ;
NumItems := NewNumItems ;
end procedure GrowNumberItems ;
-- ------------------------------------------------------------
-- -- PT Local
-- impure function NewDelayCoverage (
-- ------------------------------------------------------------
-- ID : Integer ;
-- Name : String ;
-- ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
-- ReportMode : AlertLogReportModeType := DISABLED ;
-- Search : NameSearchType := PRIVATE_NAME ;
-- PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
-- ) return DelayCoverageIDType is
-- variable NewCoverageID : DelayCoverageIDType ;
-- begin
-- SingletonArrayPtr(ID).BurstLengthCov := NewID(Name & ifelse(Name'length > 0, " ", "") & "BurstLength", ParentID, ReportMode, Search, PrintParent) ;
-- SingletonArrayPtr(ID).BurstDelayCov := NewID(Name & ifelse(Name'length > 0, " ", "") & "BurstDelay", ParentID, ReportMode, Search, PrintParent) ;
-- SingletonArrayPtr(ID).BeatDelayCov := NewID(Name & ifelse(Name'length > 0, " ", "") & "BeatDelay", ParentID, ReportMode, Search, PrintParent) ;
-- SingletonArrayPtr(ID).BurstLength := 0 ;
-- return GetDelayCoverage( ID ) ;
-- end function NewDelayCoverage ;
------------------------------------------------------------
------------------------------------------------------------
-- DelayCoverageIDType Overloading
------------------------------------------------------------
impure function NewID (
------------------------------------------------------------
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType is
variable NameID : integer ;
variable ResolvedSearch : NameSearchType ;
variable ResolvedPrintParent : AlertLogPrintParentType ;
variable NewCoverageID : DelayCoverageIDType ;
begin
ResolvedSearch := ResolveSearch (ParentID /= OSVVM_COVERAGE_ALERTLOG_ID, Search) ;
ResolvedPrintParent := ResolvePrintParent(ParentID /= OSVVM_COVERAGE_ALERTLOG_ID, PrintParent) ;
NameID := LocalNameStore.find(Name, ParentID, ResolvedSearch) ;
if NameID /= ID_NOT_FOUND.ID then
-- Get the current existing information
return GetDelayCoverage( NameID ) ;
else
-- Add New Coverage Model to Structure
GrowNumberItems(SingletonArrayPtr, NumItems, 1, MIN_NUM_ITEMS) ;
-- Add item to NameStore
NameID := LocalNameStore.NewID(Name, ParentID, ResolvedSearch) ;
AlertIfNotEqual(ParentID, NameID, NumItems, "DelayCoveragePkg: in " & Name & ", Index of LocalNameStore /= CoverageID") ;
NewCoverageID := NewDelayCoverage( NumItems, Name, ParentID, ReportMode, ResolvedSearch, ResolvedPrintParent ) ;
SetDelayCoverage(NewCoverageID) ;
return NewCoverageID ;
-- return NewDelayCoverage( NumItems, Name, ParentID, ReportMode, ResolveSearch, ResolvedPrintParent ) ;
end if ;
end function NewID ;
------------------------------------------------------------
impure function NewDelayCoverage (
------------------------------------------------------------
ID : Integer ;
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType is
variable ResolvedSearch : NameSearchType ;
variable ResolvedPrintParent : AlertLogPrintParentType ;
variable NewCoverageID : DelayCoverageIDType ;
begin
ResolvedSearch := ResolveSearch (ParentID /= OSVVM_COVERAGE_ALERTLOG_ID, Search) ;
ResolvedPrintParent := ResolvePrintParent(ParentID /= OSVVM_COVERAGE_ALERTLOG_ID, PrintParent) ;
NewCoverageID.ID := ID ;
NewCoverageID.BurstLengthCov := NewID(Name & ifelse(Name'length > 0, " ", "") & "BurstLength", ParentID, ReportMode, ResolvedSearch, ResolvedPrintParent) ;
SetCovWeight(NewCoverageID.BurstLengthCov, 0) ;
NewCoverageID.BurstDelayCov := NewID(Name & ifelse(Name'length > 0, " ", "") & "BurstDelay", ParentID, ReportMode, ResolvedSearch, ResolvedPrintParent) ;
SetCovWeight(NewCoverageID.BurstDelayCov, 0) ;
NewCoverageID.BeatDelayCov := NewID(Name & ifelse(Name'length > 0, " ", "") & "BeatDelay", ParentID, ReportMode, ResolvedSearch, ResolvedPrintParent) ;
SetCovWeight(NewCoverageID.BeatDelayCov, 0) ;
return NewCoverageID ;
end function NewDelayCoverage ;
------------------------------------------------------------
impure function IsInitialized (ID : DelayCoverageIDType) return boolean is
------------------------------------------------------------
begin
return ID /= DELAYCOVERAGE_ID_UNINITIALZED ;
end function IsInitialized ;
------------------------------------------------------------
impure function GetDelayCoverage ( ID : integer ) return DelayCoverageIDType is
------------------------------------------------------------
variable NewCoverageID : DelayCoverageIDType ;
begin
NewCoverageID.ID := ID ;
NewCoverageID.BurstLengthCov := SingletonArrayPtr(ID).BurstLengthCov ;
NewCoverageID.BurstDelayCov := SingletonArrayPtr(ID).BurstDelayCov ;
NewCoverageID.BeatDelayCov := SingletonArrayPtr(ID).BeatDelayCov ;
return NewCoverageID ;
end function GetDelayCoverage ;
------------------------------------------------------------
procedure SetDelayCoverage ( ID : DelayCoverageIDType ) is
------------------------------------------------------------
begin
SingletonArrayPtr(ID.ID).BurstLengthCov := ID.BurstLengthCov ;
SingletonArrayPtr(ID.ID).BurstDelayCov := ID.BurstDelayCov ;
SingletonArrayPtr(ID.ID).BeatDelayCov := ID.BeatDelayCov ;
if GetRandomSalt /= 0 then
-- If RandomSalt set, randomize BurstLength
SingletonArrayPtr(ID.ID).BurstLength := ToRandPoint(ID.BurstLengthCov, (1 => (Min => 0, Max => 5))) ; -- start with beat delay (1 to 5) vs burst delay (0)
else
-- If RandomSalt is not set, randomizaation would always produce the same value, so why not 0 the original behavior.
SingletonArrayPtr(ID.ID).BurstLength := 0 ;
end if ;
end procedure SetDelayCoverage ;
------------------------------------------------------------
procedure SetBurstLength ( ID : DelayCoverageIDType ; BurstLength : integer ) is
------------------------------------------------------------
begin
SingletonArrayPtr(ID.ID).BurstLength := BurstLength ;
end procedure SetBurstLength ;
------------------------------------------------------------
impure function GetBurstLength ( ID : DelayCoverageIDType ) return integer is
------------------------------------------------------------
begin
return SingletonArrayPtr(ID.ID).BurstLength ;
end function GetBurstLength ;
-- ------------------------------------------------------------
-- impure function GetDelayCoverage ( ID : DelayCoverageIDType ) return DelayCoverageIDType is
-- ------------------------------------------------------------
-- begin
-- return GetDelayCoverage(ID.ID) ;
-- end function GetDelayCoverage ;
------------------------------------------------------------
-- PT Local
impure function GetRandDelayCov ( ID : DelayCoverageIDType ) return CoverageIDType is
------------------------------------------------------------
variable DelayCov : CoverageIDType ;
begin
if SingletonArrayPtr(ID.ID).BurstLength < 1 then
DelayCov := SingletonArrayPtr(ID.ID).BurstDelayCov ;
SingletonArrayPtr(ID.ID).BurstLength := GetRandPoint(SingletonArrayPtr(ID.ID).BurstLengthCov) ;
ICoverLast(SingletonArrayPtr(ID.ID).BurstLengthCov) ;
else
DelayCov := SingletonArrayPtr(ID.ID).BeatDelayCov ;
SingletonArrayPtr(ID.ID).BurstLength := SingletonArrayPtr(ID.ID).BurstLength - 1;
end if ;
return DelayCov ;
end function GetRandDelayCov ;
------------------------------------------------------------
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer is
------------------------------------------------------------
variable DelayCov : CoverageIDType ;
variable RandIndex : integer ;
begin
DelayCov := GetRandDelayCov( ID ) ;
RandIndex := GetRandIndex( DelayCov ) ;
ICoverLast( DelayCov ) ;
return GetPoint( DelayCov, RandIndex ) ;
-- return GetRandPoint( GetRandDelayCov(ID), CoverLast => TRUE ) ;
end function GetRandDelay ;
------------------------------------------------------------
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer_vector is
------------------------------------------------------------
variable DelayCov : CoverageIDType ;
variable RandIndex : integer ;
begin
DelayCov := GetRandDelayCov( ID ) ;
RandIndex := GetRandIndex( DelayCov ) ;
ICoverLast( DelayCov ) ;
return GetPoint( DelayCov, RandIndex ) ;
-- return GetRandPoint( GetRandDelayCov(ID), CoverLast => TRUE ) ;
end function GetRandDelay ;
-- ------------------------------------------------------------
-- procedure DeallocateBins ( ID : DelayCoverageIDType ) is
-- ------------------------------------------------------------
-- begin
-- SingletonArrayPtr(ID.ID).BurstLength := 0 ;
-- DeallocateBins(SingletonArrayPtr(ID.ID).BurstLengthCov) ;
-- DeallocateBins(SingletonArrayPtr(ID.ID).BurstDelayCov) ;
-- DeallocateBins(SingletonArrayPtr(ID.ID).BeatDelayCov) ;
-- end procedure DeallocateBins ;
------------------------------------------------------------
procedure DeallocateBins ( ID : DelayCoverageIDType ) is
------------------------------------------------------------
begin
SingletonArrayPtr(ID.ID).BurstLength := 0 ; -- Changing the coverage models, so initialize the length to 0
DeallocateBins(ID.BurstLengthCov) ;
DeallocateBins(ID.BurstDelayCov) ;
DeallocateBins(ID.BeatDelayCov) ;
end procedure DeallocateBins ;
------------------------------------------------------------
------------------------------------------------------------
-- DelayCoverageIDArrayType Overloading
------------------------------------------------------------
impure function NewID (
------------------------------------------------------------
Name : string ;
Size : positive ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
Name1 : string := "" ;
Name2 : string := "" ;
Name3 : string := "" ;
Name4 : string := "" ;
Name5 : string := "" ;
Name6 : string := "" ;
Name7 : string := "" ;
Name8 : string := "" ;
Name9 : string := "" ;
Name10 : string := "" ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDArrayType is
variable NewCoverageID : DelayCoverageIDArrayType(1 to Size) ;
begin
for i in NewCoverageID'range loop
case i is
when 1 => NewCoverageID(1) := NewID(Name & ifelse(Name'length > 0 and Name1'length > 0, " ", "") & Name1, ParentID, ReportMode, Search, PrintParent) ;
when 2 => NewCoverageID(2) := NewID(Name & ifelse(Name'length > 0 and Name2'length > 0, " ", "") & Name2, ParentID, ReportMode, Search, PrintParent) ;
when 3 => NewCoverageID(3) := NewID(Name & ifelse(Name'length > 0 and Name3'length > 0, " ", "") & Name3, ParentID, ReportMode, Search, PrintParent) ;
when 4 => NewCoverageID(4) := NewID(Name & ifelse(Name'length > 0 and Name4'length > 0, " ", "") & Name4, ParentID, ReportMode, Search, PrintParent) ;
when 5 => NewCoverageID(5) := NewID(Name & ifelse(Name'length > 0 and Name5'length > 0, " ", "") & Name5, ParentID, ReportMode, Search, PrintParent) ;
when 6 => NewCoverageID(6) := NewID(Name & ifelse(Name'length > 0 and Name6'length > 0, " ", "") & Name6, ParentID, ReportMode, Search, PrintParent) ;
when 7 => NewCoverageID(7) := NewID(Name & ifelse(Name'length > 0 and Name7'length > 0, " ", "") & Name7, ParentID, ReportMode, Search, PrintParent) ;
when 8 => NewCoverageID(8) := NewID(Name & ifelse(Name'length > 0 and Name8'length > 0, " ", "") & Name8, ParentID, ReportMode, Search, PrintParent) ;
when 9 => NewCoverageID(9) := NewID(Name & ifelse(Name'length > 0 and Name9'length > 0, " ", "") & Name9, ParentID, ReportMode, Search, PrintParent) ;
when 10 => NewCoverageID(10) := NewID(Name & ifelse(Name'length > 0 and Name10'length > 0, " ", "") & Name10, ParentID, ReportMode, Search, PrintParent) ;
when others => NULL ;
end case ;
end loop ;
return NewCoverageID ;
end function NewID ;
--!! todo
-- -- -- insert an object into the data structure. Updates the ID fields
-- impure function NewID( ID : DelayCoverageIDArrayType ) return DelayCoverageIDArrayType is
-- variable NewCoverageID : DelayCoverageIDArrayType(ID'range) ;
-- begin
-- for i in ID'range loop
-- NewCoverageID(i) := NewID(ID(i)) ;
-- end loop ;
-- return NewCoverageID ;
-- end function NewID ;
------------------------------------------------------------
impure function NewDelayCoverage (
------------------------------------------------------------
ID : Integer ; -- Starting ID, and the ID's are consecutive
Name : String ;
Size : positive ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
Name1 : string := "" ;
Name2 : string := "" ;
Name3 : string := "" ;
Name4 : string := "" ;
Name5 : string := "" ;
Name6 : string := "" ;
Name7 : string := "" ;
Name8 : string := "" ;
Name9 : string := "" ;
Name10 : string := "" ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDArrayType is
variable NewCoverageID : DelayCoverageIDArrayType(1 to Size) ;
begin
for i in NewCoverageID'range loop
case i is
when 1 => NewCoverageID(1) := NewDelayCoverage(ID, Name & ifelse(Name'length > 0 and Name1'length > 0, " ", "") & Name1, ParentID, ReportMode, Search, PrintParent) ;
when 2 => NewCoverageID(2) := NewDelayCoverage(ID+1, Name & ifelse(Name'length > 0 and Name2'length > 0, " ", "") & Name2, ParentID, ReportMode, Search, PrintParent) ;
when 3 => NewCoverageID(3) := NewDelayCoverage(ID+2, Name & ifelse(Name'length > 0 and Name3'length > 0, " ", "") & Name3, ParentID, ReportMode, Search, PrintParent) ;
when 4 => NewCoverageID(4) := NewDelayCoverage(ID+2, Name & ifelse(Name'length > 0 and Name4'length > 0, " ", "") & Name4, ParentID, ReportMode, Search, PrintParent) ;
when 5 => NewCoverageID(5) := NewDelayCoverage(ID+4, Name & ifelse(Name'length > 0 and Name5'length > 0, " ", "") & Name5, ParentID, ReportMode, Search, PrintParent) ;
when 6 => NewCoverageID(6) := NewDelayCoverage(ID+5, Name & ifelse(Name'length > 0 and Name6'length > 0, " ", "") & Name6, ParentID, ReportMode, Search, PrintParent) ;
when 7 => NewCoverageID(7) := NewDelayCoverage(ID+6, Name & ifelse(Name'length > 0 and Name7'length > 0, " ", "") & Name7, ParentID, ReportMode, Search, PrintParent) ;
when 8 => NewCoverageID(8) := NewDelayCoverage(ID+7, Name & ifelse(Name'length > 0 and Name8'length > 0, " ", "") & Name8, ParentID, ReportMode, Search, PrintParent) ;
when 9 => NewCoverageID(9) := NewDelayCoverage(ID+8, Name & ifelse(Name'length > 0 and Name9'length > 0, " ", "") & Name9, ParentID, ReportMode, Search, PrintParent) ;
when 10 => NewCoverageID(10) := NewDelayCoverage(ID+9, Name & ifelse(Name'length > 0 and Name10'length > 0, " ", "") & Name10, ParentID, ReportMode, Search, PrintParent) ;
when others => NULL ;
end case ;
end loop ;
return NewCoverageID ;
end function NewDelayCoverage ;
------------------------------------------------------------
impure function GetDelayCoverage(ID : integer; Size : positive ) return DelayCoverageIDArrayType is
------------------------------------------------------------
variable NewCoverageID : DelayCoverageIDArrayType(0 to Size-1) ;
begin
for i in NewCoverageID'range loop
NewCoverageID(i) := GetDelayCoverage(ID+i) ;
end loop ;
return NewCoverageID ;
end function GetDelayCoverage ;
------------------------------------------------------------
procedure SetDelayCoverage ( ID : DelayCoverageIDArrayType ) is
------------------------------------------------------------
begin
for i in ID'range loop
SetDelayCoverage(ID(i)) ;
end loop ;
end procedure SetDelayCoverage ;
------------------------------------------------------------
procedure DeallocateBins ( ID : DelayCoverageIDArrayType ) is
------------------------------------------------------------
begin
for i in ID'range loop
DeallocateBins(ID(i)) ;
end loop ;
end procedure DeallocateBins ;
end protected body DelayCoveragePType ;
-- /////////////////////////////////////////
-- /////////////////////////////////////////
-- Singleton Data Structure
-- /////////////////////////////////////////
-- /////////////////////////////////////////
shared variable DelayCoverage : DelayCoveragePType ;
------------------------------------------------------------
impure function NewID (
------------------------------------------------------------
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType is
begin
return DelayCoverage.NewID (Name, ParentID, ReportMode, Search, PrintParent) ;
end function NewID ;
------------------------------------------------------------
impure function NewDelayCoverage (
------------------------------------------------------------
ID : Integer ;
Name : String ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDType is
begin
return DelayCoverage.NewDelayCoverage (ID, Name, ParentID, ReportMode, Search, PrintParent) ;
end function NewDelayCoverage ;
------------------------------------------------------------
impure function IsInitialized (ID : DelayCoverageIDType) return boolean is
------------------------------------------------------------
begin
return DelayCoverage.IsInitialized(ID) ;
end function IsInitialized ;
------------------------------------------------------------
impure function GetDelayCoverage ( ID : integer ) return DelayCoverageIDType is
------------------------------------------------------------
begin
return DelayCoverage.GetDelayCoverage ( ID ) ;
end function GetDelayCoverage ;
------------------------------------------------------------
procedure SetDelayCoverage ( ID : DelayCoverageIDType ) is
------------------------------------------------------------
begin
DelayCoverage.SetDelayCoverage ( ID ) ;
end procedure SetDelayCoverage ;
------------------------------------------------------------
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer is
------------------------------------------------------------
begin
return DelayCoverage.GetRandDelay(ID) ;
end function GetRandDelay ;
------------------------------------------------------------
impure function GetRandDelay ( ID : DelayCoverageIDType ) return integer_vector is
------------------------------------------------------------
begin
return DelayCoverage.GetRandDelay(ID) ;
end function GetRandDelay ;
------------------------------------------------------------
procedure DeallocateBins(ID : DelayCoverageIDType) is
------------------------------------------------------------
begin
DelayCoverage.DeallocateBins(ID) ;
end procedure DeallocateBins ;
------------------------------------------------------------
--- ///////////////////////////////////////////////////////////////////////////
------------------------------------------------------------
-- DelayCoverageIDArrayType Overloading
------------------------------------------------------------
impure function NewID (
------------------------------------------------------------
Name : string ;
Size : positive ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
Name1 : string := "" ;
Name2 : string := "" ;
Name3 : string := "" ;
Name4 : string := "" ;
Name5 : string := "" ;
Name6 : string := "" ;
Name7 : string := "" ;
Name8 : string := "" ;
Name9 : string := "" ;
Name10 : string := "" ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDArrayType is
begin
return DelayCoverage.NewID (
Name, Size, ParentID,
Name1, Name2, Name3, Name4, Name5, Name6, Name7, Name8, Name9, Name10,
ReportMode, Search, PrintParent) ;
end function NewID ;
------------------------------------------------------------
impure function NewDelayCoverage (
------------------------------------------------------------
ID : Integer ; -- Starting ID, and the ID's are consecutive
Name : String ;
Size : positive ;
ParentID : AlertLogIDType := OSVVM_COVERAGE_ALERTLOG_ID ;
Name1 : string := "" ;
Name2 : string := "" ;
Name3 : string := "" ;
Name4 : string := "" ;
Name5 : string := "" ;
Name6 : string := "" ;
Name7 : string := "" ;
Name8 : string := "" ;
Name9 : string := "" ;
Name10 : string := "" ;
ReportMode : AlertLogReportModeType := DISABLED ;
Search : NameSearchType := PRIVATE_NAME ;
PrintParent : AlertLogPrintParentType := PRINT_NAME_AND_PARENT
) return DelayCoverageIDArrayType is
begin
return DelayCoverage.NewDelayCoverage (
ID, Name, Size, ParentID,
Name1, Name2, Name3, Name4, Name5, Name6, Name7, Name8, Name9, Name10,
ReportMode, Search, PrintParent) ;
end function NewDelayCoverage ;
------------------------------------------------------------
impure function GetDelayCoverage(ID : integer; Size : positive ) return DelayCoverageIDArrayType is
------------------------------------------------------------
begin
return DelayCoverage.GetDelayCoverage ( ID, Size ) ;
end function GetDelayCoverage ;
------------------------------------------------------------
procedure SetDelayCoverage ( ID : DelayCoverageIDArrayType ) is
------------------------------------------------------------
begin
DelayCoverage.SetDelayCoverage ( ID ) ;
end procedure SetDelayCoverage ;
------------------------------------------------------------
procedure SetBurstLength ( ID : DelayCoverageIDType ; BurstLength : integer ) is
------------------------------------------------------------
begin
DelayCoverage.SetBurstLength ( ID, BurstLength ) ;
end procedure SetBurstLength ;
------------------------------------------------------------
impure function GetBurstLength ( ID : DelayCoverageIDType ) return integer is
------------------------------------------------------------
begin
return DelayCoverage.GetBurstLength ( ID ) ;
end function GetBurstLength ;
------------------------------------------------------------
procedure DeallocateBins ( ID : DelayCoverageIDArrayType ) is
------------------------------------------------------------
begin
DelayCoverage.DeallocateBins(ID) ;
end procedure DeallocateBins ;
end package body DelayCoveragePkg ;