feat: update orioledb extension

Expose patchset and revision attributes in postgresql to build orioledb
properly.

Add NixOS VM test for orioledb extension validation.

Author: jfroche

nix/ext/orioledb.nix

@@ -15,8 +15,8 @@ stdenv.mkDerivation rec {
   src = fetchFromGitHub {
     owner = "orioledb";
     repo = "orioledb";
-    rev = "beta12";
-    sha256 = "sha256-5dyVdKD1PzW+F5OPW3TR3OKBaJxxR3OhLbzK+o9Wf+Q=";
+    rev = "f147bf21fea29965c18e4f3bb9d1e57e713376b2";
+    sha256 = "sha256-W3AquOCeTYv9jLsh0VV+wW9w8mGZnpLVZDWaxmVIiX8=";
   };
   version = "beta12";
   buildInputs = [
@@ -26,7 +26,9 @@ stdenv.mkDerivation rec {
     python3
     openssl
   ];
-  buildPhase = "make USE_PGXS=1 ORIOLEDB_PATCHSET_VERSION=11";
+  buildPhase = ''
+    make USE_PGXS=1 ORIOLEDB_PATCHSET_VERSION=${postgresql.patchset} all
+  '';
   installPhase = ''
     runHook preInstall
 

nix/ext/tests/orioledb.nix

@@ -0,0 +1,82 @@
+{ self, pkgs }:
+let
+  pname = "orioledb";
+  inherit (pkgs) lib;
+  postgresqlWithExtension =
+    postgresql:
+    let
+      majorVersion = lib.versions.major postgresql.version;
+      pkg = pkgs.buildEnv {
+        name = "postgresql-${majorVersion}-${pname}";
+        paths = [
+          postgresql
+          postgresql.lib
+          self.packages.${pkgs.system}."psql_orioledb-17/exts/orioledb"
+        ];
+        passthru = {
+          inherit (postgresql) version psqlSchema;
+          lib = pkg;
+          withPackages = _: pkg;
+        };
+        nativeBuildInputs = [ pkgs.makeWrapper ];
+        pathsToLink = [
+          "/"
+          "/bin"
+          "/lib"
+        ];
+        postBuild = ''
+          wrapProgram $out/bin/postgres --set NIX_PGLIBDIR $out/lib
+          wrapProgram $out/bin/pg_ctl --set NIX_PGLIBDIR $out/lib
+          wrapProgram $out/bin/pg_upgrade --set NIX_PGLIBDIR $out/lib
+        '';
+      };
+    in
+    pkg;
+  psql_orioledb = postgresqlWithExtension self.packages.${pkgs.system}.postgresql_orioledb-17;
+in
+self.inputs.nixpkgs.lib.nixos.runTest {
+  name = pname;
+  hostPkgs = pkgs;
+  nodes.server =
+    { ... }:
+    {
+      virtualisation = {
+        forwardPorts = [
+          {
+            from = "host";
+            host.port = 13022;
+            guest.port = 22;
+          }
+        ];
+      };
+      services.openssh = {
+        enable = true;
+      };
+
+      services.postgresql = {
+        enable = true;
+        package = psql_orioledb;
+        settings = {
+          shared_preload_libraries = "orioledb";
+          default_table_access_method = "orioledb";
+        };
+        initdbArgs = [
+          "--allow-group-access"
+          "--locale-provider=icu"
+          "--encoding=UTF-8"
+          "--icu-locale=en_US.UTF-8"
+        ];
+        initialScript = pkgs.writeText "init-postgres-with-orioledb" ''
+          CREATE EXTENSION orioledb CASCADE;
+        '';
+      };
+    };
+  testScript =
+    { ... }:
+    ''
+      start_all()
+
+      server.wait_for_unit("multi-user.target")
+      server.wait_for_unit("postgresql.service")
+    '';
+}

nix/postgresql/generic.nix

@@ -131,18 +131,15 @@ let
         ++ lib.optionals gssSupport [ libkrb5 ]
         ++ lib.optionals stdenv'.isLinux [ linux-pam ]
         ++ lib.optionals (!stdenv'.isDarwin) [ libossp_uuid ]
-        ++
-          lib.optionals
-            (isOrioleDB || (lib.versionAtLeast version "17"))
-            [
-              perl
-              bison
-              flex
-              docbook_xsl
-              docbook_xml_dtd_45
-              docbook_xsl_ns
-              libxslt
-            ];
+        ++ lib.optionals (isOrioleDB || (lib.versionAtLeast version "17")) [
+          perl
+          bison
+          flex
+          docbook_xsl
+          docbook_xml_dtd_45
+          docbook_xsl_ns
+          libxslt
+        ];
 
       nativeBuildInputs =
         [
@@ -292,13 +289,20 @@ let
         in
         {
           psqlSchema = lib.versions.major version;
+          inherit revision;
 
           withJIT = if jitSupport then this else jitToggle;
           withoutJIT = if jitSupport then jitToggle else this;
 
           dlSuffix = if olderThan "16" then ".so" else stdenv.hostPlatform.extensions.sharedLibrary;
           inherit isOrioleDB;
 
+          patchset =
+            if isOrioleDB then
+              if revision != null then revision else builtins.elemAt (builtins.split "_" version) 2
+            else
+              null;
+
           pkgs =
             let
               scope = {
@@ -411,7 +415,13 @@ let
       '';
 
       passthru = {
-        inherit (postgresql) version psqlSchema isOrioleDB;
+        inherit (postgresql)
+          version
+          revision
+          patchset
+          psqlSchema
+          isOrioleDB
+          ;
       };
     };
 in