-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathmemory_stage.v
273 lines (228 loc) · 11.8 KB
/
memory_stage.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
///////////////////////////////////////////////////////////////////////////////////////////////////
// //
// Module Name: memory_stage //
// Description: Memory Stage. This stage slices outgoing data based on data with and sub-line //
// addressing, and drives the data memory read/write transactions. //
// Author : Peter Herrmann //
// //
// SPDX-License-Identifier: CC-BY-NC-ND-4.0 //
// //
///////////////////////////////////////////////////////////////////////////////////////////////////
`include "Lucid64.vh"
module memory_stage #(parameter VADDR = 39) (
//======= Clocks, Resets, and Stage Controls ========//
input clk_i,
input rst_ni,
input squash_i,
input bubble_i,
input stall_i,
//============== Execute Stage Inputs ===============//
input valid_i,
input [VADDR-1:0] dmem_full_addr_i,
input [`XLEN-1:0] rs2_data_i,
// Destination Register (rd)
input [`XLEN-1:0] rd_data_i,
input [4:0] rd_idx_i,
input rd_wr_en_i,
input rd_wr_src_load_i,
// Load/Store
input [3:0] mem_width_1h_i,
input mem_rd_i,
input mem_wr_i,
input mem_sign_i,
//============== Data Memory Interface ==============//
output wire dmem_req_o,
input dmem_gnt_i,
output wire [VADDR-1:0] dmem_addr_ao,
output wire dmem_we_ao,
output wire [7:0] dmem_be_ao,
output wire [`XLEN-1:0] dmem_wdata_ao,
input dmem_rvalid_i,
output wire dmem_stall_ao,
output wire unalign_store_ex_ao,
output wire unalign_load_ex_ao,
//================ Pipeline Outputs =================//
output reg valid_o,
// Destination Register (rd)
output reg [`XLEN-1:0] rd_data_o,
output reg [4:0] rd_idx_o,
output reg rd_wr_en_o,
output reg rd_wr_src_load_o,
// Load/Store
output reg [3:0] mem_width_1h_o,
output reg mem_sign_o,
output reg [2:0] byte_addr_o
`ifdef LUCID64_RVFI
,
input [ 32 - 1 : 0] rvfi_insn_i,
input rvfi_trap_i,
input [ 5 - 1 : 0] rvfi_rs1_addr_i,
input [ 5 - 1 : 0] rvfi_rs2_addr_i,
input [`XLEN - 1 : 0] rvfi_rs1_rdata_i,
input [`XLEN - 1 : 0] rvfi_rs2_rdata_i,
input [`XLEN - 1 : 0] rvfi_pc_rdata_i,
input [`XLEN - 1 : 0] rvfi_pc_wdata_i,
output reg [ 32 - 1 : 0] rvfi_insn_o,
output reg rvfi_trap_o,
output reg [ 5 - 1 : 0] rvfi_rs1_addr_o,
output reg [ 5 - 1 : 0] rvfi_rs2_addr_o,
output reg [`XLEN - 1 : 0] rvfi_rs1_rdata_o,
output reg [`XLEN - 1 : 0] rvfi_rs2_rdata_o,
output reg [`XLEN - 1 : 0] rvfi_pc_rdata_o,
output reg [`XLEN - 1 : 0] rvfi_pc_wdata_o,
output reg [`XLEN - 1 : 0] rvfi_mem_addr_o,
output reg [`XLEN/8 - 1 : 0] rvfi_mem_rmask_o,
output reg [`XLEN/8 - 1 : 0] rvfi_mem_wmask_o,
output reg [`XLEN - 1 : 0] rvfi_mem_wdata_o
`endif
);
///////////////////////////////////////////////////////////////////////////////////////////////
// Validity Tracker //
///////////////////////////////////////////////////////////////////////////////////////////////
wire valid;
validity_tracker MEM_validity_tracker (
.clk_i (clk_i),
.rst_ni (rst_ni),
.valid_i (valid_i),
.squash_i (squash_i),
.bubble_i (bubble_i),
.stall_i (stall_i),
.valid_ao (valid)
);
///////////////////////////////////////////////////////////////////////////////////////////////
// Byte Addressing Logic //
///////////////////////////////////////////////////////////////////////////////////////////////
wire [VADDR-1:0] dmem_word_addr;
reg [`XLEN-1:0] dmem_wdata_a;
reg illegal_addr;
reg [7:0] byte_strobe;
wire [2:0] byte_addr = dmem_full_addr_i[2:0];
wire exception;
always @ (*) begin : dmem_strobe_gen
case (mem_width_1h_i)
`MEM_WIDTH_1H_BYTE: begin
illegal_addr = 1'b0;
dmem_wdata_a = { 8{rs2_data_i[7:0]} };
byte_strobe = (8'b0000_0001 << byte_addr);
end
`MEM_WIDTH_1H_HALF: begin
illegal_addr = (byte_addr[0] == 1'b1);
dmem_wdata_a = { 4{rs2_data_i[15:0]} };
byte_strobe = (illegal_addr) ? 8'b0 : (8'b0000_0011 << byte_addr);
end
`MEM_WIDTH_1H_WORD: begin
illegal_addr = !((byte_addr == 3'b100) || (byte_addr == 3'b000));
dmem_wdata_a = { 2{rs2_data_i[31:0]} };
byte_strobe = (illegal_addr) ? 8'b0 : (8'b0000_1111 << byte_addr);
end
`MEM_WIDTH_1H_DOUBLE: begin
illegal_addr = (byte_addr != 3'b0);
dmem_wdata_a = rs2_data_i;
byte_strobe = (illegal_addr) ? 8'b0 : 8'b1111_1111;
end
default: begin
illegal_addr = 1'b1;
dmem_wdata_a = rs2_data_i;
byte_strobe = 8'b0;
end
endcase
end
assign dmem_word_addr = {dmem_full_addr_i[VADDR-1:3], 3'b0};
///////////////////////////////////////////////////////////////////////////////////////////////
// Host Memory Request Driver //
///////////////////////////////////////////////////////////////////////////////////////////////
wire mem_read = mem_rd_i & valid;
wire mem_write = mem_wr_i & valid;
obi_host_driver #(.DATA_W(`XLEN), .ADDR_W(VADDR)) dmem_obi_host_driver
(
.clk_i (clk_i),
.rst_ni (rst_ni),
.gnt_i (dmem_gnt_i),
.rvalid_i (dmem_rvalid_i),
.stall_i (stall_i),
// .be_i ((mem_write) ? byte_strobe : 8'b0),
.be_i (byte_strobe),
.addr_i (dmem_word_addr),
.wdata_i (dmem_wdata_a),
.rd_i (mem_read && ~illegal_addr),
.wr_i (mem_write && ~illegal_addr),
.stall_ao (dmem_stall_ao),
.req_o (dmem_req_o),
.we_ao (dmem_we_ao),
.be_ao (dmem_be_ao),
.addr_ao (dmem_addr_ao),
.wdata_ao (dmem_wdata_ao)
);
assign unalign_store_ex_ao = illegal_addr && mem_write;
assign unalign_load_ex_ao = illegal_addr && mem_read;
assign exception = illegal_addr && (mem_rd_i || mem_wr_i);
///////////////////////////////////////////////////////////////////////////////////////////////
// ____ _ _ _ ____ _ _ //
// | _ \(_)_ __ ___| (_)_ __ ___ | _ \ ___ __ _(_)___| |_ ___ _ __ ___ //
// | |_) | | '_ \ / _ \ | | '_ \ / _ \ | |_) / _ \/ _` | / __| __/ _ \ '__/ __| //
// | __/| | |_) | __/ | | | | | __/ | _ < __/ (_| | \__ \ || __/ | \__ \ //
// |_| |_| .__/ \___|_|_|_| |_|\___| |_| \_\___|\__, |_|___/\__\___|_| |___/ //
// |_| |___/ //
///////////////////////////////////////////////////////////////////////////////////////////////
always @(posedge clk_i) begin
if (~rst_ni)
valid_o <= 1'b0;
else if (~stall_i)
valid_o <= valid && (~exception);
end
always @(posedge clk_i) begin : execute_pipeline_registers
// On stall, all outputs do not change.
// Destination Register (rd)
rd_data_o <= (stall_i) ? rd_data_o : rd_data_i;
rd_idx_o <= (stall_i) ? rd_idx_o : rd_idx_i;
rd_wr_en_o <= (stall_i) ? rd_wr_en_o : rd_wr_en_i;
rd_wr_src_load_o <= (stall_i) ? rd_wr_src_load_o : rd_wr_src_load_i;
// Load/Store
mem_width_1h_o <= (stall_i) ? mem_width_1h_o : mem_width_1h_i;
mem_sign_o <= (stall_i) ? mem_sign_o : mem_sign_i;
byte_addr_o <= (stall_i) ? byte_addr_o : dmem_full_addr_i[2:0];
end
///////////////////////////////////////////////////////////////////////////////////////////////
// RISC-V Formal Interface //
///////////////////////////////////////////////////////////////////////////////////////////////
`ifdef LUCID64_RVFI
always @(posedge clk_i) begin
if (~rst_ni)
rvfi_trap_o <= '0;
else if (squash_i || bubble_i)
rvfi_trap_o <= '0;
else if (~stall_i)
rvfi_trap_o <= rvfi_trap_i | (exception && valid);
end
always @(posedge clk_i) begin
if (~stall_i) begin
rvfi_insn_o <= rvfi_insn_i;
rvfi_rs1_addr_o <= rvfi_rs1_addr_i;
rvfi_rs2_addr_o <= rvfi_rs2_addr_i;
rvfi_rs1_rdata_o <= rvfi_rs1_rdata_i;
rvfi_rs2_rdata_o <= rvfi_rs2_rdata_i;
rvfi_pc_rdata_o <= rvfi_pc_rdata_i;
rvfi_pc_wdata_o <= rvfi_pc_wdata_i;
rvfi_mem_addr_o <= 64'(dmem_word_addr);
rvfi_mem_rmask_o <= dmem_we_ao ? '0 : byte_strobe;
rvfi_mem_wmask_o <= dmem_we_ao ? byte_strobe : '0;
rvfi_mem_wdata_o <= dmem_wdata_ao;
end
end
`endif
endmodule
///////////////////////////////////////////////////////////////////////////////////////////////////
//// Copyright 2024 Peter Herrmann ////
//// ////
//// Licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 ////
//// International License (the "License"); you may not use this file except in compliance ////
//// with the License. You may obtain a copy of the License at ////
//// ////
//// https://creativecommons.org/licenses/by-nc-nd/4.0/ ////
//// ////
//// Unless required by applicable law or agreed to in writing, software ////
//// distributed under the License is distributed on an "AS IS" BASIS, ////
//// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. ////
//// See the License for the specific language governing permissions and ////
//// limitations under the License. ////
///////////////////////////////////////////////////////////////////////////////////////////////////