test: add transition from v2 to v3 rewards test (#50)

<!-- Reviewable:start -->
This change is [<img src="https://reviewable.io/review_button.svg" height="34" align="absmiddle" alt="Reviewable"/>](https://reviewable.io/reviews/starkware-libs/starknet-staking/50)
<!-- Reviewable:end -->

<!-- CURSOR_SUMMARY -->
---

> [!NOTE]
> Adds a flow test validating update_rewards behavior across the v2 (attestation) → v3 (consensus) transition, plus minor flow ideas cleanup.
> 
> - **Tests**:
>   - **`update_rewards_transition_from_attestation_to_consensus_flow_test`**: New end-to-end flow validating rewards across the switch from attestation-based (v2) to consensus-based (v3) rewards, including expected panics and `disable_rewards` handling. Uses `IStakingAttestationDispatcher` and `IStakingAttestationSafeDispatcher` imports.
> - **Docs**:
>   - **`src/flow_test/flow_ideas.md`**: Remove obsolete "v3 flag" scenario notes.
> 
> <sup>Written by [Cursor Bugbot](https://cursor.com/dashboard?tab=bugbot) for commit 37a0904. This will update automatically on new commits. Configure [here](https://cursor.com/dashboard?tab=bugbot).</sup>
<!-- /CURSOR_SUMMARY -->

Author: arad-starkware

src/flow_test/flow_ideas.md

@@ -15,9 +15,6 @@
 - staker change balance, attest, change balance, attest, set_v3, change balance, update_rewards, change_balance, update_rewards, test rewards.
 - with member from previous versions.
 
-## v3 flag
-- update_rewards_from_attestation, update_rewards (not distribute), set_v3_epoch, update_rewards_from_attestation, update_rewards (not distribute), advance epoch to v3 epoch, update_rewards_from_attestation-panic, update_rewards-distribute, advance epoch, update_rewards_from_attestation-panic, update_rewards-distribute, advance epoch, update_rewards_from_attestation-panic, update_rewards with disable rewards-not distribute.
-
 ## k=1 -> k=2 balances
 - staker with stake, upgrade, increase stake - before upgrade after 1 epoch, after 2 epochs (check also total stake)
 - delegator delegate, upgrade, add delegation - same

src/flow_test/test.cairo

@@ -11,6 +11,8 @@ use staking::pool::pool::Pool::STRK_CONFIG;
 use staking::pool::utils::compute_rewards_rounded_down;
 use staking::staking::errors::Error as StakingError;
 use staking::staking::interface::{
+    IStakingAttestationDispatcher, IStakingAttestationDispatcherTrait,
+    IStakingAttestationSafeDispatcher, IStakingAttestationSafeDispatcherTrait,
     IStakingConsensusDispatcherTrait, IStakingDispatcherTrait,
     IStakingRewardsManagerSafeDispatcherTrait,
 };
@@ -2627,6 +2629,137 @@ fn get_stakers_staking_power_100_flow_test() {
     assert!(stakers == expected_stakers);
 }
 
+/// Flow:
+/// Staker stake
+/// Update rewards from attestation - test rewards
+/// Update_rewards - test no rewards
+/// Set consensus epoch (in K epochs)
+/// Update rewards from attestation - test rewards
+/// Update_rewards - test no rewards
+/// Advance to consensus epoch
+/// Update rewards from attestation - panic
+/// Update_rewards - test rewards
+/// Advance epoch
+/// Update rewards from attestation - panic
+/// Update_rewards - test rewards
+/// Advance epoch
+/// Update rewards from attestation - panic
+/// Update_rewards with disable_rewards = true - test no rewards
+#[test]
+#[feature("safe_dispatcher")]
+fn update_rewards_transition_from_attestation_to_consensus_flow_test() {
+    let cfg: StakingInitConfig = Default::default();
+    let mut system = SystemConfigTrait::basic_stake_flow_cfg(:cfg).deploy();
+    let stake_amount = system.staking.get_min_stake();
+    let minting_curve_contract = system.minting_curve.address;
+    let staking_contract = system.staking.address;
+    let staker = system.new_staker(amount: stake_amount);
+    let staking_attestation = IStakingAttestationDispatcher { contract_address: staking_contract };
+    let staking_attestation_safe = IStakingAttestationSafeDispatcher {
+        contract_address: staking_contract,
+    };
+    let commission = 200;
+    system.stake(:staker, amount: stake_amount, pool_enabled: false, :commission);
+    system.advance_k_epochs();
+
+    // Update rewards from attestation
+    cheat_caller_address_once(
+        contract_address: system.staking.address,
+        caller_address: system.attestation.unwrap().address,
+    );
+    staking_attestation
+        .update_rewards_from_attestation_contract(staker_address: staker.staker.address);
+    let rewards = system.staker_claim_rewards(:staker);
+    let (expected_rewards_v2, _) = calculate_staker_strk_rewards_with_balances_v2(
+        amount_own: stake_amount,
+        pool_amount: Zero::zero(),
+        :commission,
+        :staking_contract,
+        :minting_curve_contract,
+    );
+    assert!(expected_rewards_v2.is_non_zero());
+    assert!(rewards == expected_rewards_v2);
+
+    // Call update_rewards - no rewards
+    system.update_rewards(:staker, disable_rewards: false);
+    let rewards = system.staker_claim_rewards(:staker);
+    assert!(rewards == Zero::zero());
+
+    // Set consensus rewards first epoch
+    system.advance_epoch();
+    system
+        .staking
+        .set_consensus_rewards_first_epoch(epoch_id: system.staking.get_current_epoch() + K.into());
+
+    // Update rewards from attestation - test rewards
+    cheat_caller_address_once(
+        contract_address: system.staking.address,
+        caller_address: system.attestation.unwrap().address,
+    );
+    staking_attestation
+        .update_rewards_from_attestation_contract(staker_address: staker.staker.address);
+    let rewards = system.staker_claim_rewards(:staker);
+    assert!(rewards == expected_rewards_v2);
+
+    // Call update_rewards - no rewards
+    system.update_rewards(:staker, disable_rewards: false);
+    let rewards = system.staker_claim_rewards(:staker);
+    assert!(rewards == Zero::zero());
+
+    // Advance to consensus epoch
+    system.advance_k_epochs();
+
+    // Update rewards from attestation - panic
+    let result = staking_attestation_safe
+        .update_rewards_from_attestation_contract(staker_address: staker.staker.address);
+    assert_panic_with_error(
+        :result, expected_error: StakingError::CONSENSUS_REWARDS_IS_ACTIVE.describe(),
+    );
+
+    // Call update_rewards - test rewards
+    system.update_rewards(:staker, disable_rewards: false);
+    let rewards = system.staker_claim_rewards(:staker);
+    let (expected_rewards_v3, _) = calculate_staker_strk_rewards_with_balances_v3(
+        amount_own: stake_amount,
+        pool_amount: Zero::zero(),
+        :commission,
+        :staking_contract,
+        :minting_curve_contract,
+    );
+    assert!(expected_rewards_v3.is_non_zero());
+    assert!(rewards == expected_rewards_v3);
+
+    // Advance epoch
+    system.advance_epoch();
+
+    // Update rewards from attestation - panic
+    let result = staking_attestation_safe
+        .update_rewards_from_attestation_contract(staker_address: staker.staker.address);
+    assert_panic_with_error(
+        :result, expected_error: StakingError::CONSENSUS_REWARDS_IS_ACTIVE.describe(),
+    );
+
+    // Call update_rewards - test rewards
+    system.update_rewards(:staker, disable_rewards: false);
+    let rewards = system.staker_claim_rewards(:staker);
+    assert!(rewards == expected_rewards_v3);
+
+    // Advance epoch
+    system.advance_epoch();
+
+    // Update rewards from attestation - panic
+    let result = staking_attestation_safe
+        .update_rewards_from_attestation_contract(staker_address: staker.staker.address);
+    assert_panic_with_error(
+        :result, expected_error: StakingError::CONSENSUS_REWARDS_IS_ACTIVE.describe(),
+    );
+
+    // Call update_rewards with disable rewards = true - no rewards
+    system.update_rewards(:staker, disable_rewards: true);
+    let rewards = system.staker_claim_rewards(:staker);
+    assert!(rewards == Zero::zero());
+}
+
 /// Flow:
 /// Staker stake
 /// Disable rewards is true with consensus off - test no rewards