Operator

#!/bin/zsh
set -e

LABEL="com.lifeos.bot"
PLIST="$HOME/Library/LaunchAgents/${LABEL}.plist"
PROJECT_DIR="$(cd "$(dirname "$0")" && pwd)"
LOG="${PROJECT_DIR}/logs/telegram_bot.log"
ERR_LOG="$HOME/.lifeos/launchd.err.log"
SERVICE="gui/$(id -u)/${LABEL}"
DOMAIN="gui/$(id -u)"

case "${1:l}" in
  on|start|"")
    if launchctl print "$SERVICE" >/dev/null 2>&1; then
      echo "Operator is already on."
    else
      launchctl bootstrap "$DOMAIN" "$PLIST"
      echo "Operator is on. Telegram is live 24x7."
    fi
    ;;
  restart)
    if launchctl print "$SERVICE" >/dev/null 2>&1; then
      launchctl kickstart -k "$SERVICE" || launchctl bootstrap "$DOMAIN" "$PLIST"
    else
      launchctl bootstrap "$DOMAIN" "$PLIST"
    fi
    echo "Operator restarted."
    ;;
  off|stop)
    launchctl bootout "$SERVICE" >/dev/null 2>&1 || true
    echo "Operator is off."
    ;;
  status)
    if launchctl print "$SERVICE" >/dev/null 2>&1; then
      PID=$(launchctl print "$SERVICE" 2>/dev/null | awk '/pid = /{print $3; exit}')
      if [[ -n "$PID" && "$PID" != "0" ]]; then
        echo "Operator is running (pid $PID)."
      else
        echo "Operator is loaded but not currently running (KeepAlive will respawn)."
      fi
    else
      echo "Operator is not running. Start it with: operator on"
    fi
    ;;
  logs)
    echo "--- bot log (tail) ---"
    tail -n 40 "$LOG" 2>/dev/null || echo "(no bot log yet)"
    echo "--- launchd err (tail) ---"
    tail -n 20 "$ERR_LOG" 2>/dev/null || echo "(no err log)"
    ;;
  tail)
    tail -f "$LOG"
    ;;
  *)
    echo "Use: operator on"
    echo "     operator off"
    echo "     operator restart"
    echo "     operator status"
    echo "     operator logs"
    echo "     operator tail"
    exit 2
    ;;
esac