diff --git a/Makefile.impls b/Makefile.impls
index 6ac35b23e5..9485863b9d 100644
--- a/Makefile.impls
+++ b/Makefile.impls
@@ -34,7 +34,7 @@ wasm_MODE = wasmtime
 # Implementation specific settings
 #
 
-IMPLS = ada ada.2 awk bash basic bbc-basic c c.2 chuck clojure coffee common-lisp cpp crystal cs d dart \
+IMPLS = ada ada.2 awk bash basic bbc-basic bqn c c.2 chuck clojure coffee common-lisp cpp crystal cs d dart \
 	elisp elixir elm erlang es6 factor fantom fennel forth fsharp go groovy gnu-smalltalk \
 	guile haskell haxe hy io janet java java-truffle js jq julia kotlin livescript logo lua make mal \
 	matlab miniMAL nasm nim objc objpascal ocaml perl perl6 php picolisp pike plpgsql \
@@ -110,6 +110,7 @@ awk_STEP_TO_PROG =           impls/awk/$($(1)).awk
 bash_STEP_TO_PROG =          impls/bash/$($(1)).sh
 basic_STEP_TO_PROG =         $(basic_STEP_TO_PROG_$(basic_MODE))
 bbc-basic_STEP_TO_PROG =     impls/bbc-basic/$($(1)).bas
+bqn_STEP_TO_PROG =           impls/bqn/$($(1)).bqn
 c_STEP_TO_PROG =             impls/c/$($(1))
 c.2_STEP_TO_PROG =           impls/c.2/$($(1))
 chuck_STEP_TO_PROG =         impls/chuck/$($(1)).ck
diff --git a/README.md b/README.md
index 3fa1c13df2..01a5a1d3d9 100644
--- a/README.md
+++ b/README.md
@@ -52,6 +52,7 @@ FAQ](docs/FAQ.md) where I attempt to answer some common questions.
 | [Bash 4](#bash-4) | [Joel Martin](https://github.com/kanaka)  |
 | [BASIC](#basic-c64-and-qbasic) (C64 & QBasic) | [Joel Martin](https://github.com/kanaka) |
 | [BBC BASIC V](#bbc-basic-v) | [Ben Harris](https://github.com/bjh21) |
+| [BQN](#bqn) | [Hannu Hartikainen](https://github.com/dancek)  |
 | [C](#c) | [Joel Martin](https://github.com/kanaka)  |
 | [C #2](#c2) | [Duncan Watts](https://github.com/fungiblecog)  |
 | [C++](#c-1) | [Stephen Thirlwall](https://github.com/sdt) |
@@ -289,6 +290,17 @@ Or in ARM BBC BASIC V under RISC OS 3 or later:
 *Run stepX_YYY
 ```
 
+### BQN
+
+The BQN implementation requires [CBQN](https://github.com/dzaima/CBQN) as the non-standard system values `•_while_`, `•GetLine` and `•term.OutRaw` are used. Removing them would be easy, though -- they're just for convenience and REPL usability.
+
+There are no releases of CBQN at the time of writing, but any version from mid 2022 should work. Specifically, commit `88f6585` is known to work.
+
+```
+cd impls/bqn
+./run
+```
+
 ### C
 
 The C implementation of mal requires the following libraries (lib and
diff --git a/impls/bqn/Dockerfile b/impls/bqn/Dockerfile
new file mode 100644
index 0000000000..068d8622bf
--- /dev/null
+++ b/impls/bqn/Dockerfile
@@ -0,0 +1,12 @@
+FROM ubuntu:22.04
+
+RUN apt-get update && \
+    apt-get install -qqy git clang build-essential python3 python-is-python3
+RUN git clone https://github.com/dzaima/CBQN.git && \
+    cd CBQN && \
+    git reset --hard 88f65850fa6ac28bc50886c5942652f21d5be924 && \
+    make && \
+    make install && \
+    ln -s bqn /usr/local/bin/BQN
+RUN mkdir /mal
+WORKDIR /mal
diff --git a/impls/bqn/Makefile b/impls/bqn/Makefile
new file mode 100644
index 0000000000..7af3113c71
--- /dev/null
+++ b/impls/bqn/Makefile
@@ -0,0 +1,3 @@
+all:
+
+clean:
diff --git a/impls/bqn/core.bqn b/impls/bqn/core.bqn
new file mode 100644
index 0000000000..34741457ab
--- /dev/null
+++ b/impls/bqn/core.bqn
@@ -0,0 +1,118 @@
+⟨Atom,nil,Err,_chk,_chks⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨PrStr,PrStrR⟩ ← •Import "printer.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+
+Q ← {∾´'"'∾𝕩∾'"'}
+J ← {0=≠𝕩 ? "" ;
+     1=≠𝕩 ? ⊑𝕩 ;
+     ∾´(⊑𝕩)∾𝕨∾𝕨J 1↓𝕩}
+E ← {𝕊 ⟨t‿a,s‿b⟩:
+      {(⊑t∊3‿4) ∧ ⊑s∊3‿4 ?
+       {(≠a)=≠b ? ∧´a E¨b ; 0};
+       (t≡s)∧a≡b} ;
+     {2<≠𝕩 ? ∧´E´˘2↕𝕩 ; 1}𝕩}
+
+ns ← ⟨
+  "+"‿{1∾+´1⊏˘>𝕩}
+  "-"‿{1∾-´1⊏˘>𝕩}
+  "*"‿{1∾×´1⊏˘>𝕩}
+  "/"‿{1∾⌊∘÷´1⊏˘>𝕩}
+
+  "="‿{7∾E𝕩}
+  "<"‿{7∾∧´<´˘2↕1⊸⊑¨𝕩}
+  "<="‿{7∾∧´≤´˘2↕1⊸⊑¨𝕩}
+  ">"‿{7∾∧´>´˘2↕1⊸⊑¨𝕩}
+  ">="‿{7∾∧´≥´˘2↕1⊸⊑¨𝕩}
+
+  "empty?"‿{7∾0=≠1⊑⊑𝕩}
+  "count"‿{1∾≠1⊑⊑𝕩}
+
+  "bqn-show"‿{•Show ⊑ 𝕩}
+  "pr-str"‿{2∾<" "J PrStrR¨𝕩}
+  "str"‿{2∾<""J PrStr¨𝕩}
+  "prn"‿{•Out " "J PrStrR¨𝕩 ⋄ nil}
+  "println"‿{•Out " "J PrStr¨𝕩 ⋄ nil}
+
+  "read-string"‿{ReadStr 1⊑⊑𝕩}
+  "slurp"‿{2∾<•FChars 1⊑⊑𝕩}
+
+  "atom"‿{11∾Atom ⊑𝕩}
+  "atom?"‿{7∾11=⊑⊑𝕩}
+  "deref"‿{𝕊 ⟨11‿a⟩: a.Deref@; Err "deref: not an atom"}
+  "reset!"‿{
+    𝕊 ⟨11‿a,v⟩: a.Reset v;
+    Err "reset!: not an atom"}
+  "swap!"‿{
+    ⟨t‿a,fn⟩ ← 2↑𝕩
+    args ← (<a.Deref@) ∾ 2↓𝕩
+    f ← {9‿f: f; 10‿x‿y‿z‿f: f}fn
+    a.Reset F args}
+
+  "cons"‿{𝕊 x‿⟨t,xs⟩: 3∾<(<x)∾xs ; Err "cons"}
+  "concat"‿{𝕊 ⟨⟩:3‿⟨⟩; 3∾<∾´1⊸⊑¨𝕩}
+
+  "nth"‿{𝕊 ⟨t‿xs,1‿n⟩: {n<≠xs ? n⊑xs ; Err "out of bounds"}}
+  "first"‿{S ⟨t‿xs⟩: {0<≠xs ? ⊑xs ; nil}; nil}
+  "rest"‿{𝕊 ⟨t‿⟨⟩⟩: 3‿⟨⟩; 𝕊 ⟨t‿xs⟩: 3∾<1↓xs; 3‿⟨⟩}
+
+  "throw"‿{𝕊 ⟨x⟩: ¯1‿x}
+
+  "apply"‿{𝕊
+    fn ← {9‿f:f; 10‿b‿a‿e‿f: f}⊑𝕩
+    args ← (¯1↓1↓𝕩)∾1⊑¯1⊑𝕩
+    Fn _chks args}
+  "map"‿{𝕊
+    fn ← {9‿f:f; 10‿b‿a‿e‿f: f}⊑𝕩
+    {3∾<𝕩}_chks{Fn ⟨𝕩⟩}¨ 1⊑1⊑𝕩}
+
+  "nil?"‿{𝕊 ⟨8‿⟨⟩⟩: 7‿1; 7‿0}
+  "true?"‿{𝕊 ⟨7‿1⟩: 7‿1; 7‿0}
+  "false?"‿{𝕊 ⟨7‿0⟩: 7‿1; 7‿0}
+  "symbol?"‿{𝕊 ⟨0‿x⟩: 7‿1; 7‿0}
+  "keyword?"‿{𝕊 ⟨6‿x⟩: 7‿1; 7‿0}
+  "vector?"‿{𝕊 ⟨4‿x⟩: 7‿1; 7‿0}
+  "list?"‿{𝕊 ⟨3‿x⟩: 7‿1; 7‿0}
+  "map?"‿{𝕊 ⟨5‿x⟩: 7‿1; 7‿0}
+  "sequential?"‿{𝕊 ⟨3‿x⟩: 7‿1; 𝕊 ⟨4‿x⟩: 7‿1; 7‿0}
+  "string?"‿{𝕊 ⟨2‿x⟩: 7‿1; 7‿0}
+  "number?"‿{𝕊 ⟨1‿x⟩: 7‿1; 7‿0}
+  "fn?"‿{7∾{9:1;10:1;0}⊑⊑𝕩}
+
+  "symbol"‿{0∾<1⊑⊑𝕩}
+  "keyword"‿{𝕊 ⟨6‿kw⟩: 6‿kw;
+             𝕊 ⟨2‿s⟩: 6∾<':'∾s}
+  "list"‿{3‿𝕩}
+  "vector"‿{4‿𝕩}
+  "hash-map"‿{5‿𝕩}
+  "vec"‿{𝕊 ⟨4‿x⟩: 4‿x; 𝕊 ⟨3‿x⟩: 4‿x}
+
+  "keys"‿{𝕊 ⟨5‿xs⟩: 3∾<⥊⊏˘∘‿2⥊xs}
+  "vals"‿{𝕊 ⟨5‿xs⟩: 3∾<⥊1⊏˘∘‿2⥊xs}
+  "get"‿{𝕊 ⟨5‿xs,k⟩: 1⊑@‿nil∾˜⥊(k⊸≡˘⊑˘)⊸/∘‿2⥊xs; nil}
+  "contains?"‿{𝕊 ⟨5‿xs,k⟩: 7∾×+´k⊸≡˘⊑˘∘‿2⥊xs}
+  "dissoc"‿{𝕊 ⟨x⟩: x;
+    ⟨t‿xs,k⟩ ← 2↑𝕩
+    𝕊 (2↓𝕩)∾˜<5∾<⥊(k⊸≢˘⊑˘)⊸/∘‿2⥊xs}
+  "assoc"‿{𝕊 ⟨x⟩: x;
+    ⟨t‿xs,k,v⟩ ← 3↑𝕩
+    𝕊 (3↓𝕩)∾˜<5∾<k‿v∾˜⥊(k⊸≢˘⊑˘)⊸/∘‿2⥊xs}
+
+  "readline"‿{𝕊 ⟨2‿s⟩:
+    •term.OutRaw s
+    in ← •GetLine 0
+    {in≡@ ? nil ; 2‿in}}
+
+  "time-ms"‿{𝕊⋄1∾⌊1000וMonoTime@}
+
+  "meta"‿(¯1‿"NYI")
+  "with-meta"‿(¯1‿"NYI")
+  "seq"‿(¯1‿"NYI")
+  "conj"‿(¯1‿"NYI")
+⟩
+
+core ⇐ Env@
+{𝕊 kw‿f: core.Set kw‿(9‿f)}¨ns
+
+core.Set "*host-language*"‿(2‿"BQN")
+core.Set "*ARGV*"‿⟨3,⟨⟩⟩
diff --git a/impls/bqn/env.bqn b/impls/bqn/env.bqn
new file mode 100644
index 0000000000..ecd71005c3
--- /dev/null
+++ b/impls/bqn/env.bqn
@@ -0,0 +1,14 @@
+⟨Err⟩ ← •Import "globals.bqn"
+
+Env ⇐ {𝕊 outer:
+  d ⇐ ↕0‿2
+  Set ⇐ {𝕊 k‿v:
+    d ↩ k‿v∾((<k)≢˘⊏˘)⊸/d
+  }
+  Get ⇐ {𝕊 k: {
+    i ← ⊑(⊏˘d)⊐<k
+    i<⊑≢d ? i‿1⊑d ;
+    outer≠@ ? outer.Get k ;
+    Err "'"∾k∾"' not found"
+  }}
+}
diff --git a/impls/bqn/globals.bqn b/impls/bqn/globals.bqn
new file mode 100644
index 0000000000..e39c777bf9
--- /dev/null
+++ b/impls/bqn/globals.bqn
@@ -0,0 +1,9 @@
+nil ⇐ 8‿⟨⟩
+
+Atom⇐ {𝕊 v:
+  Reset ⇐ {v↩𝕩}
+  Deref ⇐ {𝕊⋄v}
+}
+Err ⇐ {¯1‿⟨2,𝕩⟩}
+_chk ⇐ {¯1=⊑⎊0𝕩 ? 𝕩 ; 𝕨𝔽𝕩}
+_chks ⇐ {⊑¯1∊⊑¨𝕩 ? (⊑(⊑¨𝕩)⊐¯1)⊑𝕩 ; 𝕨𝔽𝕩}
diff --git a/impls/bqn/printer.bqn b/impls/bqn/printer.bqn
new file mode 100644
index 0000000000..40090c26ee
--- /dev/null
+++ b/impls/bqn/printer.bqn
@@ -0,0 +1,31 @@
+Lst ← {0=≠𝕩 ? "" ; {𝕨∾" "∾𝕩}´(𝕨⊸P¨𝕩)}
+P ← {
+  r 𝕊 ¯1‿x: "ERROR: "∾r𝕊x;
+  r 𝕊 12‿x: "#macro";
+  r 𝕊 11‿a: "(atom "∾(r P a.Deref@)∾")";
+  r 𝕊 10‿x‿y‿z‿f: "#function";
+  r 𝕊 9‿x: "#function";
+  r 𝕊 8‿x: "nil";
+  r 𝕊 7‿0: "false";
+  r 𝕊 7‿1: "true";
+  r 𝕊 6‿kw: kw;
+  r 𝕊 5‿l: "{"∾(r Lst l)∾"}";
+  r 𝕊 4‿l: "["∾(r Lst l)∾"]";
+  r 𝕊 3‿l: "("∾(r Lst l)∾")";
+  0 𝕊 2‿s: s;
+  1 𝕊 2‿s:
+    ∾´{
+      𝕊 '"': "\""";
+      𝕊 '
+': "\n";
+      𝕊 '\': "\\";
+      𝕊 @: """";
+      ""∾𝕩
+    }¨(@∾s∾@);
+  r 𝕊 1‿n: {n<0?"-";""}∾•Fmt |n;
+  r 𝕊 0‿x: x;
+  "ERROR printing: "∾(@+10)∾•Fmt 𝕩
+}
+
+{PrStr  ⇐ 0⊸P
+ PrStrR ⇐ 1⊸P}
diff --git a/impls/bqn/reader.bqn b/impls/bqn/reader.bqn
new file mode 100644
index 0000000000..dd757fa6b6
--- /dev/null
+++ b/impls/bqn/reader.bqn
@@ -0,0 +1,129 @@
+⟨nil⟩ ← •Import "globals.bqn"
+# Types:
+# ¯1 error
+# 0 symbol
+# 1 int
+# 2 string
+# 3 list
+# 4 vector
+# 5 hashmap
+# 6 keyword
+# 7 boolean
+# 8 nil
+# 9 function
+# 10 fn*
+# 11 atom
+# 12 macro
+
+Reader ← {𝕊 tokens:
+  r ← {
+    ts ← tokens
+    Peek ⇐ {𝕊 ⋄ 0=≠ts ? @; ⊑ts}
+    Next ⇐ {𝕊
+      t ← r.Peek@
+      ts ↩ 1↓ts
+      t
+    }
+  }
+}
+
+T ← {𝕊 s:
+  v←⟨⟩
+  {𝕊
+    @=⊑s ? •Exit 0 ;
+    '@'=⊑s ? v∾↩<"@" ⋄ s↩1↓s ;
+    "~@"≡2↑s ? v∾↩<"~@" ⋄ s↩2↓s ;
+    ⊑(⊑s)∊" ,"∾@+10 ? s↩1↓s ;
+    ⊑(⊑s)∊"[]{}()'`~" ? v∾↩<≍⊑s ⋄ s↩1↓s ;
+    ';'=⊑s ?
+      o←⟨⟩
+      {𝕊
+        o ∾↩ ⊑s
+        s ↩ 1↓s
+        {0=≠s ? 0 ; (⊑s) ≠ @+10}
+      } •_while_⊢1
+      v∾↩<o ;
+    """"≡s ? •Out "unbalanced quotes: """ ⋄ s↩⟨⟩;
+    '"'=⊑s ?
+      o‿p‿r ← """"‿1‿1
+      {𝕊
+        s ↩ 1↓s
+        c ← ⊑s
+        o ∾↩ c
+        q ← p∧c='"'
+        {p ? p↩c≠'\' ; p↩1}
+        {q?@;r ↩ 1<≠s}
+        r∧¬q
+      } •_while_⊢1
+      {r?@;•Out "unbalanced quotes: "∾o}
+      v∾↩<o ⋄ s↩1↓s;
+    o←⟨⟩
+    {𝕊
+      o ∾↩ ⊑s
+      s ↩ 1↓s
+      {0=≠s ? 0 ; ¬⊑(⊑s)∊"[]{}()'""`~,; "∾@+10}
+    } •_while_⊢1
+    v∾↩<o
+  }•_while_{𝕊 ⋄ 0≠≠s}@
+  v
+}
+
+# Thanks to Marshall for writing this version of readString and
+# suhr for suggesting the `out` value of Ctrl-* characters! (My
+# version was verbose functional code while this is array style.)
+readString ← {
+  in  ← "abefnrtv"
+  out ← "GH[LJMIK"-64
+  diff← (out-in)∾0
+  {
+    m ← » bs ← <`𝕩='\'
+    (¬bs) / (diff⊏˜in⊸⊐)⊸+⌾(m⊸/) 𝕩
+  }
+}
+
+Int ← {10⊸×⊸+˜´'0'-˜⌽𝕩}
+nums ← "0123456789"
+Atom ← {
+  𝕊 "true": 7‿1 ;
+  𝕊 "false": 7‿0 ;
+  𝕊 "nil": nil ;
+  𝕊 a: {'"': 2∾<ReadString 1↓¯1↓a ;
+   ':': 6‿a ;
+   ';': @ ;
+   ⊑𝕩∊nums ? 1∾Int a ;
+   (∧´(1↓a)∊nums)∧(𝕩='-')∧1<≠a ? 1∾-Int 1↓a ;
+   0‿a }⊑a
+}
+
+ReadList ← {𝕊 r‿t‿e:
+  l←⟨⟩
+  {𝕊
+    {@: t ↩ ¯1 ⋄ l ↩ "unbalanced parens" ⋄ 0;
+     𝕩≡e ? r.Next@ ⋄ 0;
+     v ← ReadForm r
+     {v≡@ ? @; l∾↩<v}
+     1
+    }r.Peek@
+  }•_while_⊢1
+  t‿l
+}
+
+ReadForm ← {𝕊 r:
+  {"(": ReadList r‿3‿")" ;
+   "[": ReadList r‿4‿"]" ;
+   "{": ReadList r‿5‿"}" ;
+   "@": 3‿⟨0‿"deref", ReadForm r⟩;
+   "'": 3‿⟨0‿"quote", ReadForm r⟩;
+   "`": 3‿⟨0‿"quasiquote", ReadForm r⟩;
+   "~": 3‿⟨0‿"unquote", ReadForm r⟩;
+   "~@": 3‿⟨0‿"splice-unquote", ReadForm r⟩;
+   Atom 𝕩
+  }r.Next@
+}
+
+{
+  Tokenize ⇐ T
+  ReadStr ⇐ {
+    v ← ReadForm Reader Tokenize 𝕩
+    v≢@ ? v ; nil}
+}
diff --git a/impls/bqn/run b/impls/bqn/run
new file mode 100755
index 0000000000..606198a117
--- /dev/null
+++ b/impls/bqn/run
@@ -0,0 +1,2 @@
+#!/bin/bash
+exec BQN $(dirname $0)/${STEP:-stepA_mal}.bqn "${@}"
diff --git a/impls/bqn/step0_repl.bqn b/impls/bqn/step0_repl.bqn
new file mode 100644
index 0000000000..1a50ad28d7
--- /dev/null
+++ b/impls/bqn/step0_repl.bqn
@@ -0,0 +1,11 @@
+READ ← ⊢
+EVAL ← ⊢
+PRINT ← ⊢
+Rep ← PRINT∘EVAL∘READ
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+} @
diff --git a/impls/bqn/step1_read_print.bqn b/impls/bqn/step1_read_print.bqn
new file mode 100644
index 0000000000..e30134b0c4
--- /dev/null
+++ b/impls/bqn/step1_read_print.bqn
@@ -0,0 +1,14 @@
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+
+READ ← ReadStr
+EVAL ← ⊢
+PRINT ← PrStrR
+Rep ← PRINT∘EVAL∘READ
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step2_eval.bqn b/impls/bqn/step2_eval.bqn
new file mode 100644
index 0000000000..6f227d59d3
--- /dev/null
+++ b/impls/bqn/step2_eval.bqn
@@ -0,0 +1,41 @@
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+
+replEnv ← >⟨
+  "+"‿1‿(+´)
+  "-"‿1‿(-´)
+  "*"‿1‿(×´)
+  "/"‿1‿(÷´)
+⟩
+Undef ← {@‿¯1‿(<"undefined: "∾𝕩)}
+
+EvalAst ← {env 𝕊 t‿v:
+  {0: idx ← ⊑((⊏˘env)⊐(<v))
+      {idx<≠env ? idx⊏env ; Undef v};
+   3: env⊸EVAL¨v ;
+   t‿v
+  }t
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {
+  env 𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+  env 𝕊 3‿xs: {
+    ys ← env EvalAst 3‿xs
+    n‿t‿f ← ⊑ys
+    zs ← 1↓ys
+    t∾F 1⊸↓¨zs
+  } ;
+  env 𝕊 4‿xs: 4∾<env⊸EVAL¨xs ;
+  env 𝕊 5‿xs: 5∾<env⊸EVAL¨xs ;
+  env 𝕊 x: env EvalAst x
+}
+Rep ← PRINT∘{replEnv EVAL 𝕩}∘READ
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step3_env.bqn b/impls/bqn/step3_env.bqn
new file mode 100644
index 0000000000..437370d674
--- /dev/null
+++ b/impls/bqn/step3_env.bqn
@@ -0,0 +1,48 @@
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStr⟩ ← •Import "printer.bqn"
+
+ns ← Env@
+ns.Set "+"‿{1∾+´1⊏˘>𝕩}
+ns.Set "-"‿{1∾-´1⊏˘>𝕩}
+ns.Set "*"‿{1∾×´1⊏˘>𝕩}
+ns.Set "/"‿{1∾⌊∘÷´1⊏˘>𝕩}
+
+EvalAst ← {env 𝕊 t‿v:
+  {0: env.Get v ;
+   3: env⊸EVAL¨v ;
+   t‿v
+  }t
+}
+
+READ ← ReadStr
+PRINT ← PrStr
+EVAL ← {
+  env 𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+  env 𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+    v ← env EVAL x
+    {¯1:@;env.Set (<k)∾<v}⊑v
+    v ;
+  outer 𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+    inner ← Env outer
+    {𝕊
+      {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+      binds 2⊸↓↩
+    }•_while_{𝕊 ⋄ 0<≠binds}@
+    inner EVAL exp ;
+  env 𝕊 3‿xs:
+    ys ← env EvalAst 3‿xs
+    f ← ⊑ys
+    F 1↓ys ;
+  env 𝕊 4‿xs: 4∾<env⊸EVAL¨xs ;
+  env 𝕊 5‿xs: 5∾<env⊸EVAL¨xs ;
+  env 𝕊 x: env EvalAst x
+}
+Rep ← PRINT∘{ns EVAL 𝕩}∘READ
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step4_if_fn_do.bqn b/impls/bqn/step4_if_fn_do.bqn
new file mode 100644
index 0000000000..d95d778cb5
--- /dev/null
+++ b/impls/bqn/step4_if_fn_do.bqn
@@ -0,0 +1,70 @@
+⟨nil⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {env 𝕊 t‿v:
+  {0: env.Get v ;
+   3: env⊸EVAL¨v ;
+   t‿v
+  }t
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {
+  # builtin special forms
+  env 𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+    v ← env EVAL x
+    {¯1:@;env.Set (<k)∾<v}⊑v
+    v ;
+  outer 𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+    inner ← Env outer
+    {𝕊
+      {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+      binds 2⊸↓↩
+    }•_while_{𝕊 ⋄ 0<≠binds}@
+    inner EVAL exp ;
+  env 𝕊 3‿⟨0‿"if",c,t,f⟩:
+    env EVAL {8‿x:f; 7‿0:f; t} env EVAL c ;
+  env 𝕊 3‿⟨0‿"if",c,t⟩:
+    env EVAL {8‿x:nil; 7‿0:nil; t} env EVAL c ;
+  outer 𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+    9‿{𝕊 xs:
+      as ← args
+      inner ← Env outer
+      {𝕊
+        {0‿"&": inner.Set (<1⊑1⊑as)∾<3∾<inner EVAL¨xs ⋄ as↩⟨⟩;
+         0‿kw: inner.Set (<kw)∾<inner EVAL ⊑xs}⊑as
+        as 1⊸↓↩
+        xs 1⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠as}@
+      inner EVAL exp} ;
+
+  # variable-length special forms
+  env 𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+  env 𝕊 3‿xs:{
+    0‿"do": ¯1⊑env⊸EVAL¨1↓xs
+    ; ys ← env EvalAst 3‿xs          # function application
+      f ← ⊑ys
+      {9‿f: F 1↓ys ;
+       ¯1‿x: f;
+       ¯1∾<"not a function: "∾PrStrR f} f
+    }⊑xs ;
+
+  # basic forms
+  env 𝕊 4‿xs: 4∾<env⊸EVAL¨xs ;
+  env 𝕊 5‿xs: 5∾<env⊸EVAL¨xs ;
+  env 𝕊 x: env EvalAst x
+}
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+Rep "(def! not (fn* (a) (if a false true)))"
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step5_tco.bqn b/impls/bqn/step5_tco.bqn
new file mode 100644
index 0000000000..08172c8c82
--- /dev/null
+++ b/impls/bqn/step5_tco.bqn
@@ -0,0 +1,89 @@
+⟨nil⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {env 𝕊 t‿v:
+  {0: env.Get v ;
+   3: env⊸EVAL¨v ;
+   t‿v
+  }t
+}
+
+SetParams ← {env 𝕊 args‿xs:
+  {𝕊
+    {0‿"&": env.Set (<1⊑1⊑args)∾<3∾<env EVAL¨xs ⋄ args↩⟨⟩;
+     0‿kw: env.Set (<kw)∾<env EVAL ⊑xs}⊑args
+    args 1⊸↓↩
+    xs 1⊸↓↩
+  }•_while_{𝕊 ⋄ 0<≠args}@
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {e 𝕊 ast:
+  # this loop runs as long as @ is returned, ie. typically once
+  {𝕊 ⋄ {
+    # builtin special forms
+    𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@;e.Set (<k)∾<v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+      inner ← Env e
+      {𝕊
+        {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+        binds 2⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠binds}@
+      e ↩ inner
+      ast ↩ exp
+      @;
+    𝕊 3‿⟨0‿"if",c,t,f⟩:
+      ast ↩ {8‿x:f; 7‿0:f; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"if",c,t⟩:
+      ast ↩ {8‿x:nil; 7‿0:nil; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+      10‿exp‿args‿e‿{𝕊 xs:
+        inner ← Env e
+        inner SetParams args‿xs
+        inner EVAL exp} ;
+
+    # variable-length special forms
+    𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+    𝕊 3‿xs:{
+      0‿"do":
+        e⊸EVAL¨¯1↓1↓xs
+        ast ↩ ¯1⊑xs
+        @
+      ; ys ← e EvalAst 3‿xs          # function application
+        f ← ⊑ys
+        {9‿f: F 1↓ys ;
+         10‿exp‿args‿e2‿fn:
+           ast ↩ exp
+           e ↩ Env e2
+           e SetParams args‿(1↓ys)
+           @;
+         ¯1‿x: f;
+         ¯1∾<"not a function: "∾PrStrR f} f
+      }⊑xs ;
+
+    # basic forms
+    𝕊 4‿xs: 4∾<e⊸EVAL¨xs ;
+    𝕊 5‿xs: 5∾<e⊸EVAL¨xs ;
+    𝕊 x: e EvalAst x
+  } ast
+}•_while_{𝕩≡@}@}
+
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+Rep "(def! not (fn* (a) (if a false true)))"
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step6_file.bqn b/impls/bqn/step6_file.bqn
new file mode 100644
index 0000000000..5a6fbe5ffd
--- /dev/null
+++ b/impls/bqn/step6_file.bqn
@@ -0,0 +1,94 @@
+⟨nil⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {env 𝕊 t‿v:
+  {0: env.Get v ;
+   3: env⊸EVAL¨v ;
+   t‿v
+  }t
+}
+
+SetParams ← {env 𝕊 args‿xs:
+  {𝕊
+    {0‿"&": env.Set (<1⊑1⊑args)∾<3∾<env EVAL¨xs ⋄ args↩⟨⟩;
+     0‿kw: env.Set (<kw)∾<env EVAL ⊑xs}⊑args
+    args 1⊸↓↩
+    xs 1⊸↓↩
+  }•_while_{𝕊 ⋄ 0<≠args}@
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {e 𝕊 ast:
+  # this loop runs as long as @ is returned, ie. typically once
+  {𝕊 ⋄ {
+    # builtin special forms
+    𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@;e.Set (<k)∾<v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+      inner ← Env e
+      {𝕊
+        {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+        binds 2⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠binds}@
+      e ↩ inner
+      ast ↩ exp
+      @;
+    𝕊 3‿⟨0‿"if",c,t,f⟩:
+      ast ↩ {8‿x:f; 7‿0:f; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"if",c,t⟩:
+      ast ↩ {8‿x:nil; 7‿0:nil; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+      10‿exp‿args‿e‿{𝕊 xs:
+        inner ← Env e
+        inner SetParams args‿xs
+        inner EVAL exp} ;
+
+    # variable-length special forms
+    𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+    𝕊 3‿xs:{
+      0‿"do":
+        e⊸EVAL¨¯1↓1↓xs
+        ast ↩ ¯1⊑xs
+        @
+      ; ys ← e EvalAst 3‿xs          # function application
+        f ← ⊑ys
+        {9‿f: F 1↓ys ;
+         10‿exp‿args‿e2‿fn:
+           ast ↩ exp
+           e ↩ Env e2
+           e SetParams args‿(1↓ys)
+           @;
+         ¯1‿x: f;
+         ¯1∾<"not a function: "∾PrStrR f} f
+      }⊑xs ;
+
+    # basic forms
+    𝕊 4‿xs: 4∾<e⊸EVAL¨xs ;
+    𝕊 5‿xs: 5∾<e⊸EVAL¨xs ;
+    𝕊 x: e EvalAst x
+  } ast
+}•_while_{𝕩≡@}@}
+
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+core.Set "eval"‿(9‿{core EVAL ⊑𝕩})
+Rep "(def! load-file (fn* (f) (eval (read-string (str ""(do "" (slurp f) "" nil)"")))))"
+
+{0=≠•args ?
+  {
+    •term.OutRaw "user> "
+    line ← •GetLine 0
+    •Out Rep line
+    𝕊𝕩
+  }@ ;
+ core.Set "*ARGV*"‿(3∾<2∾⟜<¨1↓•args)
+ Rep "(load-file """∾(⊑•args)∾""")"
+}
diff --git a/impls/bqn/step7_quote.bqn b/impls/bqn/step7_quote.bqn
new file mode 100644
index 0000000000..54ef88e903
--- /dev/null
+++ b/impls/bqn/step7_quote.bqn
@@ -0,0 +1,109 @@
+⟨nil⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {env 𝕊 t‿v:
+  {0: env.Get v ;
+   3: env⊸EVAL¨v ;
+   t‿v
+  }t
+}
+
+SetParams ← {env 𝕊 args‿xs:
+  {𝕊
+    {0‿"&": env.Set (<1⊑1⊑args)∾<3∾<env EVAL¨xs ⋄ args↩⟨⟩;
+     0‿kw: env.Set (<kw)∾<env EVAL ⊑xs}⊑args
+    args 1⊸↓↩
+    xs 1⊸↓↩
+  }•_while_{𝕊 ⋄ 0<≠args}@
+}
+
+QQi ← {
+  𝕊 ⟨⟩: 3‿⟨⟩;
+  e ← ⊑𝕩
+  a ← QQi 1↓𝕩
+  {3‿⟨0‿"splice-unquote",x⟩: 3‿⟨0‿"concat", x, a⟩
+  ;3‿⟨0‿"cons", QQ e, a⟩
+  }e
+}
+QQ ← {
+  𝕊 3‿⟨⟩: 3‿⟨⟩;
+  𝕊 3‿⟨0‿"unquote",x⟩: x;
+  𝕊 3‿xs: QQi xs;
+  3∾< 0‿"quote" ⋈ 𝕩
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {e 𝕊 ast:
+  # this loop runs as long as @ is returned, ie. typically once
+  {𝕊 ⋄ {
+    # builtin special forms
+    𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@;e.Set (<k)∾<v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+      inner ← Env e
+      {𝕊
+        {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+        binds 2⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠binds}@
+      e ↩ inner
+      ast ↩ exp
+      @;
+    𝕊 3‿⟨0‿"if",c,t,f⟩:
+      ast ↩ {8‿x:f; 7‿0:f; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"if",c,t⟩:
+      ast ↩ {8‿x:nil; 7‿0:nil; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+      10‿exp‿args‿e‿{𝕊 xs:
+        inner ← Env e
+        inner SetParams args‿xs
+        inner EVAL exp} ;
+    𝕊 3‿⟨0‿"quote",x⟩: x;
+    𝕊 3‿⟨0‿"quasiquote",x⟩:
+      ast ↩ QQ x
+      @;
+
+    # variable-length special forms
+    𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+    𝕊 3‿xs:{
+      0‿"do":
+        e⊸EVAL¨¯1↓1↓xs
+        ast ↩ ¯1⊑xs
+        @
+      ; ys ← e EvalAst 3‿xs          # function application
+        f ← ⊑ys
+        {9‿f: F 1↓ys ;
+         10‿exp‿args‿e2‿fn:
+           ast ↩ exp
+           e ↩ Env e2
+           e SetParams args‿(1↓ys)
+           @;
+         ¯1‿x: f;
+         ¯1∾<"not a function: "∾PrStrR f} f
+      }⊑xs ;
+
+    # basic forms
+    𝕊 4‿xs: 4∾<e⊸EVAL¨xs ;
+    𝕊 5‿xs: 5∾<e⊸EVAL¨xs ;
+    𝕊 x: e EvalAst x
+  } ast
+}•_while_{𝕩≡@}@}
+
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+core.Set "eval"‿(9‿{core EVAL ⊑𝕩})
+Rep "(def! load-file (fn* (f) (eval (read-string (str ""(do "" (slurp f) "" nil)"")))))"
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step8_macros.bqn b/impls/bqn/step8_macros.bqn
new file mode 100644
index 0000000000..eaceb714bf
--- /dev/null
+++ b/impls/bqn/step8_macros.bqn
@@ -0,0 +1,133 @@
+⟨nil⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {
+  env 𝕊 t‿v:
+    {0: env.Get v ;
+     3: env⊸EVAL¨v ;
+     t‿v
+    }t ;
+  𝕩
+}
+
+SetParams ← {env 𝕊 args‿xs:
+  {𝕊
+    {0‿"&": env.Set (<1⊑1⊑args)∾<3∾<xs ⋄ args↩⟨⟩;
+     0‿kw: env.Set (<kw)∾<⊑xs}⊑args
+    args 1⊸↓↩
+    xs 1⊸↓↩
+  }•_while_{𝕊 ⋄ 0<≠args}@
+}
+
+QQi ← {
+  𝕊 ⟨⟩: 3‿⟨⟩;
+  e ← ⊑𝕩
+  a ← QQi 1↓𝕩
+  {3‿⟨0‿"splice-unquote",x⟩: 3‿⟨0‿"concat", x, a⟩
+  ;3‿⟨0‿"cons", QQ e, a⟩
+  }e
+}
+QQ ← {
+  𝕊 3‿⟨⟩: 3‿⟨⟩;
+  𝕊 3‿⟨0‿"unquote",x⟩: x;
+  𝕊 3‿xs: QQi xs;
+  3∾< 0‿"quote" ⋈ 𝕩
+}
+Mxp ← {
+  e 𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+  e 𝕊 3‿xs: {
+    0‿sym: {
+      12‿f: {
+        9‿fn: Fn 1↓xs;
+        10‿exp‿args‿e2‿fn: Fn 1↓xs} f ;
+      3‿xs
+    } e.Get sym ;
+    3‿xs
+  }⊑xs ;
+  𝕩
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {e 𝕊 ast:
+  # this loop runs as long as @ is returned, ie. typically once
+  {𝕊 ⋄ ast ↩ e Mxp ast ⋄ {
+    # builtin special forms
+    𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@;e.Set (<k)∾<v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"defmacro!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@; e.Set (<k)∾<12‿v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+      inner ← Env e
+      {𝕊
+        {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+        binds 2⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠binds}@
+      e ↩ inner
+      ast ↩ exp
+      @;
+    𝕊 3‿⟨0‿"if",c,t,f⟩:
+      ast ↩ {8‿x:f; 7‿0:f; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"if",c,t⟩:
+      ast ↩ {8‿x:nil; 7‿0:nil; t} e EVAL c
+      @;
+    𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+      10‿exp‿args‿e‿{𝕊 xs:
+        inner ← Env e
+        inner SetParams args‿xs
+        inner EVAL exp} ;
+    𝕊 3‿⟨0‿"quote",x⟩: x;
+    𝕊 3‿⟨0‿"quasiquote",x⟩:
+      ast ↩ QQ x
+      @;
+    𝕊 3‿⟨0‿"macroexpand",x⟩: e Mxp x;
+
+    # variable-length special forms
+    𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+    𝕊 3‿xs: {
+      0‿"do":
+        e⊸EVAL¨¯1↓1↓xs
+        ast ↩ ¯1⊑xs
+        @
+      ; # function application
+        ys ← e EvalAst 3‿xs
+        f ← ⊑ys
+        {9‿f: F 1↓ys ;
+         10‿exp‿args‿e2‿fn:
+           ast ↩ exp
+           e ↩ Env e2
+           e SetParams args‿(1↓ys)
+           @;
+         ¯1‿x: f;
+         ¯1∾<"not a function: "∾PrStrR f} f ;
+       e EvalAst 𝕩
+      }⊑xs ;
+
+    # basic forms
+    𝕊 4‿xs: 4∾<e⊸EVAL¨xs ;
+    𝕊 5‿xs: 5∾<e⊸EVAL¨xs ;
+    𝕊 x: e EvalAst x
+  } ast
+}•_while_{𝕩≡@}@}
+
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+core.Set "eval"‿(9‿{core EVAL ⊑𝕩})
+Rep "(def! not (fn* (a) (if a false true)))"
+Rep "(def! load-file (fn* (f) (eval (read-string (str ""(do "" (slurp f) "" nil)"")))))"
+Rep "(defmacro! cond (fn* (& xs) (if (> (count xs) 0) (list 'if (first xs) (if (> (count xs) 1) (nth xs 1) (throw ""odd number of forms to cond"")) (cons 'cond (rest (rest xs)))))))"
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/step9_try.bqn b/impls/bqn/step9_try.bqn
new file mode 100644
index 0000000000..da30e4752a
--- /dev/null
+++ b/impls/bqn/step9_try.bqn
@@ -0,0 +1,137 @@
+⟨Err,nil,_chk,_chks⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {
+  env 𝕊 t‿v:
+    {0: env.Get v ;
+     3: env⊸EVAL¨v ;
+     t‿v
+    }t ;
+  𝕩
+}
+
+SetParams ← {env 𝕊 args‿xs:
+  {𝕊
+    {0‿"&": env.Set (<1⊑1⊑args)∾<3∾<xs ⋄ args↩⟨⟩;
+     0‿kw: env.Set (<kw)∾<⊑xs}⊑args
+    args 1⊸↓↩
+    xs 1⊸↓↩
+  }•_while_{𝕊 ⋄ 0<≠args}@
+}
+
+QQi ← {
+  𝕊 ⟨⟩: 3‿⟨⟩;
+  e ← ⊑𝕩
+  a ← QQi 1↓𝕩
+  {3‿⟨0‿"splice-unquote",x⟩: 3‿⟨0‿"concat", x, a⟩
+  ;3‿⟨0‿"cons", QQ e, a⟩
+  }e
+}
+QQ ← {
+  𝕊 3‿⟨⟩: 3‿⟨⟩;
+  𝕊 3‿⟨0‿"unquote",x⟩: x;
+  𝕊 3‿xs: QQi xs;
+  3∾< 0‿"quote" ⋈ 𝕩
+}
+Mxp ← {
+  e 𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+  e 𝕊 3‿xs: {
+    0‿sym: {
+      12‿f: {
+        9‿fn: Fn 1↓xs;
+        10‿exp‿args‿e2‿fn: Fn 1↓xs} f ;
+      3‿xs
+    } e.Get sym ;
+    3‿xs
+  }⊑xs ;
+  𝕩
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {e 𝕊 ast:
+  # this loop runs as long as @ is returned, ie. typically once
+  {𝕊 ⋄ ast ↩ e Mxp ast ⋄ {
+    # builtin special forms
+    𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@;e.Set (<k)∾<v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"defmacro!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@; e.Set (<k)∾<12‿v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+      inner ← Env e
+      {𝕊
+        {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+        binds 2⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠binds}@
+      e ↩ inner
+      ast ↩ exp
+      @;
+    𝕊 3‿⟨0‿"if",c,t,f⟩:
+      {ast ↩ {8‿x:f; 7‿0:f; t}𝕩
+       @}_chk e EVAL c ;
+    𝕊 3‿⟨0‿"if",c,t⟩:
+      {ast ↩ {8‿x:nil; 7‿0:nil; t}𝕩
+       @}_chk e EVAL c ;
+    𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+      10‿exp‿args‿e‿{𝕊 xs:
+        inner ← Env e
+        inner SetParams args‿xs
+        inner EVAL exp} ;
+    𝕊 3‿⟨0‿"quote",x⟩: x;
+    𝕊 3‿⟨0‿"quasiquote",x⟩:
+      ast ↩ QQ x
+      @;
+    𝕊 3‿⟨0‿"macroexpand",x⟩: e Mxp x;
+    𝕊 3‿⟨0‿"try*",a,3‿⟨0‿"catch*",0‿b,c⟩⟩:
+      {¯1‿x:
+        e2 ← Env e
+        e2.Set b‿x
+        e2 EVAL c
+      ; 𝕩}e EVAL a ;
+
+    # variable-length special forms
+    𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+    𝕊 3‿xs: {
+      0‿"do":
+        {𝕊 ⋄ ast ↩ ¯1⊑xs ⋄ @}_chks e⊸EVAL¨¯1↓1↓xs
+      ; # function application
+        ys ← e EvalAst 3‿xs
+        f ← ⊑ys
+        {9‿f: F _chks 1↓ys ;
+         10‿exp‿args‿e2‿fn:
+           ast ↩ exp
+           e ↩ Env e2
+           {e SetParams args‿𝕩 ⋄ @}_chks 1↓ys ;
+         ¯1‿x: f;
+         Err "not a function: "∾PrStrR f} f ;
+       e EvalAst 𝕩
+      }⊑xs ;
+
+    # basic forms
+    𝕊 4‿xs: {4∾<𝕩}_chks e⊸EVAL¨xs ;
+    𝕊 5‿xs: {5∾<𝕩}_chks e⊸EVAL¨xs ;
+    𝕊 ¯1‿x: ¯1‿x ;
+    𝕊 x: e EvalAst x
+  } ast
+}•_while_{𝕩≡@}@}
+
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+core.Set "eval"‿(9‿{core EVAL ⊑𝕩})
+Rep "(def! not (fn* (a) (if a false true)))"
+Rep "(def! load-file (fn* (f) (eval (read-string (str ""(do "" (slurp f) "" nil)"")))))"
+Rep "(defmacro! cond (fn* (& xs) (if (> (count xs) 0) (list 'if (first xs) (if (> (count xs) 1) (nth xs 1) (throw ""odd number of forms to cond"")) (cons 'cond (rest (rest xs)))))))"
+
+{
+  •Out "user> "
+  line ← •GetLine 0
+  •Out Rep line
+  𝕊𝕩
+}@
diff --git a/impls/bqn/stepA_mal.bqn b/impls/bqn/stepA_mal.bqn
new file mode 100644
index 0000000000..884be542b4
--- /dev/null
+++ b/impls/bqn/stepA_mal.bqn
@@ -0,0 +1,142 @@
+⟨Err,nil,_chk,_chks⟩ ← •Import "globals.bqn"
+⟨Env⟩ ← •Import "env.bqn"
+⟨ReadStr⟩ ← •Import "reader.bqn"
+⟨PrStrR⟩ ← •Import "printer.bqn"
+⟨core⟩ ← •Import "core.bqn"
+
+EvalAst ← {
+  env 𝕊 t‿v:
+    {0: env.Get v ;
+     3: env⊸EVAL¨v ;
+     t‿v
+    }t ;
+  𝕩
+}
+
+SetParams ← {env 𝕊 args‿xs:
+  {𝕊
+    {0‿"&": env.Set (<1⊑1⊑args)∾<3∾<xs ⋄ args↩⟨⟩;
+     0‿kw: env.Set (<kw)∾<⊑xs}⊑args
+    args 1⊸↓↩
+    xs 1⊸↓↩
+  }•_while_{𝕊 ⋄ 0<≠args}@
+}
+
+QQi ← {
+  𝕊 ⟨⟩: 3‿⟨⟩;
+  e ← ⊑𝕩
+  a ← QQi 1↓𝕩
+  {3‿⟨0‿"splice-unquote",x⟩: 3‿⟨0‿"concat", x, a⟩
+  ;3‿⟨0‿"cons", QQ e, a⟩
+  }e
+}
+QQ ← {
+  𝕊 3‿⟨⟩: 3‿⟨⟩;
+  𝕊 3‿⟨0‿"unquote",x⟩: x;
+  𝕊 3‿xs: QQi xs;
+  3∾< 0‿"quote" ⋈ 𝕩
+}
+Mxp ← {
+  e 𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+  e 𝕊 3‿xs: {
+    0‿sym: {
+      12‿f: {
+        9‿fn: Fn 1↓xs;
+        10‿exp‿args‿e2‿fn: Fn 1↓xs} f ;
+      3‿xs
+    } e.Get sym ;
+    3‿xs
+  }⊑xs ;
+  𝕩
+}
+
+READ ← ReadStr
+PRINT ← PrStrR
+EVAL ← {e 𝕊 ast:
+  # this loop runs as long as @ is returned, ie. typically once
+  {𝕊 ⋄ ast ↩ e Mxp ast ⋄ {
+    # builtin special forms
+    𝕊 3‿⟨0‿"def!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@;e.Set (<k)∾<v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"defmacro!",0‿k,x⟩:
+      v ← e EVAL x
+      {¯1:@; e.Set (<k)∾<12‿v}⊑v
+      v ;
+    𝕊 3‿⟨0‿"let*",t‿binds,exp⟩:
+      inner ← Env e
+      {𝕊
+        {⟨0‿kw,x⟩: inner.Set (<kw)∾<inner EVAL x}2↑binds
+        binds 2⊸↓↩
+      }•_while_{𝕊 ⋄ 0<≠binds}@
+      e ↩ inner
+      ast ↩ exp
+      @;
+    𝕊 3‿⟨0‿"if",c,t,f⟩:
+      {ast ↩ {8‿x:f; 7‿0:f; t}𝕩
+       @}_chk e EVAL c ;
+    𝕊 3‿⟨0‿"if",c,t⟩:
+      {ast ↩ {8‿x:nil; 7‿0:nil; t}𝕩
+       @}_chk e EVAL c ;
+    𝕊 3‿⟨0‿"fn*",t‿args,exp⟩:
+      10‿exp‿args‿e‿{𝕊 xs:
+        inner ← Env e
+        inner SetParams args‿xs
+        inner EVAL exp} ;
+    𝕊 3‿⟨0‿"quote",x⟩: x;
+    𝕊 3‿⟨0‿"quasiquote",x⟩:
+      ast ↩ QQ x
+      @;
+    𝕊 3‿⟨0‿"macroexpand",x⟩: e Mxp x;
+    𝕊 3‿⟨0‿"try*",a,3‿⟨0‿"catch*",0‿b,c⟩⟩:
+      {¯1‿x:
+        e2 ← Env e
+        e2.Set b‿x
+        e2 EVAL c
+      ; 𝕩}e EVAL a ;
+
+    # variable-length special forms
+    𝕊 3‿⟨⟩: 3‿⟨⟩ ;
+    𝕊 3‿xs: {
+      0‿"do":
+        {𝕊 ⋄ ast ↩ ¯1⊑xs ⋄ @}_chks e⊸EVAL¨¯1↓1↓xs
+      ; # function application
+        ys ← e EvalAst 3‿xs
+        f ← ⊑ys
+        {9‿f: F _chks 1↓ys ;
+         10‿exp‿args‿e2‿fn:
+           ast ↩ exp
+           e ↩ Env e2
+           {e SetParams args‿𝕩 ⋄ @}_chks 1↓ys ;
+         ¯1‿x: f;
+         Err "not a function: "∾PrStrR f} f ;
+       e EvalAst 𝕩
+      }⊑xs ;
+
+    # basic forms
+    𝕊 4‿xs: {4∾<𝕩}_chks e⊸EVAL¨xs ;
+    𝕊 5‿xs: {5∾<𝕩}_chks e⊸EVAL¨xs ;
+    𝕊 ¯1‿x: ¯1‿x ;
+    𝕊 x: e EvalAst x
+  } ast
+}•_while_{𝕩≡@}@}
+
+Rep ← PRINT∘{core EVAL 𝕩}∘READ
+
+core.Set "eval"‿(9‿{core EVAL ⊑𝕩})
+Rep "(def! not (fn* (a) (if a false true)))"
+Rep "(def! load-file (fn* (f) (eval (read-string (str ""(do "" (slurp f) "" nil)"")))))"
+Rep "(defmacro! cond (fn* (& xs) (if (> (count xs) 0) (list 'if (first xs) (if (> (count xs) 1) (nth xs 1) (throw ""odd number of forms to cond"")) (cons 'cond (rest (rest xs)))))))"
+
+{0=≠•args ?
+  Rep "(println (str ""Mal ["" *host-language* ""]""))"
+  {
+    •term.OutRaw "user> "
+    line ← •GetLine 0
+    •Out Rep line
+    𝕊𝕩
+  }@ ;
+ core.Set "*ARGV*"‿(3∾<2∾⟜<¨1↓•args)
+ Rep "(load-file """∾(⊑•args)∾""")"
+}