Allow forcing specific compilers

Author: josevalim

lib/mix/lib/mix/task.compiler.ex

@@ -295,10 +295,24 @@ defmodule Mix.Task.Compiler do
   end
 
   defp run_compiler(compiler, args) do
-    result = normalize(Mix.Task.run("compile.#{compiler}", args), compiler)
+    args_maybe_force = maybe_prepend_force(args, compiler)
+    result = normalize(Mix.Task.run("compile.#{compiler}", args_maybe_force), compiler)
     Enum.reduce(Mix.ProjectStack.pop_after_compiler(compiler), result, & &1.(&2))
   end
 
+  defp maybe_prepend_force(args, compiler) do
+    args
+    |> Enum.any?(fn
+      "--force-" <> rest -> rest == compiler |> to_string() |> String.replace("_", "-")
+      _ -> false
+    end)
+    |> if do
+      ["--force" | args]
+    else
+      args
+    end
+  end
+
   # Normalize the compiler result to a diagnostic tuple
   defp normalize(result, name) do
     case result do

lib/mix/lib/mix/tasks/compile.ex

@@ -7,7 +7,7 @@ defmodule Mix.Tasks.Compile do
 
   @shortdoc "Compiles source files"
 
-  @moduledoc """
+  @moduledoc ~S"""
   The main entry point to compile source files.
 
   It simply runs the compilers registered in your project and returns
@@ -59,7 +59,9 @@ defmodule Mix.Tasks.Compile do
     * `--all-warnings` (`--no-all-warnings`) - prints all warnings, including previous compilations
       (default is true except on errors)
     * `--erl-config` - path to an Erlang term file that will be loaded as Mix config
-    * `--force` - forces compilation
+    * `--force` - forces compilation. You can also specify `--force-#{compiler}` for each compiler
+      invoked to force specifically that compiler to run (it requires the compiler to respect the
+      `--force` option, which is advised)
     * `--list` - lists all enabled compilers
     * `--listeners` - starts Mix listeners (they are started by default,
       unless `--no-listeners` or `--no-deps-check` are given)

lib/mix/test/mix/tasks/compile.elixir_test.exs

@@ -1253,6 +1253,23 @@ defmodule Mix.Tasks.Compile.ElixirTest do
     end)
   end
 
+  test "recompiles with --force-elixir" do
+    in_fixture("no_mixfile", fn ->
+      Mix.Project.push(MixTest.Case.Sample)
+      assert Mix.Task.run("compile") == {:ok, []}
+      purge([A, B])
+
+      # Now we have a noop
+      Mix.Task.clear()
+      assert Mix.Task.run("compile") == {:noop, []}
+
+      # --force-elixir
+      Mix.Task.clear()
+      assert Mix.Task.run("compile", ["--verbose", "--force-elixir"]) == {:ok, []}
+      assert_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+    end)
+  end
+
   test "compiles files with autoload disabled" do
     in_fixture("no_mixfile", fn ->
       Mix.Project.push(MixTest.Case.Sample)