Add nix flake for a development shell

Author: k3d3

.envrc

@@ -0,0 +1 @@
+use flake

flake.lock

@@ -0,0 +1,50 @@
+{
+  description = "Rust dev environment for Panamax";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+  };
+
+  outputs = { self, nixpkgs, rust-overlay }:
+    let
+      overlays = [
+        rust-overlay.overlays.default
+        (final: prev: {
+          rustToolchain =
+            let
+              rust = prev.rust-bin;
+            in
+            if builtins.pathExists ./rust-toolchain.toml then
+              rust.fromRustupToolchainFile ./rust-toolchain.toml
+            else if builtins.pathExists ./rust-toolchain then
+              rust.fromRustupToolchainFile ./rust-toolchain
+            else
+              rust.stable.latest.default.override {
+                extensions = [ "rust-src" ];
+                targets = [ "x86_64-unknown-linux-gnu" "wasm32-unknown-unknown" ];
+              };
+        })
+      ];
+      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+      forEachSupportedSystem = f: nixpkgs.lib.genAttrs supportedSystems (system: f {
+        pkgs = import nixpkgs { inherit overlays system; };
+      });
+    in
+    {
+      devShells = forEachSupportedSystem ({ pkgs }: {
+        default = pkgs.mkShell {
+          packages = with pkgs; [
+            rustToolchain
+            openssl
+            pkg-config
+            libgit2
+            cargo-deny
+            cargo-edit
+            cargo-watch
+            rust-analyzer
+          ];
+        };
+      });
+    };
+}