build.gradle

plugins {
    id "com.palantir.git-version" version "5.0.0"
    id "org.sonarqube" version "7.3.1.8318"
}

def gitOutput(String... args) {
    return providers.exec {
        commandLine(['git'] + args.toList())
        ignoreExitValue = true
    }.standardOutput.asText.get().trim()
}

def normalizeReleaseTag(String tag) {
    if (!tag) {
        return null
    }

    return tag.startsWith('v') ? tag.substring(1) : tag
}

def pep440VersionFromLatestTag() {
    def exactTag = gitOutput('describe', '--tags', '--exact-match')
    if (exactTag) {
        return normalizeReleaseTag(exactTag)
    }

    def tag = gitOutput('describe', '--tags', '--abbrev=0')
    if (!tag) {
        tag = '0.0.0'
    }

    def baseVersion = normalizeReleaseTag(tag)

    def distanceText = tag == '0.0.0'
            ? gitOutput('rev-list', 'HEAD', '--count')
            : gitOutput('rev-list', "${tag}..HEAD", '--count')
    def distance = distanceText?.isInteger() ? distanceText.toInteger() : 0

    def hash = gitOutput('rev-parse', '--short=7', 'HEAD')
    def dirty = gitOutput('status', '--porcelain') ? true : false

    if (distance == 0 && !dirty) {
        return baseVersion
    }

    def version = "${baseVersion}.post${distance}"
    def localParts = []

    if (hash) {
        localParts.add("g${hash}")
    }

    if (dirty) {
        localParts.add("dirty")
    }

    if (!localParts.isEmpty()) {
        version += "+" + localParts.join(".")
    }

    return version
}

allprojects {
    group = 'mil.army.wmist.regi-python'
    version = pep440VersionFromLatestTag()
}