cmake: add LAPACKE imported targets

Author: andrea-iob

CMakeLists.txt

@@ -108,11 +108,10 @@ function(configureBitpitTargetDependencies TARGET_NAME DEPENDENCIES_SCOPE)
     endif()
 
     if (LAPACKE_FOUND)
-        set(LAPACKE_PRIVATE_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/external/LAPACKE/include")
+        target_link_libraries(${TARGET_NAME} ${DEPENDENCIES_SCOPE} LAPACKE::LAPACKE)
 
-        target_link_libraries(${TARGET_NAME} ${DEPENDENCIES_SCOPE} ${LAPACKE_LIBRARIES})
+        set(LAPACKE_PRIVATE_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/external/LAPACKE/include")
         target_include_directories(${TARGET_NAME} PRIVATE ${LAPACKE_PRIVATE_INCLUDE_DIR})
-        target_include_directories(${TARGET_NAME} ${DEPENDENCIES_SCOPE} ${LAPACKE_INCLUDE_DIRS})
     endif()
 
     if (PETSC_FOUND)

external/LAPACKE/cmake/FindLAPACKE.cmake

@@ -424,3 +424,76 @@ include(FindPackageHandleStandardArgs)
 find_package_handle_standard_args(LAPACKE DEFAULT_MSG
   LAPACKE_LIBRARIES
   LAPACKE_WORKS)
+
+#-----------------------------------------------------------------------------
+# Create imported target
+#-----------------------------------------------------------------------------
+if (NOT TARGET LAPACKE::LAPACKE)
+    set(LAPACKE_LIBRARY_TARGETS "")
+    foreach(LIBRARY_PATH ${LAPACKE_LIBRARIES})
+        get_filename_component(LIBRARY_FILENAME "${LIBRARY_PATH}" NAME)
+        get_filename_component(LIBRARY_EXTENSION "${LIBRARY_PATH}" LAST_EXT)
+
+        string(REGEX REPLACE "\\.[^.]*$" "" LIBRARY_TARGET "${LIBRARY_FILENAME}")
+        string(REGEX REPLACE "^lib" "" LIBRARY_TARGET "${LIBRARY_TARGET}")
+        set(LIBRARY_TARGET "LAPACKE::${LIBRARY_TARGET}_library")
+
+        if (LIBRARY_EXTENSION STREQUAL ".a")
+            set(TARGET_TYPE "STATIC")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+        elseif (LIBRARY_EXTENSION STREQUAL ".lib")
+            get_filename_component(LIBRARY_BASENAME "${LIBRARY_FILENAME}" NAME_WE)
+            get_filename_component(LIBRARY_DIRECTORY "${LIBRARY_PATH}" DIRECTORY)
+            set(LIBRARY_DLL_SEARCH_PATHS
+                "${LIBRARY_DIRECTORY}"
+                "${LIBRARY_DIRECTORY}/../bin"
+                "${LIBRARY_DIRECTORY}/../../bin"
+                "${LIBRARY_DIRECTORY}/../../redist/intel64"
+                "${LIBRARY_DIRECTORY}/../../../redist/intel64"
+                "${LIBRARY_DIRECTORY}/../../redist/intel64/compiler"
+                "${LIBRARY_DIRECTORY}/../../../redist/intel64/compiler"
+                "${LIBRARY_DIRECTORY}/../../redist/intel64_win/compiler"
+                "${LIBRARY_DIRECTORY}/../../../redist/intel64_win/compiler"
+            )
+
+            set(TARGET_TYPE "STATIC")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+            foreach(LIBRARY_DLL_SEARCH_PATH IN LISTS LIBRARY_DLL_SEARCH_PATHS)
+                string(REGEX REPLACE "_dll$" "" CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_BASENAME}")
+                set(CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_DLL_SEARCH_PATH}/${CANDIDATE_LIBRARY_DLL_PATH}.dll")
+                if(EXISTS "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    set(TARGET_TYPE "SHARED")
+                    set(TARGET_IMPORTED_LOCATION "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    break()
+                endif()
+
+                string(REGEX REPLACE "_dll$" "" CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_BASENAME}")
+                set(CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_DLL_SEARCH_PATH}/${CANDIDATE_LIBRARY_DLL_PATH}.2.dll")
+                if(EXISTS "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    set(TARGET_TYPE "SHARED")
+                    set(TARGET_IMPORTED_LOCATION "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    break()
+                endif()
+            endforeach()
+        elseif (LIBRARY_EXTENSION STREQUAL ".so")
+            set(TARGET_TYPE "SHARED")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+        elseif (LIBRARY_EXTENSION STREQUAL ".dll")
+            set(TARGET_TYPE "SHARED")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+        endif()
+
+        add_library(${LIBRARY_TARGET} ${TARGET_TYPE} IMPORTED)
+        set_target_properties(${LIBRARY_TARGET} PROPERTIES IMPORTED_LOCATION ${TARGET_IMPORTED_LOCATION})
+        if (WIN32 AND TARGET_TYPE STREQUAL "SHARED")
+            set_target_properties(${LIBRARY_TARGET} PROPERTIES IMPORTED_IMPLIB "${LIBRARY_PATH}")
+        endif()
+        set_target_properties(${LIBRARY_TARGET} PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${LAPACKE_INCLUDE_DIRS}")
+        set_target_properties(${LIBRARY_TARGET} PROPERTIES INTERFACE_LINK_OPTIONS "${LAPACKE_LINKER_FLAGS}")
+
+        list(APPEND LAPACKE_LIBRARY_TARGETS ${LIBRARY_TARGET})
+    endforeach()
+
+    add_library(LAPACKE::LAPACKE INTERFACE IMPORTED)
+    set_target_properties(LAPACKE::LAPACKE PROPERTIES INTERFACE_LINK_LIBRARIES "${LAPACKE_LIBRARY_TARGETS}")
+endif()