cmake: add CBLAS imported targets

Author: andrea-iob

CMakeLists.txt

@@ -95,11 +95,10 @@ function(configureBitpitTargetDependencies TARGET_NAME DEPENDENCIES_SCOPE)
     endif()
 
     if (CBLAS_FOUND)
-        set(CBLAS_PRIVATE_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/external/CBLAS/include")
+        target_link_libraries(${TARGET_NAME} ${DEPENDENCIES_SCOPE} CBLAS::CBLAS)
 
-        target_link_libraries(${TARGET_NAME} ${DEPENDENCIES_SCOPE} ${CBLAS_LIBRARIES})
+        set(CBLAS_PRIVATE_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/external/CBLAS/include")
         target_include_directories(${TARGET_NAME} PRIVATE ${CBLAS_PRIVATE_INCLUDE_DIR})
-        target_include_directories(${TARGET_NAME} ${DEPENDENCIES_SCOPE} ${CBLAS_INCLUDE_DIRS})
     endif()
 
     if (LAPACK_FOUND)

external/CBLAS/cmake/FindCBLAS.cmake

@@ -394,3 +394,76 @@ include(FindPackageHandleStandardArgs)
 find_package_handle_standard_args(CBLAS DEFAULT_MSG
   CBLAS_LIBRARIES
   CBLAS_WORKS)
+
+#-----------------------------------------------------------------------------
+# Create imported target
+#-----------------------------------------------------------------------------
+if (NOT TARGET CBLAS::CBLAS)
+    set(CBLAS_LIBRARY_TARGETS "")
+    foreach(LIBRARY_PATH ${CBLAS_LIBRARIES})
+        get_filename_component(LIBRARY_FILENAME "${LIBRARY_PATH}" NAME)
+        get_filename_component(LIBRARY_EXTENSION "${LIBRARY_PATH}" LAST_EXT)
+
+        string(REGEX REPLACE "\\.[^.]*$" "" LIBRARY_TARGET "${LIBRARY_FILENAME}")
+        string(REGEX REPLACE "^lib" "" LIBRARY_TARGET "${LIBRARY_TARGET}")
+        set(LIBRARY_TARGET "CBLAS::${LIBRARY_TARGET}_library")
+
+        if (LIBRARY_EXTENSION STREQUAL ".a")
+            set(TARGET_TYPE "STATIC")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+        elseif (LIBRARY_EXTENSION STREQUAL ".lib")
+            get_filename_component(LIBRARY_BASENAME "${LIBRARY_FILENAME}" NAME_WE)
+            get_filename_component(LIBRARY_DIRECTORY "${LIBRARY_PATH}" DIRECTORY)
+            set(LIBRARY_DLL_SEARCH_PATHS
+                "${LIBRARY_DIRECTORY}"
+                "${LIBRARY_DIRECTORY}/../bin"
+                "${LIBRARY_DIRECTORY}/../../redist/intel64"
+                "${LIBRARY_DIRECTORY}/../../../redist/intel64"
+                "${LIBRARY_DIRECTORY}/../../redist/intel64/compiler"
+                "${LIBRARY_DIRECTORY}/../../../redist/intel64/compiler"
+                "${LIBRARY_DIRECTORY}/../../redist/intel64_win/compiler"
+                "${LIBRARY_DIRECTORY}/../../../redist/intel64_win/compiler"
+
+            )
+
+            set(TARGET_TYPE "STATIC")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+            foreach(LIBRARY_DLL_SEARCH_PATH IN LISTS LIBRARY_DLL_SEARCH_PATHS)
+                string(REGEX REPLACE "_dll$" "" CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_BASENAME}")
+                set(CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_DLL_SEARCH_PATH}/${CANDIDATE_LIBRARY_DLL_PATH}.dll")
+                if(EXISTS "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    set(TARGET_TYPE "SHARED")
+                    set(TARGET_IMPORTED_LOCATION "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    break()
+                endif()
+
+                string(REGEX REPLACE "_dll$" "" CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_BASENAME}")
+                set(CANDIDATE_LIBRARY_DLL_PATH "${LIBRARY_DLL_SEARCH_PATH}/${CANDIDATE_LIBRARY_DLL_PATH}.2.dll")
+                if(EXISTS "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    set(TARGET_TYPE "SHARED")
+                    set(TARGET_IMPORTED_LOCATION "${CANDIDATE_LIBRARY_DLL_PATH}")
+                    break()
+                endif()
+            endforeach()
+        elseif (LIBRARY_EXTENSION STREQUAL ".so")
+            set(TARGET_TYPE "SHARED")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+        elseif (LIBRARY_EXTENSION STREQUAL ".dll")
+            set(TARGET_TYPE "SHARED")
+            set(TARGET_IMPORTED_LOCATION "${LIBRARY_PATH}")
+        endif()
+
+        add_library(${LIBRARY_TARGET} ${TARGET_TYPE} IMPORTED)
+        set_target_properties(${LIBRARY_TARGET} PROPERTIES IMPORTED_LOCATION ${TARGET_IMPORTED_LOCATION})
+        if (WIN32 AND TARGET_TYPE STREQUAL "SHARED")
+            set_target_properties(${LIBRARY_TARGET} PROPERTIES IMPORTED_IMPLIB "${LIBRARY_PATH}")
+        endif()
+        set_target_properties(${LIBRARY_TARGET} PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${CBLAS_INCLUDE_DIRS}")
+        set_target_properties(${LIBRARY_TARGET} PROPERTIES INTERFACE_LINK_OPTIONS "${CBLAS_LINKER_FLAGS}")
+
+        list(APPEND CBLAS_LIBRARY_TARGETS ${LIBRARY_TARGET})
+    endforeach()
+
+    add_library(CBLAS::CBLAS INTERFACE IMPORTED)
+    set_target_properties(CBLAS::CBLAS PROPERTIES INTERFACE_LINK_LIBRARIES "${CBLAS_LIBRARY_TARGETS}")
+endif()