Promise lib

Author: Stephan Brandauer

modules/standard/Data/Promise.enc

@@ -0,0 +1,32 @@
+-- Promises are futures that you can fulfil by explictly calling a method that you pass a value.
+module Promise
+
+-- Create a promise, together with a future that can be
+-- fulfilled using the promise:
+-- Once you call fulfil(..) on the promise object, the
+-- future returned by this call will be fulfilled.
+fun mkPromise[t]() : (Fut[t], Promise[t])
+  val f = EMBED (Fut[t]) future_mk(_ctx, _enc__type_t); END
+  (f, new Promise(f))
+end
+
+-- This should be linear, but we're hitting issue #770 then
+-- in the mean time, do not alias promises!
+unsafe class Promise[t]
+  var f : Maybe[Fut[t]]
+
+  def init(f : Fut[t]): unit
+    this.f = Just(f)
+  end
+
+  def fulfil(v : t): unit
+    match this.f with
+      case Just(f) =>
+          EMBED (unit) future_fulfil(_ctx, #{f}, #{v}); END
+          this.f = Nothing
+      end
+      case Nothing => assertTrue(false, "Promise is already fulfilled!")
+    end
+  end
+end
+

src/tests/encore/stdlib/Data/Promise.enc

@@ -0,0 +1,35 @@
+module Promise
+
+import Data.Promise
+
+active class Worker
+  val p: Promise[int]
+  var cnt: int
+  def init(var p: Promise[int]) : unit
+    this.p = p
+    this.cnt = 0
+  end
+
+  def work() : unit
+    this.cnt = this.cnt+1
+    if this.cnt == 3 then
+      this.p.fulfil(123)
+    end
+  end
+end
+
+active class Main
+  def main() : unit
+    val tpl = mkPromise[int]()
+    match mkPromise[int]() with
+      case (f, p) =>
+        val w = new Worker(p)
+        for i <- [1..100] do
+          w!work()
+        end
+        val x = get(f)
+        println("gotten {}", x)
+      end
+    end
+  end
+end

src/tests/encore/stdlib/Data/Promise.out

@@ -0,0 +1 @@
+gotten 123