GH-46116: [C++] Implement IPC directory in Meson

Author: WillAyd

cpp/meson.build

@@ -63,7 +63,22 @@ needs_filesystem = false or needs_hdfs
 needs_integration = get_option('integration')
 needs_tests = get_option('tests')
 needs_ipc = get_option('ipc') or needs_tests or needs_benchmarks
-needs_testing = get_option('testing') or needs_tests or needs_benchmarks or needs_integration
+needs_fuzzing = get_option('fuzzing')
+needs_testing = (get_option('testing')
+or needs_tests
+or needs_benchmarks
+or needs_fuzzing
+or needs_integration
+)
 needs_json = get_option('json') or needs_testing
+needs_brotli = get_option('brotli') or needs_fuzzing
+needs_lz4 = get_option('lz4')
+needs_zstd = get_option('zstd')
+needs_utilities = get_option('utilities')
+
+if get_option('brotli') or get_option('lz4') or get_option('zstd')
+    # See GH issue 46115
+    error('Compression options (brotli, lz4, zstd) are not implemented in Meson')
+endif
 
 subdir('src/arrow')

cpp/meson.options

@@ -22,13 +22,27 @@ option(
     value: false,
 )
 
+option(
+    'brotli',
+    type: 'boolean',
+    description: 'Build with Brotli compression',
+    value: false,
+)
+
 option(
     'csv',
     type: 'boolean',
     description: 'Build the Arrow CSV Parser Module',
     value: false,
 )
 
+option(
+    'fuzzing',
+    type: 'boolean',
+    description: 'Build Arrow Fuzzing executables',
+    value: false,
+)
+
 option(
     'hdfs',
     type: 'boolean',
@@ -67,6 +81,13 @@ option(
     type: 'string',
 )
 
+option(
+    'lz4',
+    type: 'boolean',
+    description: 'Build with lz4 compression',
+    value: false,
+)
+
 option(
     'package_kind',
     type: 'string',
@@ -86,3 +107,17 @@ option(
     description: 'Build the Arrow googletest unit tests',
     value: false,
 )
+
+option(
+    'utilities',
+    type: 'boolean',
+    description: 'Build Arrow commandline utilities',
+    value: false,
+)
+
+option(
+    'zstd',
+    type: 'boolean',
+    description: 'Build with zstd compression',
+    value: false,
+)

cpp/src/arrow/ipc/meson.build

@@ -0,0 +1,127 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements.  See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership.  The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License.  You may obtain a copy of the License at
+#
+#   http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied.  See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+exc = executable(
+    'arrow-feather-test',
+    sources: ['feather_test.cc'],
+    dependencies: [arrow_test_dep, arrow_ipc_deps],
+)
+test('arrow-feather-test', exc)
+
+ipc_tests = [
+    'json_simple_test',
+    'message_internal_test',
+    'read_write_test',
+    'tensor_test',
+]
+
+foreach ipc_test : ipc_tests
+    test_name = 'arrow-ipc-@0@'.format(ipc_test.replace('_', '-'))
+    exc = executable(
+        test_name,
+        sources: ['@[email protected]'.format(ipc_test)],
+        dependencies: [arrow_test_dep, arrow_ipc_deps],
+    )
+    test(test_name, exc)
+endforeach
+
+install_headers(
+    [
+        'api.h',
+        'dictionary.h',
+        'feather.h',
+        'json_simple.h',
+        'message.h',
+        'options.h',
+        'reader.h',
+        'test_common.h',
+        'type_fwd.h',
+        'util.h',
+        'writer.h',
+    ],
+    subdir: 'arrow/ipc',
+)
+
+if needs_utilities or needs_integration
+    file_to_stream_exc = executable(
+        'arrow-file-to-stream',
+        sources: ['file_to_stream.cc'],
+        dependencies: [arrow_dep],
+        install: needs_utilities,
+    )
+
+    stream_to_file_exc = executable(
+        'arrow-stream-to-file',
+        sources: ['stream_to_file.cc'],
+        dependencies: [arrow_dep],
+        install: needs_utilities,
+    )
+
+    if needs_integration
+        # TODO: The CMake configuration would add these executables
+        # to an arrow-integration target, which is in turn
+        # used by arrow-all. The targets are modified, but not
+        # used within Arrow C++ (?) - do we need to replicate that here?
+    endif
+endif
+
+exc = executable(
+    'arrow-ipc-read-write-benchmark',
+    sources: ['read_write_benchmark.cc'],
+    dependencies: [arrow_benchmark_dep],
+)
+benchmark('arrow-ipc-read-write-benchmark', exc)
+
+if needs_fuzzing or (needs_utilities
+and needs_testing
+and needs_lz4
+and needs_zstd
+)
+    fuzz_corpus_exc = executable(
+        'arrow-ipc-generate-fuzz-corpus',
+        sources: ['generate_fuzz_corpus.cc'],
+        dependencies: [arrow_test_dep],
+    )
+
+    tensor_fuzz_corpus_exc = executable(
+        'arrow-ipc-generate-tensor-fuzz-corpus',
+        sources: ['generate_tensor_fuzz_corpus.cc'],
+        dependencies: [arrow_test_dep],
+    )
+endif
+
+ipc_fuzz_targets = ['file_fuzz', 'stream_fuzz', 'tensor_stream_fuzz']
+
+if needs_fuzzing
+    if meson.version() < '1.8.0'
+        error(
+            ' Meson >= 1.8.0 is required for fuzzing support, found @0@'.format(
+                meson.version(),
+            ),
+        )
+    endif
+
+    foreach ipc_fuzz_target : ipc_fuzz_targets
+        target_name = 'arrow-ipc-@0@'.format(ipc_fuzz_target.replace('_', '-'))
+        executable(
+            target_name,
+            sources: ['@[email protected]'.format(ipc_fuzz_target)],
+            dependencies: [arrow_dep],
+            override_options: ['-Db_sanitize=fuzzer'],
+        )
+    endforeach
+endif

cpp/src/arrow/meson.build

@@ -554,3 +554,7 @@ endif
 if needs_csv
     subdir('csv')
 endif
+
+if needs_ipc
+    subdir('ipc')
+endif