build.gradle.kts

import java.util.Properties

val versionPropertiesFile = file("version.properties")
val versionString = Properties().run {
	versionPropertiesFile.inputStream().use(::load)
	val majorVersion = get("MAJOR_VERSION") as String
	val minorVersion = get("MINOR_VERSION") as String
	val patchVersion = get("PATCH_VERSION") as String
	val suffix = get("SUFFIX") as String
	val isSnapshot = (get("SNAPSHOT") as String).toBoolean()
	return@run buildString {
		append("$majorVersion.$minorVersion.$patchVersion")
		if (suffix.isNotEmpty()) {
			append("-$suffix")
		}
		if (isSnapshot) {
			append("-SNAPSHOT")
		}
	}
}

val publishGroupId by extra("io.github.solrudev")
val publishVersion by extra(versionString)
group = publishGroupId
version = publishVersion

plugins {
	id("io.github.gradle-nexus.publish-plugin") version "1.3.0"
}

buildscript {
	val androidGradleVersion by extra("8.2.0")
	dependencies {
		classpath("com.android.tools.build:gradle:$androidGradleVersion")
		classpath(kotlin("gradle-plugin", "1.9.21"))
	}
}

tasks.register<Delete>("clean").configure {
	delete(rootProject.layout.buildDirectory)
}

val ossrhUsername by extra("")
val ossrhPassword by extra("")
val sonatypeStagingProfileId by extra("")
extra["signing.keyId"] = ""
extra["signing.password"] = ""
extra["signing.key"] = ""

val secretPropertiesFile = file("local.properties")
if (secretPropertiesFile.exists()) {
	Properties().run {
		secretPropertiesFile.inputStream().use(::load)
		forEach { name, value -> extra[name as String] = value }
	}
}

extra["ossrhUsername"] = System.getenv("OSSRH_USERNAME") ?: extra["ossrhUsername"]
extra["ossrhPassword"] = System.getenv("OSSRH_PASSWORD") ?: extra["ossrhPassword"]
extra["sonatypeStagingProfileId"] = System.getenv("SONATYPE_STAGING_PROFILE_ID") ?: extra["sonatypeStagingProfileId"]
extra["signing.keyId"] = System.getenv("SIGNING_KEY_ID") ?: extra["signing.keyId"]
extra["signing.password"] = System.getenv("SIGNING_PASSWORD") ?: extra["signing.password"]
extra["signing.key"] = System.getenv("SIGNING_KEY") ?: extra["signing.key"]

nexusPublishing {
	this.repositories {
		sonatype {
			stagingProfileId.set(sonatypeStagingProfileId)
			username.set(ossrhUsername)
			password.set(ossrhPassword)
			nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
			snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
		}
	}
}