-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathwmwavemd.ftn
1811 lines (1806 loc) · 64.2 KB
/
wmwavemd.ftn
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#include "w3macros.h"
!/ ------------------------------------------------------------------- /
MODULE WMWAVEMD
!/
!/ +-----------------------------------+
!/ | WAVEWATCH III NOAA/NCEP |
!/ | H. L. Tolman |
!/ | FORTRAN 90 |
!/ | Last update : 28-Jan-2014 |
!/ +-----------------------------------+
!/
!/ 13-Jun-2005 : Origination. ( version 3.07 )
!/ 30-Jan-2006 : Add static nesting. ( version 3.08 )
!/ 25-May-2006 : Add overlapping grids. ( version 3.09 )
!/ 09-Aug-2006 : Unified point output added. ( version 3.10 )
!/ 22-Dec-2006 : Final algorith changes for tests. ( version 3.10 )
!/ 25-Jan-2007 : Tweaking algorithm. ( version 3.10 )
!/ 02-Feb-2007 : Replacing MPI_BCAST with WMBCST. ( version 3.10 )
!/ 07-Feb-2007 : Reintroduce pre-fetching. ( version 3.10 )
!/ 10-May-2007 : Removing / streamlining WMBCST. ( version 3.11 )
!/ 21-Jun-2007 : Dedicated output processes. ( version 3.11 )
!/ 20-Sep-2007 : Fix reset of GRSTAT in 0.b ( version 3.13 )
!/ 29-May-2009 : Preparing distribution version. ( version 3.14 )
!/ 20-Aug-2010 : Fix MAPSTA/MAPST2 bug. ( version 3.14.6 )
!/ 12-Mar-2012 : Use MPI_COMM_NULL for checks. ( version 3.14 )
!/ 28-Jan-2014 : Add memory hwm to profiling. ( version 5.00 )
!/
!/ Copyright 2009-2014 National Weather Service (NWS),
!/ National Oceanic and Atmospheric Administration. All rights
!/ reserved. WAVEWATCH III is a trademark of the NWS.
!/ No unauthorized use without permission.
!/
! 1. Purpose :
!
! Running the multi-grid version of WAVEWATCH III up to a given
! ending time for each grid.
!
! 2. Variables and types :
!
! Name Type Scope Description
! ----------------------------------------------------------------
! ----------------------------------------------------------------
!
! 3. Subroutines and functions :
!
! Name Type Scope Description
! ----------------------------------------------------------------
! WMWAVE Subr. Public Wave model initialization.
! WMPRNT Subr. Public Print action table to log file.
! WMBCST Subr. Public Non-blocking MPI broadcast.
! WMWOUT Subr. Public Non-blocking MPI broadcast.
! ----------------------------------------------------------------
!
! 4. Subroutines and functions used :
!
! See subroutine documentation.
!
! 5. Remarks :
!
! 6. Switches :
!
! See subroutine documentation.
!
! 7. Source code :
!
!/ ------------------------------------------------------------------- /
PUBLIC
!/
CONTAINS
!/ ------------------------------------------------------------------- /
SUBROUTINE WMWAVE ( TEND )
!/
!/ +-----------------------------------+
!/ | WAVEWATCH III NOAA/NCEP |
!/ | H. L. Tolman |
!/ | FORTRAN 90 |
!/ | Last update : 28-Jan-2014 |
!/ +-----------------------------------+
!/
!/ 13-Jun-2005 : Origination. ( version 3.07 )
!/ 30-Jan-2006 : Add static nesting. ( version 3.08 )
!/ 25-May-2006 : Add overlapping grids. ( version 3.09 )
!/ 09-Aug-2006 : Unified point output added. ( version 3.10 )
!/ 22-Dec-2006 : Final algorith changes for tests. ( version 3.10 )
!/ 25-Jan-2007 : Tweaking algorithm. ( version 3.10 )
!/ 02-Feb-2007 : Replacing MPI_BCAST with WMBCST. ( version 3.10 )
!/ 07-Feb-2007 : Reintroduce pre-fetching. ( version 3.10 )
!/ 10-May-2007 : Removing / streamlining WMBCST. ( version 3.11 )
!/ 21-Jun-2007 : Dedicated output processes. ( version 3.11 )
!/ 20-Sep-2007 : Fix reset of GRSTAT in 0.b ( version 3.13 )
!/ 20-Aug-2010 : Fix MAPSTA/MAPST2 bug sec. 9.a. ( version 3.14.6 )
!/ 12-Mar-2012 : Use MPI_COMM_NULL for checks. ( version 3.14 )
!/ 28-Jan-2014 : Add memory hwm to profiling. ( version 5.00 )
!/
! 1. Purpose :
!
! Run multi-grid version of WAVEWATCH III.
!
! 2. Method :
!
! See manual.
!
! 3. Parameters :
!
! Parameter list
! ----------------------------------------------------------------
! TEND I.A. I Ending time for calculations for each grid.
! ----------------------------------------------------------------
!
! Local variables
! ----------------------------------------------------------------
! J Int. Group counter.
! JJ Int. Grid in group counter.
! I Int. Grid counter.
! ----------------------------------------------------------------
!
! 4. Subroutines used :
!
! Name Type Module Description
! ----------------------------------------------------------------
! W3SETG Subr W3GDATMD Point to grid/model.
! W3SETW Subr W3WDATMD Point to grid/model.
! W3SETA Subr W3ADATMD Point to grid/model.
! W3SETO Subr W3ODATMD Point to grid/model.
! W3IOPE Subr W3IOPOMD Extracting point output.
! W3WAVE Subr W3WAVEMD Actual ave model routine.
! STRACE Subr W3SERVMD Subroutine tracing.
! EXTCDE Subr Id. Abort program with exit code.
! WWTIME Subr Id. System time in readable format.
! PRTIME Subr Id. Profiling routine ( !/MPRF )
! STME21 Subr W3TIMEMD Print date and time readable.
! DSEC21 Func Id. Difference between times.
! TICK21 Subr Id. Advance time.
! WMSETM Subr WMMDATMD Point to grid/model.
! WMUPDT Subr WMUPDTMD Update input fields at driver level.
! WMIOBG Subr WMINIOMD Gather staged boundary data.
! WMIOBS Subr Id. Stage boundary data.
! WMIOBF Subr Id. Finalize WMIOBS. ( !/MPI )
! WMIOHS Subr Id. Stage high-to-low data.
! WMIOHG Subr Id. Gather staged high-to-low data.
! WMIOHF Subr Id. Finalize WMIOHS. ( !/MPI )
! WMIOES Subr Id. Stage same-rank data.
! WMIOEG Subr Id. Gather staged same-rank data.
! WMIOEF Subr Id. Finalize WMIOES. ( !/MPI )
! WMIOPO Subr WMIOPOMD Unified point output.
! ----------------------------------------------------------------
!
! 5. Called by :
!
! Name Type Module Description
! ----------------------------------------------------------------
! W3MLTI Prog. N/A Multi-grid model driver.
! .... Any coupled model.
! ----------------------------------------------------------------
!
! 6. Error messages :
!
! See formats 1000 and following, or escape locations 2000 and
! following.
!
! 7. Remarks :
!
! - If no action is taken in the endless loop, an error is
! assumed (code 2099). This should never take place in the
! default driver, but may be a problem in a coupled model.
! - If output is requested for the initial model time, TSYNC
! is set to TIME instead of (-1,0) for GRSTAT = 0. In this case
! input is updated, after which GRSTAT is set to 6 instead
! of 1. This assures that restarts do not impact model results
! by spurious double reconciliations.
!
! 8. Structure :
!
! See source code and manual.
!
! 9. Switches :
!
! !/S Enable subroutine tracing.
! !/T Enable test output.
! !/MPIT Enable test output (use with !/MPI only).
! !/MPRF Profiling.
!
! !/SHRD, !/DIST, !/MPI
! Shared / distributed program model.
!
! 10. Source code :
!
!/ ------------------------------------------------------------------- /
USE CONSTANTS
!/
USE W3GDATMD, ONLY: W3SETG
USE W3WDATMD, ONLY: W3SETW
USE W3ADATMD, ONLY: W3SETA
USE W3ODATMD, ONLY: W3SETO, NOTYPE
USE W3IOPOMD, ONLY: W3IOPE
USE W3WAVEMD, ONLY: W3WAVE
USE W3SERVMD, ONLY: EXTCDE, WWTIME
!/S USE W3SERVMD, ONLY: STRACE
!/MPRF USE W3TIMEMD, ONLY: PRTIME
USE W3TIMEMD, ONLY: DSEC21, STME21, TICK21
USE WMMDATMD, ONLY: WMSETM
USE WMUPDTMD, ONLY: WMUPDT
USE WMINIOMD, ONLY: WMIOBG, WMIOBS, WMIOBF, WMIOHG, WMIOHS, &
WMIOHF, WMIOEG, WMIOES, WMIOEF
USE WMIOPOMD, ONLY: WMIOPO
!/
USE W3GDATMD, ONLY: DTMAX, NX, NY, MAPSTA, MAPST2
USE W3WDATMD, ONLY: TIME, VA
USE W3ODATMD, ONLY: FLOUT, TONEXT, DTOUT, TOLAST, IAPROC, &
NAPPNT, NOPTS, UNIPTS
!/MPI USE W3ODATMD, ONLY: NRQPO, IRQPO1
USE W3IDATMD, ONLY: INFLAGS1
USE WMMDATMD, ONLY: MDSO, MDSS, MDST, MDSE, IMPROC, &
NMPROC, NMPSCR, NMPERR, NMPTST, NMPLOG, &
STIME, ETIME, NMV, TMV, AMV, DMV, &
NRGRD, NRGRP, GRANK, INGRP, GRDHGH, GRDEQL, &
GRDLOW, TSYNC, TMAX, TOUTP, TDATA, GRSTAT, &
FLLSTL, FLLSTI, DTRES, FLGHG1, FLGHG2, &
MAPMSK
!/MPI USE WMMDATMD, ONLY: MPI_COMM_MWAVE, MPI_COMM_GRD, &
!/MPI MPI_COMM_BCT, CROOT, FBCAST
!/MPRF USE WMMDATMD, ONLY: MDSP
!/
IMPLICIT NONE
!
!/MPI INCLUDE "mpif.h"
!/
!/ ------------------------------------------------------------------- /
!/ Parameter list
!/
INTEGER, INTENT(IN) :: TEND(2,NRGRD)
!/
!/ ------------------------------------------------------------------- /
!/ Local parameters
!/
INTEGER :: J, JJ, I, JO, TPRNT(2), TAUX(2), &
II, JJJ, IX, IY, UPNEXT(2), UPLAST(2)
!/T INTEGER :: ILOOP
!/S INTEGER, SAVE :: IENT = 0
!/MPI INTEGER :: IERR_MPI, NMPSCS
!/MPI INTEGER, ALLOCATABLE :: STATUS(:,:)
REAL :: DTTST, DTMAXI
!/MPRF REAL :: PRFT0, PRFTN, PRFTS
!/MPRF REAL(KIND=8) :: get_memory
CHARACTER(LEN=8) :: WTIME
CHARACTER(LEN=23) :: MTIME
LOGICAL :: DONE, TSTAMP, FLAGOK, DO_UPT, &
FLG_O1, FLG_O2
!/MPI LOGICAL :: FLAG
LOGICAL, ALLOCATABLE :: FLSYNC(:), GRSYNC(:), TMSYNC(:), &
FLEQOK(:)
!/MPI LOGICAL, ALLOCATABLE :: PREGTB(:), PREGTH(:), PREGTE(:)
!/
!/ ------------------------------------------------------------------- /
!
!/S CALL STRACE (IENT, 'WMWAVE')
!
!/MPRF CALL PRTIME ( PRFT0 )
!
!/O10 IF ( MDSS.NE.MDSO .AND. NMPSCR.EQ.IMPROC ) WRITE (MDSS,900)
!
! 0. Initializations ------------------------------------------------ /
! 0.a Initial testing
! Test GRSTAT
!
DO I=1, NRGRD
IF ( ( GRSTAT(I).LT.0 .OR. GRSTAT(I).GT.7 ) .AND. &
GRSTAT(I).NE.99 ) GOTO 2000
!
! Consistency of times for grids
!
IF ( TSYNC(1,I) .NE. -1 ) THEN
DTTST = DSEC21 ( TSYNC(:,I), TEND(:,I) )
IF ( DTTST .LT. 0. ) GOTO 2001
END IF
END DO
!
! Consistency of times within groups, set global TSYNC(:,0)
!
DO J=1, NRGRP
DO JJ=2, INGRP(J,0)
IF ( DSEC21(TSYNC(:,INGRP(J,1)),TSYNC(:,INGRP(J,JJ))).NE.0. &
.OR. DSEC21(TEND(:,INGRP(J,1)),TEND(:,INGRP(J,JJ))).NE.0. ) &
GOTO 2002
END DO
IF ( GRANK(INGRP(J,1)).EQ.1 .AND. TSYNC(1,0).EQ.-1 ) &
TSYNC(:,0) = TSYNC(:,INGRP(J,1))
END DO
!
! Check if FLSYNC initialized
!
IF ( .NOT. ALLOCATED(FLSYNC) ) THEN
ALLOCATE ( FLSYNC(NRGRD), GRSYNC(NRGRP), TMSYNC(NRGRD), &
FLEQOK(NRGRD) )
!/MPI ALLOCATE ( PREGTB(NRGRD), PREGTH(NRGRD), PREGTE(NRGRD) )
FLSYNC = .FALSE.
GRSYNC = .FALSE.
TMSYNC = .TRUE.
FLEQOK = .FALSE.
!/MPI PREGTB = .FALSE.
!/MPI PREGTH = .FALSE.
!/MPI PREGTE = .FALSE.
END IF
!
! 0.b Reset GRSTAT as needed
!
DO I=1, NRGRD
CALL W3SETW ( I, MDSE, MDST )
DTTST = DSEC21 ( TIME, TEND(:,I) )
IF ( GRSTAT(I).EQ.99 .AND. DTTST.GT.0. ) GRSTAT(I) = 0
END DO
!
! 0.c Other initializations
!
DTRES = 0.
!/MPI NMPSCS = NMPSCR
!
IF ( UNIPTS ) THEN
CALL W3SETO ( 0, MDSE, MDST )
UPNEXT = TONEXT(:,2)
UPLAST = TOLAST(:,2)
DO_UPT = .TRUE.
ELSE
UPNEXT(1) = -1
UPNEXT(2) = 0
DO_UPT = .FALSE.
END IF
!
! 0.d Output
!
IF ( MDSS.NE.MDSO .AND. NMPSCR.EQ.IMPROC ) THEN
CALL WMPRNT ( MDSO, NRGRD, TSYNC(:,0), GRSTAT )
CALL STME21 ( TSYNC(:,0), MTIME )
CALL WWTIME ( WTIME )
WRITE (MDSS,901) MTIME, WTIME, MINVAL(GRSTAT), MAXVAL(GRSTAT)
TPRNT = TSYNC(:,0)
TSTAMP = .TRUE.
ENDIF
!
!/MPI CALL MPI_BARRIER (MPI_COMM_MWAVE,IERR_MPI)
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,990) PRFT0, PRFTN, get_memory()
!
! 1. Setting up loop structure -------------------------------------- /
!
!/T ILOOP = 0
!
LOOP_OUTER: DO
!
IF ( MDSS.NE.MDSO .AND. NMPSCR.EQ.IMPROC .AND. &
DSEC21(TPRNT,TSYNC(:,0)).NE.0. ) THEN
IF ( .NOT. TSTAMP ) WRITE (MDSS,*)
CALL WMPRNT ( MDSO, NRGRD, TSYNC(:,0), GRSTAT )
CALL STME21 ( TSYNC(:,0), MTIME )
CALL WWTIME ( WTIME )
WRITE (MDSS,901) MTIME, WTIME, MINVAL(GRSTAT), MAXVAL(GRSTAT)
TPRNT = TSYNC(:,0)
TSTAMP = .TRUE.
ENDIF
!
!/T ILOOP = ILOOP + 1
!/T WRITE (MDST,9000) ILOOP, TSYNC(:,0)
!/T DO I=1, NRGRD
!/T CALL W3SETW ( I, MDSE, MDST )
!/T WRITE (MDST,9001) I, GRSTAT(I), TIME, TSYNC(:,I), TEND(:,I)
!/T END DO
!/T IF ( ILOOP .EQ. -1 ) CALL EXTCDE ( 508 )
!
DONE = .FALSE.
TPRNT = TSYNC(:,0)
!
LOOP_J: DO J=1, NRGRP
!
!/MPI GRSYNC(J) = .FALSE.
!/MPI DO JJ=1, INGRP(J,0)
!/MPI I = INGRP(J,JJ)
!/MPI CALL WMSETM ( I, MDSE, MDST )
!/MPI GRSYNC(J) = GRSYNC(J) .OR. FBCAST
!/MPI END DO
!
LOOP_JJ: DO JJ=1, INGRP(J,0)
I = INGRP(J,JJ)
CALL WMSETM ( I, MDSE, MDST )
!
!/MPI IF ( GRSTAT(I).EQ.0 ) TMSYNC(I) = .NOT. FBCAST
!/MPI IF ( FBCAST ) THEN
!/MPI NMPSCR = CROOT
!/MPI ELSE
!/MPI NMPSCR = NMPSCS
!/MPI END IF
!
! 2. Update input fields -------------------------------------------- /
! ( GRSTAT = 0 )
!
! 2.a Check TDATA and finish step if data is still OK
!
!/SHRD IF ( GRSTAT(I) .EQ. 0 ) THEN
!/MPI IF ( GRSTAT(I).EQ.0 .AND. .NOT.FLSYNC(I) ) THEN
!
!/T WRITE (MDST,9002) I, GRSTAT(I), ' '
!
IF ( TDATA(1,I) .EQ. -1 ) THEN
DTTST = 0.
ELSE
CALL W3SETW ( I, MDSE, MDST )
DTTST = DSEC21 ( TIME , TDATA(:,I) )
END IF
!/T WRITE (MDST,9020) DTTST
!
IF ( DTTST .GT. 0. ) THEN
GRSTAT(I) = 1
!/T WRITE (MDST,9003) I, GRSTAT(I)
DONE = .TRUE.
END IF
!
END IF
!
! 2.b Update input and TDATA
!
!/SHRD IF ( GRSTAT(I) .EQ. 0 ) THEN
!/MPI IF ( GRSTAT(I).EQ.0 .AND. .NOT.FLSYNC(I) .AND. &
!/MPI MPI_COMM_GRD .NE. MPI_COMM_NULL ) THEN
!
!/MPRF CALL PRTIME ( PRFT0 )
IF ( DTTST .LE. 0 ) THEN
IF ( MDSS.NE.MDSO .AND. NMPSCR.EQ.IMPROC ) &
WRITE (MDSS,*)
TSTAMP = .FALSE.
CALL WMUPDT ( I, TDATA(:,I) )
!/T WRITE (MDST,9021) TIME, TDATA(:,I), TEND(:,I)
END IF
!
! 2.c Finish up if possible ( !/SHRD or .NOT. FBCAST or no update )
!
!/SHRD GRSTAT(I) = 1
!/SHRD DONE = .TRUE.
!
!/MPI IF ( .NOT. GRSYNC(J) ) THEN
!/MPIT WRITE (MDST,9902) I, GRSTAT(I), &
!/MPIT 'NO SYNC FOR TDATA NEEDED'
!/MPI GRSTAT(I) = 1
!/MPI DONE = .TRUE.
!/MPI END IF
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, get_memory(), &
!/MPRF 'ST00', I
!
END IF
!
! 2.d Synchronize in parts ( !/MPI )
!
!/MPI IF ( GRSTAT(I).EQ.0 .AND. GRSYNC(J) ) THEN
!/MPI DONE = .TRUE.
!
!/MPI IF ( FLSYNC(I) ) THEN
!/MPIT WRITE (MDST,9902) I, GRSTAT(I), &
!/MPIT 'SYNCING TDATA'
!/MPRF IF (FLSYNC(I)) CALL PRTIME ( PRFT0 )
!/MPI IF ( FBCAST ) CALL WMBCST &
!/MPI ( TDATA(1,I), 2, I, NRGRD, 1 )
!/MPRF IF (FLSYNC(I)) CALL PRTIME ( PRFTN )
!/MPRF IF (FLSYNC(I)) WRITE (MDSP,991) &
!/MPRF PRFT0, PRFTN, get_memory(), 'BCST',I
!/MPIT WRITE (MDST,9902) I, GRSTAT(I), 'SYNCING DONE'
!/MPI GRSTAT(I) = 1
!/MPI FLSYNC(I) = .FALSE.
!/MPI IF ( GRSYNC(J) ) CYCLE LOOP_JJ
!/MPI ELSE
!/MPIT WRITE (MDST,9902) I, GRSTAT(I), &
!/MPIT 'CYCLE BEFORE SYNCING TDATA'
!/MPI FLSYNC(I) = .TRUE.
!/MPI CYCLE LOOP_JJ
!/MPI END IF
!
!/MPI END IF
!
! 3. Update data from lower ranked grids ---------------------------- /
! ( GRSTAT = 1 )
!
! 3.a Skip for initial output only
!
IF ( GRSTAT(I) .EQ. 1 .AND. TSYNC(1,I) .NE. -1 ) THEN
!/T WRITE (MDST,9002) I, GRSTAT(I), 'FIRST PART'
CALL W3SETW ( I, MDSE, MDST )
DTTST = DSEC21 ( TIME, TSYNC(:,I) )
IF ( DTTST .EQ. 0. ) THEN
GRSTAT(I) = 7
!/T WRITE (MDST,9003) I, GRSTAT(I)
DONE = .TRUE.
END IF
END IF
!
! 3.b Normal processing
!
IF ( GRSTAT(I) .EQ. 1 ) THEN
!/T WRITE (MDST,9002) I, GRSTAT(I), 'SECOND PART'
!/MPRF CALL PRTIME ( PRFT0 )
!
! 3.b.1 Test if data is there
!
FLAGOK = .TRUE.
CALL W3SETW ( I, MDSE, MDST )
TAUX = TIME
DO JJJ=1, GRDLOW(I,0)
CALL W3SETW ( GRDLOW(I,JJJ), MDSE, MDST )
FLAGOK = FLAGOK .AND. DSEC21(TAUX,TIME).GT.0. &
.AND. GRSTAT(GRDLOW(I,JJJ)).EQ.5
END DO
CALL W3SETW ( I, MDSE, MDST )
!
!/T WRITE (MDST,9004) FLAGOK
!
! 3.b.1 Get the data
!
!/MPI IF ( .NOT.FLAGOK .AND. .NOT.PREGTB(I) ) THEN
!/MPI IF ( MPI_COMM_GRD.NE.MPI_COMM_NULL ) &
!/MPI CALL WMIOBG (I,FLAG)
!/MPI PREGTB(I) = .TRUE.
!/MPI END IF
!
IF ( FLAGOK ) THEN
!/SHRD CALL WMIOBG ( I, FLAGOK )
!/MPI IF ( MPI_COMM_GRD.NE.MPI_COMM_NULL ) &
!/MPI CALL WMIOBG ( I )
!/MPI PREGTB(I) = .FALSE.
GRSTAT(I) = 2
DONE = .TRUE.
END IF
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, get_memory(), &
!/MPRF 'ST01', I
END IF
!
! 4. Update model time step ----------------------------------------- /
! ( GRSTAT = 2 )
!
IF ( GRSTAT(I) .EQ. 2 ) THEN
!/T WRITE (MDST,9002) I, GRSTAT(I), ' '
!/MPRF CALL PRTIME ( PRFT0 )
!
! 4.a Check TMAX and update as necessary ( needs !/MPI synchronizaion )
!
CALL W3SETW ( I, MDSE, MDST )
IF ( TMAX(1,I) .EQ. -1 ) THEN
TMAX(:,I) = TIME
DTTST = 0.
ELSE
DTTST = DSEC21(TIME,TMAX(:,I))
END IF
!
IF ( DTTST .LE. 0 ) THEN
CALL W3SETG ( I, MDSE, MDST )
DTMAXI = REAL(NINT(DTMAX+DTRES(I)+0.0001))
DTRES(I)= DTRES(I)+ DTMAX - DTMAXI
IF ( ABS(DTRES(I)) .LT. 0.001 ) DTRES(I) = 0.
TMAX(:,I) = TIME
CALL TICK21 ( TMAX(:,I), DTMAXI )
TAUX = TMAX(:,I)
IF ( TDATA(1,I) .NE. -1 ) THEN
IF ( DSEC21(TDATA(:,I),TMAX(:,I)) .GT. 0 ) &
TMAX(:,I) = TDATA(:,I)
END IF
IF ( TOUTP(1,I) .NE. -1 ) THEN
IF ( DSEC21(TOUTP(:,I),TMAX(:,I)) .GT. 0 ) &
TMAX(:,I) = TOUTP(:,I)
END IF
IF ( UNIPTS ) THEN
IF ( DSEC21(UPNEXT,TMAX(:,I)) .GT. 0 ) &
TMAX(:,I) = UPNEXT(:)
END IF
!/T WRITE (MDST,9040) TMAX(:,I), DTRES(I), TAUX, &
!/T TDATA(:,I), TOUTP(:,I), UPNEXT
DONE = .TRUE.
CYCLE LOOP_JJ
!/T ELSE
!/T WRITE (MDST,9041) TMAX(:,I)
END IF
!
! 4.b Lowest ranked grids, minimum of all TMAXes
!
!/T WRITE (MDST,9042) GRANK(I)
!
IF ( GRANK(I) .EQ. 1 ) THEN
!
TAUX = TMAX(:,I)
FLAGOK = .TRUE.
!
! 4.b.1 Check if all grids have reached previous sync point
!
DO II=1, NRGRD
CALL W3SETW ( II, MDSE, MDST )
!/SHRD IF ( TIME(1) .NE. -1 ) THEN
!/MPI IF ( TIME(1).NE.-1 .AND. &
!/MPI MPI_COMM_GRD.NE.MPI_COMM_NULL ) THEN
IF ( DSEC21(TIME,TSYNC(:,0)) .NE. 0 ) THEN
FLAGOK = .FALSE.
EXIT
END IF
END IF
END DO
!
! 4.b.2 Check availability of data
!
DO II=1, NRGRD
IF ( GRANK(II) .EQ. 1 ) THEN
IF ( TMAX(1,II) .EQ. -1 ) THEN
FLAGOK = .FALSE.
EXIT
ELSE
IF ( DSEC21 (TAUX,TMAX(:,II)) .LT. 0. ) &
TAUX = TMAX(:,II)
END IF
END IF
END DO
!
CALL W3SETW ( I, MDSE, MDST )
FLAGOK = FLAGOK .AND. DSEC21(TIME,TAUX).GT.0.
!
! 4.b.3 Update TSYNC for all grids
!
IF ( FLAGOK ) THEN
!
TSYNC(:,0) = TAUX
DO_UPT = .TRUE.
DO II=1, NRGRD
IF ( GRANK(II) .EQ. 1 ) THEN
TSYNC(:,II) = TAUX
IF ( GRSTAT(II) .EQ. 2 ) GRSTAT(II) = 3
!/T IF ( GRSTAT(II) .EQ. 3 ) &
!/T WRITE (MDST,9003) II, GRSTAT(II)
END IF
END DO
DONE = .TRUE.
!/MPRF CALL PRTIME ( PRFTS )
!/MPRF WRITE (MDSP,992) PRFTS, PRFTS, &
!/MPRF get_memory(), 'TIME', TSYNC(:,0)
!
! 4.b.4 Output
!
!/T WRITE (MDST,9043) TSYNC(:,0)
!/T WRITE (MDST,9045)
!/T WRITE (MDST,9046) (II,TSYNC(:,II),II=0,NRGRD)
!
! 4.b.5 Skip computations so that all grids start processing
! simultaneously.
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, &
!/MPRF get_memory(), 'ST02', I
!/T IF ( INGRP(J,0) .GT. 1 ) WRITE (MDST,9006)
IF ( INGRP(J,0) .GT. 1 ) GOTO 1111
!
END IF
!
! 4.c Other grids, logical from relations and TMAXes
!
ELSE IF ( TSYNC(1,0) .NE. -1 ) THEN
!
TAUX = TSYNC(:,0)
FLAGOK = .TRUE.
!
! 4.c.1 Check availability of data within group
! Time within group needs to be the same for load balancing.
!
DO JJJ=1, INGRP(J,0)
II = INGRP(J,JJJ)
IF ( TMAX(1,II) .EQ. -1 ) THEN
FLAGOK = .FALSE.
EXIT
ELSE
IF ( DSEC21 (TAUX,TMAX(:,II)) .LT. 0. ) &
TAUX = TMAX(:,II)
END IF
END DO
!
! 4.c.2 Check with dependent lower rank grids ( TSYNC )
!
DO JJJ=1, GRDLOW(I,0)
II = GRDLOW(I,JJJ)
IF ( TSYNC(1,II) .EQ. -1 ) THEN
FLAGOK = .FALSE.
EXIT
ELSE
IF ( DSEC21 (TAUX,TSYNC(:,II)) .LT. 0. ) &
TAUX = TSYNC(:,II)
END IF
END DO
!
! 4.c.3 Check with dependent higher rank grids ( TSYNC )
! No check needed
!
! 4.c.4 Final check against grid time
!
CALL W3SETW ( I, MDSE, MDST )
FLAGOK = FLAGOK .AND. DSEC21(TIME,TAUX).GT.0.
!
! 4.c.5 Update TSYNC throughout group
!
IF ( FLAGOK ) THEN
!
DO JJJ=1, INGRP(J,0)
II = INGRP(J,JJJ)
TSYNC(:,II) = TAUX
IF ( GRSTAT(II) .EQ. 2 ) GRSTAT(II) = 3
!/T IF ( GRSTAT(II) .EQ. 3 ) &
!/T WRITE (MDST,9003) II, GRSTAT(II)
END DO
DONE = .TRUE.
!
!/T WRITE (MDST,9044) TSYNC(:,I), TAUX
!/T WRITE (MDST,9045)
!/T WRITE (MDST,9046) (II,TSYNC(:,II),II=0,NRGRD)
!
! 4.c.6 Skip computations so that all grids in group are advanced
! simultaneously.
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, &
!/MPRF get_memory(), 'ST02', I
!/T IF ( INGRP(J,0) .GT. 1 ) WRITE (MDST,9006)
IF ( INGRP(J,0) .GT. 1 ) GOTO 1111
!
END IF
!
END IF
!
END IF
!
! 5. Run the wave model --------------------------------------------- /
! ( GRSTAT = 3 ) w3xdatmd data structures set in W3WAVE
!
! 5.a Run model
!
!/SHRD IF ( GRSTAT(I) .EQ. 3 ) THEN
!
!/MPI IF ( GRSTAT(I).EQ.3 .AND. &
!/MPI MPI_COMM_GRD .EQ. MPI_COMM_NULL ) THEN
!/MPI CALL W3SETW ( I, MDSE, MDST )
!/MPI TIME = TSYNC(:,I)
!/MPI GRSTAT(I) = 4
!/MPI DONE = .TRUE.
!/MPI ELSE IF ( GRSTAT(I).EQ.3 .AND. &
!/MPI MPI_COMM_GRD .NE. MPI_COMM_NULL ) THEN
!
!/T WRITE (MDST,9002) I, GRSTAT(I), 'RUNNING MODEL'
!/MPRF CALL PRTIME ( PRFT0 )
!
CALL WMSETM ( I, MDSE, MDST )
CALL W3WAVE ( I, TSYNC(:,I), .FALSE., .TRUE. )
IF ( FLLSTL ) INFLAGS1(1) = .FALSE.
IF ( FLLSTI ) INFLAGS1(4) = .FALSE.
!
! 5.b Stage data for grids with equal rank
!
!/MPI CALL WMIOEF ( I )
CALL WMIOES ( I )
!
! 5.c Finish up
!
GRSTAT(I) = 4
DONE = .TRUE.
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, get_memory(), &
!/MPRF 'ST03', I
!
END IF
!
! 6. Reconcile grids with same rank --------------------------------- /
! and stage data transfer to higher and lower ranked grids.
! ( GRSTAT = 4 )
!
IF ( GRSTAT(I) .EQ. 4 ) THEN
!/MPRF CALL PRTIME ( PRFT0 )
!
! 6.a Test against times and statuses of dependent grids
! Note: This is done per GROUP, not per local equal grid dependence
! Therefore, it is essential that sync times per group are
! equal (4.c.1) and that all equal grid dependences are a
! subset of groups (WMGEQL 5.d)
!
!/T WRITE (MDST,9002) I, GRSTAT(I), 'FIRST PART'
!/T WRITE (MDST,9005) FLEQOK(I)
!
! 6.a.1 Check if sync point is reached
!
IF ( .NOT. FLEQOK(I) ) THEN
!
FLAGOK = .TRUE.
CALL W3SETW ( I, MDSE, MDST )
TAUX = TIME
DO JJJ=1, INGRP(J,0)
CALL W3SETW ( INGRP(J,JJJ), MDSE, MDST )
FLAGOK = FLAGOK .AND. DSEC21(TAUX,TIME).EQ.0. &
.AND. GRSTAT(INGRP(J,JJJ)).EQ.4
END DO
CALL W3SETW ( I, MDSE, MDST )
!/T WRITE (MDST,9004) FLAGOK
!
! 6.a.2 Point reached, set flag for all in group and cycle
!
IF ( FLAGOK ) THEN
DO JJJ=1, INGRP(J,0)
FLEQOK(INGRP(J,JJJ)) = .TRUE.
!/T WRITE (MDST,9061) INGRP(J,JJJ), &
!/T FLEQOK(INGRP(J,JJJ))
END DO
DONE = .TRUE.
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, &
!/MPRF get_memory(), 'ST04', I
!
!/T IF ( INGRP(J,0) .GT. 1 ) WRITE (MDST,9006)
IF ( INGRP(J,0) .GT. 1 ) GOTO 1111
END IF
!
END IF
!
! 6.b Call gathering routine, reset FLEQOK and cycle
!
!/MPI IF ( .NOT.FLEQOK(I) .AND. .NOT.PREGTE(I) ) THEN
!/MPI IF ( MPI_COMM_GRD.NE.MPI_COMM_NULL ) &
!/MPI CALL WMIOEG (I,FLAG)
!/MPI PREGTE(I) = .TRUE.
!/MPI END IF
!
IF ( FLEQOK(I) ) THEN
!/SHRD CALL WMIOEG ( I )
!/MPI IF ( MPI_COMM_GRD.NE.MPI_COMM_NULL ) &
!/MPI CALL WMIOEG ( I )
!/MPI PREGTE(I) = .FALSE.
GRSTAT(I) = 5
FLEQOK(I) = .FALSE.
DONE = .TRUE.
END IF
!
! 6.c Stage data
!
IF ( GRSTAT(I) .EQ. 5 ) THEN
!
!/T WRITE (MDST,9002) I, GRSTAT(I)-1, 'SECOND PART'
!
!/SHRD CALL WMIOBS ( I )
!
!/MPI IF ( MPI_COMM_GRD .NE. MPI_COMM_NULL ) THEN
!/MPI CALL WMIOBF ( I )
!/MPI CALL WMIOBS ( I )
!/MPI END IF
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, &
!/MPRF get_memory(), 'ST04', I
CYCLE LOOP_JJ
!
END IF
!
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, &
!/MPRF get_memory(), 'ST04', I
!
END IF
!
! 7. Reconcile with higher ranked grids ----------------------------- /
! ( GRSTAT = 5 )
!
! This needs to be a little more complicated than with boundary
! data to assure proper logic in cases where data providing
! data does not get data back (e.g., as for the boundary grid
! in mww3_test_04)
!
IF ( GRSTAT(I) .EQ. 5 ) THEN
!/MPRF CALL PRTIME ( PRFT0 )
!/T WRITE (MDST,9002) I, GRSTAT(I), ' '
!
! 7.a Test against times and statuses of dependent grids
!
IF ( GRDHGH(I,0) .EQ. 0 ) THEN
GRSTAT(I) = 6
DONE = .TRUE.
ELSE
!
FLAGOK = .TRUE.
CALL W3SETW ( I, MDSE, MDST )
TAUX = TIME
DO JJJ=1, GRDHGH(I,0)
CALL W3SETW ( GRDHGH(I,JJJ), MDSE, MDST )
IF ( .NOT. ( DSEC21(TAUX,TIME).EQ.0. .AND. &
( GRSTAT(GRDHGH(I,JJJ)).GE.7 .OR. &
GRSTAT(GRDHGH(I,JJJ)).LE.2 ) ) ) &
FLAGOK = .FALSE.
END DO
CALL W3SETW ( I, MDSE, MDST )
!
!/T WRITE (MDST,9004) FLAGOK
!
! 7.b Call gathering routine
!
!/MPI IF ( .NOT.FLAGOK .AND. .NOT.PREGTH(I) ) THEN
!/MPI IF ( MPI_COMM_GRD.NE.MPI_COMM_NULL ) &
!/MPI CALL WMIOHG ( I, FLAG )
!/MPI PREGTH(I) = .TRUE.
!/MPI END IF
!
IF ( FLAGOK ) THEN
!/SHRD CALL WMIOHG ( I, FLAGOK )
!/MPI IF ( MPI_COMM_GRD.NE.MPI_COMM_NULL ) &
!/MPI CALL WMIOHG ( I )
!/MPI PREGTH(I) = .FALSE.
GRSTAT(I) = 6
DONE = .TRUE.
END IF
!
END IF
!
! 7.c Stage data
!
!/SHRD IF ( GRSTAT(I) .EQ. 6 ) CALL WMIOHS ( I )
!
!/MPI IF ( GRSTAT(I) .EQ. 6 .AND. &
!/MPI MPI_COMM_GRD .NE. MPI_COMM_NULL ) THEN
!/MPI CALL WMIOHF ( I )
!/MPI CALL WMIOHS ( I )
!/MPI END IF
!
!/T IF (GRSTAT(I).EQ.6) WRITE(MDST,9003) I, GRSTAT(I)
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, get_memory(), &
!/MPRF 'ST05', I
END IF
!
! 8. Perform data assimmilation ------------------------------------- /
! ( GRSTAT = 6 ) Placeholder only .....
!
IF ( GRSTAT(I) .EQ. 6 ) THEN
!/MPRF CALL PRTIME ( PRFT0 )
!/T WRITE (MDST,9002) I, GRSTAT(I), ' '
GRSTAT(I) = 7
!/MPRF CALL PRTIME ( PRFTN )
!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, get_memory(), &
!/MPRF 'ST06', I
DONE = .TRUE.
END IF
!
! 9. Perform output ------------------------------------------------- /
! ( GRSTAT = 7 ) w3xdatmd data structures set in W3WAVE
!
!
! 9.a Check times and finish step if no output to be made
!
!/SHRD IF ( GRSTAT(I) .EQ. 7 ) THEN
!/MPI IF ( GRSTAT(I).EQ.7 .AND. .NOT.FLSYNC(I) ) THEN
!
!/T WRITE (MDST,9002) I, GRSTAT(I), ' '
!
IF ( TOUTP(1,I) .EQ. -1 ) THEN
DTTST = 1.
ELSE
CALL W3SETW ( I, MDSE, MDST )
DTTST = DSEC21 ( TIME , TOUTP(:,I) )
END IF
!/T WRITE (MDST,9090) DTTST
FLG_O1 = DTTST .EQ. 0.
!
IF ( UNIPTS ) THEN
CALL W3SETW ( I, MDSE, MDST )
DTTST = DSEC21 ( TIME , UPNEXT )
FLG_O2 = DTTST .EQ. 0.
ELSE
FLG_O2 = .FALSE.
END IF
!
IF ( .NOT.FLG_O1 .AND. .NOT.FLG_O2 ) THEN
GRSTAT(I) = 8
!/T WRITE (MDST,9003) I, GRSTAT(I)
DONE = .TRUE.
END IF
!
END IF
!
! 9.b Perform output
!
IF ( GRSTAT(I) .EQ. 7 ) THEN
!/MPI IF ( MPI_COMM_GRD .NE. MPI_COMM_NULL ) THEN
!
!!/MPRF CALL PRTIME ( PRFT0 )
!!/MPRF CALL WMWOUT ( I, NRGRD, 3 )
!!/MPRF CALL PRTIME ( PRFTN )
!!/MPRF WRITE (MDSP,991) PRFT0, PRFTN, get_memory(), &
!!/MPRF 'BCST',I
!
!/MPRF CALL PRTIME ( PRFT0 )
!
IF ( FLG_O1 ) THEN
CALL W3SETG ( I, MDSE, MDST )
CALL WMSETM ( I, MDSE, MDST )
!