-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathUsdcVaultL2.spec
1644 lines (1243 loc) · 65.3 KB
/
UsdcVaultL2.spec
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// UsdcVaultL2.spec
using Psm3Mock as psm;
using SUsdsMock as susds;
using UsdcMock as usdc;
using UsdsMock as usds;
using RateProviderMock as rateProvider;
using SignerMock as signer;
using Auxiliar as aux;
methods {
// storage variables
function wards(address) external returns (uint256) envfree;
function totalSupply() external returns (uint256) envfree;
function balanceOf(address) external returns (uint256) envfree;
function allowance(address, address) external returns (uint256) envfree;
function nonces(address) external returns (uint256) envfree;
// immutables
function usdc() external returns (address) envfree;
//
function DOMAIN_SEPARATOR() external returns (bytes32) envfree;
function PERMIT_TYPEHASH() external returns (bytes32) envfree;
//
function psm.pocket() external returns (address) envfree;
function susds.allowance(address, address) external returns (uint256) envfree;
function susds.balanceOf(address) external returns (uint256) envfree;
function susds.totalSupply() external returns (uint256) envfree;
function usdc.allowance(address, address) external returns (uint256) envfree;
function usdc.balanceOf(address) external returns (uint256) envfree;
function usdc.totalSupply() external returns (uint256) envfree;
function usds.balanceOf(address) external returns (uint256) envfree;
function aux.call_ecrecover(bytes32, uint8, bytes32, bytes32) external returns (address) envfree;
function aux.computeDigestForToken(bytes32, bytes32, address, address, uint256, uint256, uint256) external returns (bytes32) envfree;
function aux.signatureToVRS(bytes) external returns (uint8, bytes32, bytes32) envfree;
function aux.VRSToSignature(uint8, bytes32, bytes32) external returns (bytes) envfree;
function aux.size(bytes) external returns (uint256) envfree;
function rateProvider.getConversionRate() external returns (uint256) envfree;
//
function _.transfer(address,uint256) external => DISPATCHER(true);
function _.transferFrom(address,address,uint256) external => DISPATCHER(true);
function _.isValidSignature(bytes32, bytes) external => DISPATCHER(true);
}
definition RAY() returns mathint = 10^27;
definition _min(mathint x, mathint y) returns mathint = x < y ? x : y;
definition defCeilDiv(mathint a, mathint b) returns mathint = b == 0 ? a / b : (a == 0 ? 0 : (a - 1) / b + 1);
definition defConvertToSUsds(mathint amount, mathint assetPrecision, bool roundUp)
returns mathint = rateProvider.getConversionRate() == 0 ? 0 :
!roundUp ? amount * 10^27 / rateProvider.getConversionRate() * psm._susdsPrecision / assetPrecision
: defCeilDiv(defCeilDiv(amount * 10^27, rateProvider.getConversionRate()) * psm._susdsPrecision, assetPrecision);
definition defConvertFromSUsds(mathint amount, mathint assetPrecision, bool roundUp)
returns mathint = !roundUp ? amount * rateProvider.getConversionRate() / 10^27 * assetPrecision / psm._susdsPrecision
: defCeilDiv(defCeilDiv(amount * rateProvider.getConversionRate(), 10^27) * assetPrecision, psm._susdsPrecision);
definition defConvertOneToOne(mathint amount, mathint assetPrecision, mathint convertAssetPrecision, bool roundUp)
returns mathint = !roundUp ? amount * convertAssetPrecision / assetPrecision
: defCeilDiv(amount * convertAssetPrecision, assetPrecision);
definition defGetSwapQuote(address asset, address quoteAsset, mathint amount, bool roundUp)
returns mathint = (asset == usdc && quoteAsset == susds ? defConvertToSUsds(amount, psm._usdcPrecision, roundUp) : 0) +
(asset == susds && quoteAsset == usdc ? defConvertFromSUsds(amount, psm._usdcPrecision, roundUp) : 0);
ghost susds_balanceSum() returns mathint {
init_state axiom susds_balanceSum() == 0;
}
hook Sstore susds.balanceOf[KEY address a] uint256 balance (uint256 old_balance) {
havoc susds_balanceSum assuming susds_balanceSum@new() == susds_balanceSum@old() + balance - old_balance;
}
invariant susds_balanceSum_equals_totalSupply() susds_balanceSum() == to_mathint(susds.totalSupply())
filtered {
m -> m.selector != sig:upgradeToAndCall(address, bytes).selector
}
ghost balanceSum() returns mathint {
init_state axiom balanceSum() == 0;
}
hook Sstore balanceOf[KEY address a] uint256 balance (uint256 old_balance) {
havoc balanceSum assuming balanceSum@new() == balanceSum@old() + balance - old_balance && balanceSum@new() >= 0;
}
invariant balanceSum_equals_totalSupply() balanceSum() <= susds.balanceOf(currentContract) && susds.balanceOf(currentContract) + susds.balanceOf(psm) <= susds.totalSupply() && balanceSum() == to_mathint(totalSupply())
filtered {
m -> m.selector != sig:upgradeToAndCall(address, bytes).selector
} {
preserved {
requireInvariant susds_balanceSum_equals_totalSupply;
}
}
rule invariant_vault_total_supply_equals_susds_balance(method f) filtered { f -> !f.isView &&
f.selector != sig:upgradeToAndCall(address,bytes).selector } {
env e;
require totalSupply() == susds.balanceOf(currentContract);
if (f.selector == sig:exit(uint256, address, address).selector) {
uint256 shares;
address receiver;
address owner;
require receiver != currentContract;
exit(e, shares, receiver, owner);
} else {
calldataarg args;
f(e, args);
}
assert totalSupply() == susds.balanceOf(currentContract), "Assert 1";
}
rule invariant_vault_usdc_and_usds_balance_is_0(method f) filtered { f -> !f.isView } {
env e;
address pocket = psm.pocket();
require pocket != currentContract;
require usdc.balanceOf(currentContract) == 0;
require usds.balanceOf(currentContract) == 0;
if (f.selector == sig:withdraw(uint256,address,address).selector) {
uint256 assets;
address receiver;
address owner;
require receiver != currentContract;
withdraw(e, assets, receiver, owner);
} else if (f.selector == sig:withdraw(uint256,address,address,uint256).selector) {
uint256 assets;
address receiver;
address owner;
uint256 maxShares;
require receiver != currentContract;
withdraw(e, assets, receiver, owner, maxShares);
} else if (f.selector == sig:redeem(uint256,address,address).selector) {
uint256 shares;
address receiver;
address owner;
require receiver != currentContract;
redeem(e, shares, receiver, owner);
} else if (f.selector == sig:redeem(uint256,address,address,uint256).selector) {
uint256 shares;
address receiver;
address owner;
uint256 minAssets;
require receiver != currentContract;
redeem(e, shares, receiver, owner, minAssets);
} else {
calldataarg args;
f(e, args);
}
assert usdc.balanceOf(currentContract) == 0, "Assert 1";
assert usds.balanceOf(currentContract) == 0, "Assert 2";
}
rule invariant_maxDeposit(address anyAddr) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address receiver;
require receiver != 0 && receiver != currentContract;
uint256 maxDeposit = maxDeposit(e, anyAddr);
require maxDeposit > 0;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
// Contracts set up
require usdc.allowance(currentContract, psm) == max_uint256;
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(e.msg.sender) + usdc.balanceOf(currentContract) + usdc.balanceOf(psm) + usdc.balanceOf(psm.pocket());
require susds.totalSupply() >= susds.balanceOf(currentContract) + susds.balanceOf(psm) + susds.balanceOf(receiver);
// Sender assumptions
require usdc.allowance(e.msg.sender, currentContract) >= maxDeposit;
require usdc.balanceOf(e.msg.sender) >= maxDeposit;
// Avoid overflows
require maxDeposit * RAY() <= max_uint256;
require maxDeposit * RAY() / rate * psm._susdsPrecision <= max_uint256;
deposit@withrevert(e, maxDeposit, receiver);
bool lastRevertedValue = lastReverted;
mathint susdsBalanceOfPSMAfter = susds.balanceOf(psm);
mathint maxDepositAfter = maxDeposit(e, anyAddr);
assert !lastRevertedValue, "Assert 1";
assert susdsBalanceOfPSMAfter <= 10 * 10^12, "Assert 2";
assert maxDepositAfter <= 10 * 10^12, "Assert 3";
}
rule invariant_maxMint(address anyAddr) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address receiver;
require receiver != 0 && receiver != currentContract;
uint256 maxMint = maxMint(e, anyAddr);
require maxMint > 0;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
// Contracts set up
require usdc.allowance(currentContract, psm) == max_uint256;
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(e.msg.sender) + usdc.balanceOf(currentContract) + usdc.balanceOf(psm) + usdc.balanceOf(psm.pocket());
require susds.totalSupply() >= susds.balanceOf(currentContract) + susds.balanceOf(psm) + susds.balanceOf(receiver);
mathint assets = previewMint(e, maxMint);
// Sender assumptions
require usdc.allowance(e.msg.sender, currentContract) >= assets;
require usdc.balanceOf(e.msg.sender) >= assets;
// Avoid overflows
require maxMint * rate <= max_uint256;
require maxMint * rate / RAY() * psm._usdcPrecision <= max_uint256;
mint@withrevert(e, maxMint, receiver);
bool lastRevertedValue = lastReverted;
mathint susdsBalanceOfPSMAfter = susds.balanceOf(psm);
mathint maxMintAfter = maxMint(e, anyAddr);
assert !lastRevertedValue, "Assert 1";
assert susdsBalanceOfPSMAfter <= 10^12, "Assert 2";
assert maxMintAfter == 0, "Assert 3";
}
rule invariant_maxWithdraw(address owner) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address pocket = psm.pocket();
address receiver;
require receiver != 0 && receiver != currentContract && receiver != pocket;
uint256 maxWithdraw = maxWithdraw(e, owner);
require maxWithdraw > 0;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
// Contracts set up
require usdc.allowance(pocket, psm) == max_uint256;
require susds.allowance(currentContract, psm) == max_uint256;
// Contract behavior
require susds.balanceOf(currentContract) >= totalSupply();
require totalSupply() >= balanceOf(owner);
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(pocket) + usdc.balanceOf(currentContract) + usdc.balanceOf(receiver);
require susds.totalSupply() >= susds.balanceOf(currentContract) + susds.balanceOf(psm);
// Owner => sender allowance
require allowance(owner, e.msg.sender) == max_uint256;
// Avoid overflows
require maxWithdraw * RAY() <= max_uint256;
require defCeilDiv(maxWithdraw * RAY(), rate) * psm._susdsPrecision <= max_uint256;
withdraw@withrevert(e, maxWithdraw, receiver, owner);
bool lastRevertedValue = lastReverted;
mathint maxWithdrawAfter = maxWithdraw(e, owner);
assert !lastRevertedValue, "Assert 1";
assert maxWithdrawAfter == 0, "Assert 2";
}
rule invariant_maxRedeem(address owner) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address pocket = psm.pocket();
address receiver;
require receiver != 0 && receiver != currentContract && receiver != pocket;
uint256 maxRedeem = maxRedeem(e, owner);
require maxRedeem > 0;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
// Contracts set up
require usdc.allowance(pocket, psm) == max_uint256;
require susds.allowance(currentContract, psm) == max_uint256;
// Contract behavior
require susds.balanceOf(currentContract) >= totalSupply();
require totalSupply() >= balanceOf(owner);
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(pocket) + usdc.balanceOf(currentContract) + usdc.balanceOf(receiver);
require susds.totalSupply() >= susds.balanceOf(currentContract) + susds.balanceOf(psm);
// Owner => sender allowance
require allowance(owner, e.msg.sender) == max_uint256;
// Avoid overflows
require maxRedeem * rate <= max_uint256;
require maxRedeem * rate / RAY() * psm._usdcPrecision <= max_uint256;
redeem@withrevert(e, maxRedeem, receiver, owner);
bool lastRevertedValue = lastReverted;
mathint maxRedeemAfter = maxRedeem(e, owner);
assert !lastRevertedValue, "Assert 1";
assert maxRedeemAfter <= 10^12, "Assert 2";
}
// Verify no more entry points exist
rule entryPoints(method f) filtered { f -> !f.isView } {
env e;
calldataarg args;
f(e, args);
assert f.selector == sig:initialize().selector ||
f.selector == sig:upgradeToAndCall(address,bytes).selector ||
f.selector == sig:rely(address).selector ||
f.selector == sig:deny(address).selector ||
f.selector == sig:transfer(address,uint256).selector ||
f.selector == sig:transferFrom(address,address,uint256).selector ||
f.selector == sig:approve(address,uint256).selector ||
f.selector == sig:deposit(uint256,address).selector ||
f.selector == sig:deposit(uint256,address,uint256,uint16).selector ||
f.selector == sig:mint(uint256,address).selector ||
f.selector == sig:mint(uint256,address,uint256,uint16).selector ||
f.selector == sig:withdraw(uint256,address,address).selector ||
f.selector == sig:withdraw(uint256,address,address,uint256).selector ||
f.selector == sig:redeem(uint256,address,address).selector ||
f.selector == sig:redeem(uint256,address,address,uint256).selector ||
f.selector == sig:exit(uint256,address,address).selector ||
f.selector == sig:permit(address,address,uint256,uint256,bytes).selector ||
f.selector == sig:permit(address,address,uint256,uint256,uint8,bytes32,bytes32).selector;
}
// Verify that each storage layout is only modified in the corresponding functions
rule storageAffected(method f) filtered { f -> f.selector != sig:upgradeToAndCall(address,bytes).selector } {
env e;
address anyAddr;
address anyAddr2;
mathint wardsBefore = wards(anyAddr);
mathint totalSupplyBefore = totalSupply();
mathint balanceOfBefore = balanceOf(anyAddr);
mathint allowanceBefore = allowance(anyAddr, anyAddr2);
mathint noncesBefore = nonces(anyAddr);
calldataarg args;
f(e, args);
mathint wardsAfter = wards(anyAddr);
mathint totalSupplyAfter = totalSupply();
mathint balanceOfAfter = balanceOf(anyAddr);
mathint allowanceAfter = allowance(anyAddr, anyAddr2);
mathint noncesAfter = nonces(anyAddr);
assert wardsAfter != wardsBefore => f.selector == sig:initialize().selector ||
f.selector == sig:rely(address).selector ||
f.selector == sig:deny(address).selector, "Assert 1";
assert totalSupplyAfter != totalSupplyBefore => f.selector == sig:deposit(uint256,address).selector ||
f.selector == sig:deposit(uint256,address,uint256,uint16).selector ||
f.selector == sig:mint(uint256,address).selector ||
f.selector == sig:mint(uint256,address,uint256,uint16).selector ||
f.selector == sig:withdraw(uint256,address,address).selector ||
f.selector == sig:withdraw(uint256,address,address,uint256).selector ||
f.selector == sig:redeem(uint256,address,address).selector ||
f.selector == sig:redeem(uint256,address,address,uint256).selector ||
f.selector == sig:exit(uint256,address,address).selector, "Assert 2";
assert balanceOfAfter != balanceOfBefore => f.selector == sig:deposit(uint256,address).selector ||
f.selector == sig:deposit(uint256,address,uint256,uint16).selector ||
f.selector == sig:mint(uint256,address).selector ||
f.selector == sig:mint(uint256,address,uint256,uint16).selector ||
f.selector == sig:withdraw(uint256,address,address).selector ||
f.selector == sig:withdraw(uint256,address,address,uint256).selector ||
f.selector == sig:redeem(uint256,address,address).selector ||
f.selector == sig:redeem(uint256,address,address,uint256).selector ||
f.selector == sig:transfer(address,uint256).selector ||
f.selector == sig:transferFrom(address,address,uint256).selector ||
f.selector == sig:exit(uint256,address,address).selector, "Assert 3";
assert allowanceAfter != allowanceBefore => f.selector == sig:approve(address,uint256).selector ||
f.selector == sig:transferFrom(address,address,uint256).selector ||
f.selector == sig:withdraw(uint256,address,address).selector ||
f.selector == sig:withdraw(uint256,address,address,uint256).selector ||
f.selector == sig:redeem(uint256,address,address).selector ||
f.selector == sig:redeem(uint256,address,address,uint256).selector ||
f.selector == sig:exit(uint256,address,address).selector ||
f.selector == sig:permit(address,address,uint256,uint256,bytes).selector ||
f.selector == sig:permit(address,address,uint256,uint256,uint8,bytes32,bytes32).selector, "Assert 4";
assert noncesAfter != noncesBefore => f.selector == sig:permit(address,address,uint256,uint256,bytes).selector ||
f.selector == sig:permit(address,address,uint256,uint256,uint8,bytes32,bytes32).selector, "Assert 5";
}
// Verify correct storage changes for non reverting rely
rule rely(address usr) {
env e;
address other;
require other != usr;
mathint wardsOtherBefore = wards(other);
rely(e, usr);
mathint wardsUsrAfter = wards(usr);
mathint wardsOtherAfter = wards(other);
assert wardsUsrAfter == 1, "Assert 1";
assert wardsOtherAfter == wardsOtherBefore, "Assert 2";
}
// Verify revert rules on rely
rule rely_revert(address usr) {
env e;
mathint wardsSender = wards(e.msg.sender);
rely@withrevert(e, usr);
bool revert1 = e.msg.value > 0;
bool revert2 = wardsSender != 1;
assert lastReverted <=> revert1 || revert2, "Revert rules failed";
}
// Verify correct storage changes for non reverting deny
rule deny(address usr) {
env e;
address other;
require other != usr;
mathint wardsOtherBefore = wards(other);
deny(e, usr);
mathint wardsUsrAfter = wards(usr);
mathint wardsOtherAfter = wards(other);
assert wardsUsrAfter == 0, "Assert 1";
assert wardsOtherAfter == wardsOtherBefore, "Assert 2";
}
// Verify revert rules on deny
rule deny_revert(address usr) {
env e;
mathint wardsSender = wards(e.msg.sender);
deny@withrevert(e, usr);
bool revert1 = e.msg.value > 0;
bool revert2 = wardsSender != 1;
assert lastReverted <=> revert1 || revert2, "Revert rules failed";
}
// Verify correct storage changes for non reverting transfer
rule transfer(address to, uint256 value) {
env e;
requireInvariant balanceSum_equals_totalSupply();
address other;
require other != e.msg.sender && other != to;
mathint balanceOfSenderBefore = balanceOf(e.msg.sender);
mathint balanceOfToBefore = balanceOf(to);
mathint balanceOfOtherBefore = balanceOf(other);
transfer(e, to, value);
mathint balanceOfSenderAfter = balanceOf(e.msg.sender);
mathint balanceOfToAfter = balanceOf(to);
mathint balanceOfOtherAfter = balanceOf(other);
assert e.msg.sender != to => balanceOfSenderAfter == balanceOfSenderBefore - value, "Assert 1";
assert e.msg.sender != to => balanceOfToAfter == balanceOfToBefore + value, "Assert 2";
assert e.msg.sender == to => balanceOfSenderAfter == balanceOfSenderBefore, "Assert 3";
assert balanceOfOtherAfter == balanceOfOtherBefore, "Assert 4";
}
// Verify revert rules on transfer
rule transfer_revert(address to, uint256 value) {
env e;
mathint balanceOfSender = balanceOf(e.msg.sender);
transfer@withrevert(e, to, value);
bool revert1 = e.msg.value > 0;
bool revert2 = to == 0 || to == currentContract;
bool revert3 = balanceOfSender < to_mathint(value);
assert lastReverted <=> revert1 || revert2 || revert3, "Revert rules failed";
}
// Verify correct storage changes for non reverting transferFrom
rule transferFrom(address from, address to, uint256 value) {
env e;
requireInvariant balanceSum_equals_totalSupply();
address other;
require other != from && other != to;
address other2; address other3;
require other2 != from || other3 != e.msg.sender;
mathint totalSupplyBefore = totalSupply();
mathint balanceOfFromBefore = balanceOf(from);
mathint balanceOfToBefore = balanceOf(to);
mathint balanceOfOtherBefore = balanceOf(other);
mathint allowanceFromSenderBefore = allowance(from, e.msg.sender);
mathint allowanceOtherBefore = allowance(other2, other3);
transferFrom(e, from, to, value);
mathint balanceOfFromAfter = balanceOf(from);
mathint balanceOfToAfter = balanceOf(to);
mathint balanceOfOtherAfter = balanceOf(other);
mathint allowanceFromSenderAfter = allowance(from, e.msg.sender);
mathint allowanceOtherAfter = allowance(other2, other3);
assert from != to => balanceOfFromAfter == balanceOfFromBefore - value, "Assert 1";
assert from != to => balanceOfToAfter == balanceOfToBefore + value, "Assert 2";
assert from == to => balanceOfFromAfter == balanceOfFromBefore, "Assert 3";
assert balanceOfOtherAfter == balanceOfOtherBefore, "Assert 4";
assert e.msg.sender != from && allowanceFromSenderBefore != max_uint256 => allowanceFromSenderAfter == allowanceFromSenderBefore - value, "Assert 5";
assert e.msg.sender == from => allowanceFromSenderAfter == allowanceFromSenderBefore, "Assert 6";
assert allowanceFromSenderBefore == max_uint256 => allowanceFromSenderAfter == allowanceFromSenderBefore, "Assert 7";
assert allowanceOtherAfter == allowanceOtherBefore, "Assert 8";
}
// Verify revert rules on transferFrom
rule transferFrom_revert(address from, address to, uint256 value) {
env e;
mathint balanceOfFrom = balanceOf(from);
mathint allowanceFromSender = allowance(from, e.msg.sender);
transferFrom@withrevert(e, from, to, value);
bool revert1 = e.msg.value > 0;
bool revert2 = to == 0 || to == currentContract;
bool revert3 = balanceOfFrom < to_mathint(value);
bool revert4 = allowanceFromSender < to_mathint(value) && e.msg.sender != from;
assert lastReverted <=> revert1 || revert2 || revert3 || revert4, "Revert rules failed";
}
// Verify correct storage changes for non reverting approve
rule approve(address spender, uint256 value) {
env e;
address anyUsr; address anyUsr2;
require anyUsr != e.msg.sender || anyUsr2 != spender;
mathint allowanceOtherBefore = allowance(anyUsr, anyUsr2);
approve(e, spender, value);
mathint allowanceSenderSpenderAfter = allowance(e.msg.sender, spender);
mathint allowanceOtherAfter = allowance(anyUsr, anyUsr2);
assert allowanceSenderSpenderAfter == to_mathint(value), "Assert 1";
assert allowanceOtherAfter == allowanceOtherBefore, "Assert 2";
}
// Verify revert rules on approve
rule approve_revert(address spender, uint256 value) {
env e;
approve@withrevert(e, spender, value);
bool revert1 = e.msg.value > 0;
assert lastReverted <=> revert1, "Revert rules failed";
}
// Verify correct behaviour of asset getter
rule asset() {
env e;
address asset = asset(e);
assert asset == usdc(), "Assert 1";
}
// Verify correct behaviour of totalAssets getter
rule totalAssets() {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint totalAssetsCalc = defGetSwapQuote(susds, usdc, totalSupply(), false);
mathint totalAssets = totalAssets(e);
assert totalAssets == totalAssetsCalc, "Assert 1";
}
// Verify correct behaviour of convertToShares getter
rule convertToShares(uint256 assets) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint sharesCalc = defGetSwapQuote(usdc, susds, assets, false);
mathint shares = convertToShares(e, assets);
assert shares == sharesCalc, "Assert 1";
}
// Verify correct behaviour of convertToAssets getter
rule convertToAssets(uint256 shares) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint assetsCalc = defGetSwapQuote(susds, usdc, shares, false);
mathint assets = convertToAssets(e, shares);
assert assets == assetsCalc, "Assert 1";
}
// Verify correct behaviour of maxDeposit getter
rule maxDeposit(address anyAddr) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint maxDepositCalc = defGetSwapQuote(susds, usdc, susds.balanceOf(psm), false);
mathint maxDeposit = maxDeposit(e, anyAddr);
assert maxDepositCalc == maxDeposit, "Assert 1";
}
// Verify correct behaviour of previewDeposit getter
rule previewDeposit(uint256 assets) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint previewDepositCalc = defGetSwapQuote(usdc, susds, assets, false);
mathint previewDeposit = previewDeposit(e, assets);
assert previewDepositCalc == previewDeposit, "Assert 1";
}
// Verify correct storage changes for non reverting deposit
rule deposit(uint256 assets, address receiver) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address pocket = psm.pocket();
require e.msg.sender != pocket;
address other;
require other != receiver;
mathint sharesCalc = defGetSwapQuote(usdc, susds, assets, false);
mathint totalSupplyBefore = totalSupply();
mathint balanceOfReceiverBefore = balanceOf(receiver);
mathint balanceOfOtherBefore = balanceOf(other);
mathint usdcBalanceOfSenderBefore = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketBefore = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmBefore = susds.balanceOf(psm);
mathint susdsBalanceOfVaultBefore = susds.balanceOf(currentContract);
require totalSupplyBefore <= susds.balanceOf(currentContract);
require totalSupplyBefore >= balanceOfReceiverBefore + balanceOfOtherBefore;
mathint shares = deposit(e, assets, receiver);
mathint totalSupplyAfter = totalSupply();
mathint balanceOfReceiverAfter = balanceOf(receiver);
mathint balanceOfOtherAfter = balanceOf(other);
mathint usdcBalanceOfSenderAfter = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketAfter = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmAfter = susds.balanceOf(psm);
mathint susdsBalanceOfVaultAfter = susds.balanceOf(currentContract);
assert shares == sharesCalc, "Assert 1";
assert totalSupplyAfter == totalSupplyBefore + shares, "Assert 2";
assert balanceOfReceiverAfter == balanceOfReceiverBefore + shares, "Assert 3";
assert balanceOfOtherAfter == balanceOfOtherBefore, "Assert 4";
assert usdcBalanceOfSenderAfter == usdcBalanceOfSenderBefore - assets, "Assert 5";
assert usdcBalanceOfPocketAfter == usdcBalanceOfPocketBefore + assets, "Assert 6";
assert susdsBalanceOfPsmAfter == susdsBalanceOfPsmBefore - shares, "Assert 7";
assert susdsBalanceOfVaultAfter == susdsBalanceOfVaultBefore + shares, "Assert 9";
}
// Verify revert rules on deposit
rule deposit_revert(uint256 assets, address receiver) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
mathint susdsBalanceOfPsm = susds.balanceOf(psm);
mathint shares = defGetSwapQuote(usdc, susds, assets, false);
// Contracts set up
require usdc.allowance(currentContract, psm) == max_uint256;
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(e.msg.sender) + usdc.balanceOf(currentContract) + usdc.balanceOf(psm) + usdc.balanceOf(psm.pocket());
require susds.totalSupply() >= susdsBalanceOfPsm + susds.balanceOf(currentContract);
// Sender assumptions
require usdc.allowance(e.msg.sender, currentContract) >= assets;
require usdc.balanceOf(e.msg.sender) >= assets;
// Avoid external contracts overflows
require assets * RAY() <= max_uint256;
require assets * RAY() / rate * psm._susdsPrecision <= max_uint256;
require assets > 0;
deposit@withrevert(e, assets, receiver);
bool revert1 = e.msg.value > 0;
bool revert2 = shares > susdsBalanceOfPsm;
bool revert3 = receiver == 0 || receiver == currentContract;
assert lastReverted <=> revert1 || revert2 || revert3, "Revert rules failed";
}
// Verify correct storage changes for non reverting deposit
rule deposit2(uint256 assets, address receiver, uint256 minShares, uint16 referral) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address pocket = psm.pocket();
require e.msg.sender != pocket;
address other;
require other != receiver;
mathint sharesCalc = defGetSwapQuote(usdc, susds, assets, false);
mathint totalSupplyBefore = totalSupply();
mathint balanceOfReceiverBefore = balanceOf(receiver);
mathint balanceOfOtherBefore = balanceOf(other);
mathint usdcBalanceOfSenderBefore = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketBefore = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmBefore = susds.balanceOf(psm);
mathint susdsBalanceOfVaultBefore = susds.balanceOf(currentContract);
require totalSupplyBefore <= susds.balanceOf(currentContract);
require totalSupplyBefore >= balanceOfReceiverBefore + balanceOfOtherBefore;
mathint shares = deposit(e, assets, receiver, minShares, referral);
mathint totalSupplyAfter = totalSupply();
mathint balanceOfReceiverAfter = balanceOf(receiver);
mathint balanceOfOtherAfter = balanceOf(other);
mathint usdcBalanceOfSenderAfter = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketAfter = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmAfter = susds.balanceOf(psm);
mathint susdsBalanceOfVaultAfter = susds.balanceOf(currentContract);
assert shares == sharesCalc, "Assert 1";
assert totalSupplyAfter == totalSupplyBefore + shares, "Assert 2";
assert balanceOfReceiverAfter == balanceOfReceiverBefore + shares, "Assert 3";
assert balanceOfOtherAfter == balanceOfOtherBefore, "Assert 4";
assert usdcBalanceOfSenderAfter == usdcBalanceOfSenderBefore - assets, "Assert 5";
assert usdcBalanceOfPocketAfter == usdcBalanceOfPocketBefore + assets, "Assert 6";
assert susdsBalanceOfPsmAfter == susdsBalanceOfPsmBefore - shares, "Assert 7";
assert susdsBalanceOfVaultAfter == susdsBalanceOfVaultBefore + shares, "Assert 9";
}
// Verify revert rules on deposit
rule deposit2_revert(uint256 assets, address receiver, uint256 minShares, uint16 referral) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
mathint susdsBalanceOfPsm = susds.balanceOf(psm);
mathint shares = defGetSwapQuote(usdc, susds, assets, false);
// Contracts set up
require usdc.allowance(currentContract, psm) == max_uint256;
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(e.msg.sender) + usdc.balanceOf(currentContract) + usdc.balanceOf(psm) + usdc.balanceOf(psm.pocket());
require susds.totalSupply() >= susdsBalanceOfPsm + susds.balanceOf(currentContract);
// Sender assumptions
require usdc.allowance(e.msg.sender, currentContract) >= assets;
require usdc.balanceOf(e.msg.sender) >= assets;
// Avoid external contracts overflows
require assets * RAY() <= max_uint256;
require assets * RAY() / rate * psm._susdsPrecision <= max_uint256;
require assets > 0;
deposit@withrevert(e, assets, receiver, minShares, referral);
bool revert1 = e.msg.value > 0;
bool revert2 = shares > susdsBalanceOfPsm;
bool revert3 = shares < minShares;
bool revert4 = receiver == 0 || receiver == currentContract;
assert lastReverted <=> revert1 || revert2 || revert3 ||
revert4, "Revert rules failed";
}
// Verify correct behaviour of maxMint getter
rule maxMint(address anyAddr) {
env e;
mathint maxMintCalc = susds.balanceOf(psm);
mathint maxMint = maxMint(e, anyAddr);
assert maxMintCalc == maxMint, "Assert 1";
}
// Verify correct behaviour of previewMint getter
rule previewMint(uint256 shares) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint previewMintCalc = defGetSwapQuote(susds, usdc, shares, true);
mathint previewMint = previewMint(e, shares);
assert previewMintCalc == previewMint, "Assert 1";
}
// Verify correct storage changes for non reverting mint
rule mint(uint256 shares, address receiver) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address pocket = psm.pocket();
require e.msg.sender != pocket;
address other;
require other != receiver;
mathint assetsCalc = defGetSwapQuote(susds, usdc, shares, true);
mathint totalSupplyBefore = totalSupply();
mathint balanceOfReceiverBefore = balanceOf(receiver);
mathint balanceOfOtherBefore = balanceOf(other);
mathint usdcBalanceOfSenderBefore = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketBefore = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmBefore = susds.balanceOf(psm);
mathint susdsBalanceOfVaultBefore = susds.balanceOf(currentContract);
require totalSupplyBefore <= susdsBalanceOfVaultBefore;
require totalSupplyBefore >= balanceOfReceiverBefore + balanceOfOtherBefore;
mathint assets = mint(e, shares, receiver);
mathint totalSupplyAfter = totalSupply();
mathint balanceOfReceiverAfter = balanceOf(receiver);
mathint balanceOfOtherAfter = balanceOf(other);
mathint usdcBalanceOfSenderAfter = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketAfter = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmAfter = susds.balanceOf(psm);
mathint susdsBalanceOfVaultAfter = susds.balanceOf(currentContract);
assert assets == assetsCalc, "Assert 1";
assert totalSupplyAfter == totalSupplyBefore + shares, "Assert 2";
assert balanceOfReceiverAfter == balanceOfReceiverBefore + shares, "Assert 3";
assert balanceOfOtherAfter == balanceOfOtherBefore, "Assert 4";
assert usdcBalanceOfSenderAfter == usdcBalanceOfSenderBefore - assets, "Assert 5";
assert usdcBalanceOfPocketAfter == usdcBalanceOfPocketBefore + assets, "Assert 6";
assert susdsBalanceOfPsmAfter == susdsBalanceOfPsmBefore - shares, "Assert 7";
assert susdsBalanceOfVaultAfter == susdsBalanceOfVaultBefore + shares, "Assert 8";
}
// Verify revert rules on mint
rule mint_revert(uint256 shares, address receiver) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
mathint rate = rateProvider.getConversionRate();
require rate >= RAY() && rate <= 10 * RAY(); // Logical rate
mathint susdsBalanceOfPsm = susds.balanceOf(psm);
mathint assets = defGetSwapQuote(susds, usdc, shares, true);
// Contracts set up
require usdc.allowance(currentContract, psm) == max_uint256;
// ERC20 correct behaviour
require usdc.totalSupply() >= usdc.balanceOf(e.msg.sender) + usdc.balanceOf(currentContract) + usdc.balanceOf(psm) + usdc.balanceOf(psm.pocket());
require susds.totalSupply() >= susdsBalanceOfPsm + susds.balanceOf(currentContract);
// Sender assumptions
require usdc.allowance(e.msg.sender, currentContract) >= assets;
require usdc.balanceOf(e.msg.sender) >= assets;
// Avoid external contracts overflows
require shares * rate <= max_uint256;
require shares * rate / RAY() * psm._usdcPrecision <= max_uint256;
require shares > 0;
mint@withrevert(e, shares, receiver);
bool revert1 = e.msg.value > 0;
bool revert2 = shares > susdsBalanceOfPsm;
bool revert3 = receiver == 0 || receiver == currentContract;
assert lastReverted <=> revert1 || revert2 || revert3, "Revert rules failed";
}
// Verify correct storage changes for non reverting mint
rule mint2(uint256 shares, address receiver, uint256 maxAssets, uint16 referral) {
env e;
require psm._susdsPrecision == 10^18;
require psm._usdcPrecision == 10^6;
address pocket = psm.pocket();
require e.msg.sender != pocket;
address other;
require other != receiver;
mathint assetsCalc = defGetSwapQuote(susds, usdc, shares, true);
mathint totalSupplyBefore = totalSupply();
mathint balanceOfReceiverBefore = balanceOf(receiver);
mathint balanceOfOtherBefore = balanceOf(other);
mathint usdcBalanceOfSenderBefore = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketBefore = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmBefore = susds.balanceOf(psm);
mathint susdsBalanceOfVaultBefore = susds.balanceOf(currentContract);
require totalSupplyBefore <= susdsBalanceOfVaultBefore;
require totalSupplyBefore >= balanceOfReceiverBefore + balanceOfOtherBefore;
mathint assets = mint(e, shares, receiver, maxAssets, referral);
mathint totalSupplyAfter = totalSupply();
mathint balanceOfReceiverAfter = balanceOf(receiver);
mathint balanceOfOtherAfter = balanceOf(other);
mathint usdcBalanceOfSenderAfter = usdc.balanceOf(e.msg.sender);
mathint usdcBalanceOfPocketAfter = usdc.balanceOf(pocket);
mathint susdsBalanceOfPsmAfter = susds.balanceOf(psm);
mathint susdsBalanceOfVaultAfter = susds.balanceOf(currentContract);
assert assets == assetsCalc, "Assert 1";
assert totalSupplyAfter == totalSupplyBefore + shares, "Assert 2";
assert balanceOfReceiverAfter == balanceOfReceiverBefore + shares, "Assert 3";
assert balanceOfOtherAfter == balanceOfOtherBefore, "Assert 4";
assert usdcBalanceOfSenderAfter == usdcBalanceOfSenderBefore - assets, "Assert 5";
assert usdcBalanceOfPocketAfter == usdcBalanceOfPocketBefore + assets, "Assert 6";
assert susdsBalanceOfPsmAfter == susdsBalanceOfPsmBefore - shares, "Assert 7";
assert susdsBalanceOfVaultAfter == susdsBalanceOfVaultBefore + shares, "Assert 8";
}
// Verify revert rules on mint
rule mint2_revert(uint256 shares, address receiver, uint256 maxAssets, uint16 referral) {