Creating an install target for a pure Rust C API

[scott-wilson]

Hey, I'm making a C API in Rust using corrosion/cmake as the build tools to include in another cmake project. I know that I could simply do cargo build --release and it'll create my dynamic library/static library, but I want to use cmake to build a deployable package.

I'm hoping I could take the following CMakeLists.txt and produce a folder structure that looks like this:

The Structure

${PREFIX}/
    include/
        openchecks.h  # Works
    share/pkgconfig
        copenchecks.pc  # Works
    lib/
        cmake/copenchecks/
            copenchecks-config-version.cmake  # Works
            copenchecks-config.cmake  # Works
        libcopenchecks.so.0.1.0  # Sort of works, need to use the install(file ...) to get it to work
        libcopenchecks.so.0.1  # Does not work/create symlink
        libcopenchecks.so.0  # Does not work/create symlink
        libcopenchecks.so  # Does not work/create symlink
        libcopenchecks.a.0.1.0  # Sort of works, need to use the install(file ...) to get it to work
        libcopenchecks.a.0  # Does not work/create symlink
        libcopenchecks.a  # Does not work/create symlink

The CMakeLists File

cmake_minimum_required(VERSION 3.15.0 FATAL_ERROR)

set(COPENCHECKS_VERSION_MAJOR "0")
set(COPENCHECKS_VERSION_MINOR "1")
set(COPENCHECKS_VERSION_PATCH "0")
set(COPENCHECKS_VERSION_PRERELEASE "")

if(COPENCHECKS_VERSION_PRERELEASE)
    set(COPENCHECKS_VERSION ${COPENCHECKS_VERSION_MAJOR}.${COPENCHECKS_VERSION_MINOR}.${COPENCHECKS_VERSION_PATCH}-${COPENCHECKS_VERSION_PRERELEASE})
else()
    set(COPENCHECKS_VERSION ${COPENCHECKS_VERSION_MAJOR}.${COPENCHECKS_VERSION_MINOR}.${COPENCHECKS_VERSION_PATCH})
endif()


project(
    copenchecks
    VERSION ${COPENCHECKS_VERSION}
    DESCRIPTION "A simple checks framework"
    LANGUAGES C
)

# --------------------------------------------------------------------------------
# Build Options
# --------------------------------------------------------------------------------
option(CODE_COVERAGE "Enable coverage reporting" OFF)

# --------------------------------------------------------------------------------
# Do the build
# --------------------------------------------------------------------------------
set(UNIT_TESTING OFF)

add_subdirectory(corrosion)

if (NOT DEFINED COPENCHECKS_SOURCE_DIR OR COPENCHECKS_SOURCE_DIR MATCHES "")
set(COPENCHECKS_SOURCE_DIR "${PROJECT_SOURCE_DIR}")
endif()

corrosion_import_crate(MANIFEST_PATH "${COPENCHECKS_SOURCE_DIR}/Cargo.toml")

# Install
set_target_properties(${CMAKE_PROJECT_NAME} PROPERTIES VERSION ${COPENCHECKS_VERSION})
set_target_properties(${CMAKE_PROJECT_NAME} PROPERTIES SOVERSION ${COPENCHECKS_VERSION_MAJOR})
set_target_properties(${CMAKE_PROJECT_NAME} PROPERTIES PUBLIC_HEADER include/openchecks.h)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

set(INCLUDE_INSTALL_DIR ${CMAKE_INSTALL_INCLUDEDIR}
    CACHE PATH "Location of header files"
)
set(SYSCONFIG_INSTALL_DIR ${CMAKE_INSTALL_SYSCONFDIR}
    CACHE PATH "Location of configuration files"
)

configure_package_config_file(
    cmake/${CMAKE_PROJECT_NAME}-config.cmake.in
    ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}-config.cmake
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/Foo
    PATH_VARS INCLUDE_INSTALL_DIR SYSCONFIG_INSTALL_DIR
)
write_basic_package_version_file(
    ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}-config-version.cmake
    VERSION ${COPENCHECKS_VERSION}
    COMPATIBILITY SameMajorVersion
)
configure_file(share/pkgconfig/${CMAKE_PROJECT_NAME}.pc.in ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}.pc @ONLY)

install(
    FILES ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}-config.cmake ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}-config-version.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${CMAKE_PROJECT_NAME}
)
install(
    FILES ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}.pc
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig
)
install(
    TARGETS ${CMAKE_PROJECT_NAME}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
install(
    FILES ${CMAKE_CURRENT_BINARY_DIR}/lib${CMAKE_PROJECT_NAME}.so
    DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RENAME lib${CMAKE_PROJECT_NAME}.so.${COPENCHECKS_VERSION_MAJOR}.${COPENCHECKS_VERSION_MINOR}.${COPENCHECKS_VERSION_PATCH}
)
install(
    FILES ${CMAKE_CURRENT_BINARY_DIR}/lib${CMAKE_PROJECT_NAME}.a
    DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RENAME lib${CMAKE_PROJECT_NAME}.a.${COPENCHECKS_VERSION_MAJOR}.${COPENCHECKS_VERSION_MINOR}.${COPENCHECKS_VERSION_PATCH}
)

# Test
if (BUILD_COPENCHECKS_TESTS)
    enable_testing()
    add_subdirectory(cmocka)
    add_subdirectory(tests)
endif()

How would I go about doing this? Also, if there's anything glaringly obviously bad with my file, then I'll happily take advise.

[jschwe]

Im currently travelling without my laptop, but at first glance your cmake code is not telling rustc to add the soname / install_name. You can see the following discussion in the corrosion guide:

https://corrosion-rs.github.io/corrosion/common_issues.html#missing-soname-on-linux-for-cdylibs

That doesn't really answer your question, but I believe setting the soname is also something you must do for your usecase.

I'd also recommend asking this question on the CMake discourse forum. From the perspective of CMake corrosion imports shared libraries as an "IMPORTED SHARED" library. I'm not overly familiar with the newer installation features added in recent cmake versions - so perhaps there is something besides install(FILE) which is better suited.