diff --git a/.gitignore b/.gitignore
index d32cc8f60..dd55b82e9 100644
--- a/.gitignore
+++ b/.gitignore
@@ -17,6 +17,7 @@ __pycache__/
 result*
 .env-local
 .history
+.nixos-test-history
 
 
 #IDE
diff --git a/flake.nix b/flake.nix
index f4c333fbb..5250f3718 100644
--- a/flake.nix
+++ b/flake.nix
@@ -1381,6 +1381,7 @@
           psql_15 = makeCheckHarness basePackages.psql_15.bin;
           psql_17 = makeCheckHarness basePackages.psql_17.bin;
           psql_orioledb-17 = makeCheckHarness basePackages.psql_orioledb-17.bin;
+          pg_hashids = import ./nix/tests/pg_hashids.nix { inherit self; inherit pkgs; };
         };
 
         # Apps is a list of names of things that can be executed with 'nix run';
diff --git a/nix/ext/pg_hashids.nix b/nix/ext/pg_hashids.nix
index 828db60fb..bf38ca95d 100644
--- a/nix/ext/pg_hashids.nix
+++ b/nix/ext/pg_hashids.nix
@@ -1,30 +1,92 @@
-{ lib, stdenv, fetchFromGitHub, postgresql }:
+{ pkgs, lib, stdenv, fetchFromGitHub, postgresql }:
 
-stdenv.mkDerivation rec {
+let
   pname = "pg_hashids";
-  version = "cd0e1b31d52b394a0df64079406a14a4f7387cd6";
+  build = version: hash: revision:
+    stdenv.mkDerivation rec {
+      inherit pname version;
 
-  buildInputs = [ postgresql ];
+      buildInputs = [ postgresql ];
 
-  src = fetchFromGitHub {
-    owner = "iCyberon";
-    repo = pname;
-    rev = "${version}";
-    hash = "sha256-Nmb7XLqQflYZfqj0yrewfb1Hl5YgEB5wfjBunPwIuOU=";
-  };
+      src = fetchFromGitHub {
+        owner = "iCyberon";
+        repo = pname;
+        rev = version;
+        inherit hash;
+      };
+
+      installPhase = ''
+        mkdir -p $out/{lib,share/postgresql/extension}
+
+        mv ${pname}${postgresql.dlSuffix} $out/lib/${pname}-${version}${postgresql.dlSuffix}
+
+        create_sql_files() {
+          if test -f ${pname}--${version}.sql; then
+            cp ${pname}--${version}.sql $out/share/postgresql/extension
+          fi
+          echo "Creating SQL files for previous versions..."
+          if [[ "${version}" == "${latestVersion}" ]]; then
+            cp *.sql $out/share/postgresql/extension
+
+            # anything after 1.2.1 is unreleased
+            cp pg_hashids--1.3.sql $out/share/postgresql/extension/pg_hashids--${version}.sql
+            cp pg_hashids--1.2.1--1.3.sql $out/share/postgresql/extension/pg_hashids--1.2.1--${version}.sql
+          fi
+        }
+
+        create_control_files() {
+          sed -e "/^default_version =/d" \
+              -e "s|^module_pathname = .*|module_pathname = '\$libdir/${pname}'|" \
+            ${pname}.control > $out/share/postgresql/extension/${pname}--${version}.control
+
+          if [[ "${version}" == "${latestVersion}" ]]; then
+            {
+              echo "default_version = '${latestVersion}'"
+              cat $out/share/postgresql/extension/${pname}--${latestVersion}.control
+            } > $out/share/postgresql/extension/${pname}.control
+            ln -sfn ${pname}-${latestVersion}${postgresql.dlSuffix} $out/lib/${pname}${postgresql.dlSuffix}
+          fi
+        }
 
-  installPhase = ''
-    mkdir -p $out/{lib,share/postgresql/extension}
+        create_sql_files
+        create_control_files
+      '';
 
-    cp *${postgresql.dlSuffix}      $out/lib
-    cp *.sql     $out/share/postgresql/extension
-    cp *.control $out/share/postgresql/extension
+      meta = with lib; {
+        description = "Generate short unique IDs in PostgreSQL";
+        homepage = "https://github.com/iCyberon/pg_hashids";
+        license = licenses.postgresql;
+        inherit (postgresql.meta) platforms;
+      };
+    };
+  allVersions =
+    (builtins.fromJSON (builtins.readFile ./versions.json)).pg_hashids;
+  supportedVersions = lib.filterAttrs (_: value:
+    builtins.elem (lib.versions.major postgresql.version) value.postgresql)
+    allVersions;
+  versions = lib.naturalSort (lib.attrNames supportedVersions);
+  latestVersion = lib.last versions;
+  numberOfVersions = builtins.length versions;
+  packages = builtins.attrValues
+    (lib.mapAttrs (name: value: build name value.hash (value.revision or name))
+      supportedVersions);
+in pkgs.buildEnv {
+  name = pname;
+  paths = packages;
+  pathsToLink = [ "/lib" "/share/postgresql/extension" ];
+  postBuild = ''
+    # checks
+    (set -x
+       test "$(ls -A $out/lib/${pname}*${postgresql.dlSuffix} | wc -l)" = "${
+         toString (numberOfVersions + 1)
+       }"
+    )
   '';
 
-  meta = with lib; {
-    description = "Generate short unique IDs in PostgreSQL";
-    homepage = "https://github.com/iCyberon/pg_hashids";
-    platforms = postgresql.meta.platforms;
-    license = licenses.postgresql;
+  passthru = {
+    inherit versions numberOfVersions;
+    pname = "${pname}-all";
+    version = "multi-" + lib.concatStringsSep "-"
+      (map (v: lib.replaceStrings [ "." ] [ "-" ] v) versions);
   };
 }
diff --git a/nix/ext/versions.json b/nix/ext/versions.json
new file mode 100644
index 000000000..3caf64493
--- /dev/null
+++ b/nix/ext/versions.json
@@ -0,0 +1,20 @@
+{
+  "pg_hashids": {
+    "1.2.1": {
+      "postgresql": [
+        "15",
+        "17"
+      ],
+      "revision": "v1.2.1",
+      "hash": "sha256-2yQ0JrhwZF9dGEIydOviDpQ+3ZhJ8T16dQt6KIirAJ0="
+    },
+    "1.3.0-cd0e1b31d52b394a0df64079406a14a4f7387cd6": {
+      "postgresql": [
+        "15",
+        "17"
+      ],
+      "revision": "cd0e1b31d52b394a0df64079406a14a4f7387cd6",
+      "hash": "sha256-Nmb7XLqQflYZfqj0yrewfb1Hl5YgEB5wfjBunPwIuOU="
+    }
+  }
+}
diff --git a/nix/tests/pg_hashids.nix b/nix/tests/pg_hashids.nix
new file mode 100644
index 000000000..93e3a9410
--- /dev/null
+++ b/nix/tests/pg_hashids.nix
@@ -0,0 +1,147 @@
+{ self, pkgs }:
+let
+  pname = "pg_hashids";
+  inherit (pkgs) lib;
+  installedExtension = postgresMajorVersion:
+    self.packages.${pkgs.system}."psql_${postgresMajorVersion}/exts/${pname}-all";
+  versions = postgresqlMajorVersion: (installedExtension postgresqlMajorVersion).versions;
+  postgresqlWithExtension = postgresql:
+    let
+      majorVersion = lib.versions.major postgresql.version;
+      pkg = pkgs.buildEnv {
+        name = "postgresql-${majorVersion}-${pname}";
+        paths = [ postgresql postgresql.lib (installedExtension majorVersion) ];
+        passthru = {
+          inherit (postgresql) version psqlSchema;
+          lib = pkg;
+          withPackages = _: pkg;
+        };
+        nativeBuildInputs = [ pkgs.makeWrapper ];
+        pathsToLink = [ "/" "/bin" "/lib" ];
+        postBuild = ''
+          wrapProgram $out/bin/postgres --set NIX_PGLIBDIR $out/lib
+          wrapProgram $out/bin/pg_ctl --set NIX_PGLIBDIR $out/lib
+          wrapProgram $out/bin/pg_upgrade --set NIX_PGLIBDIR $out/lib
+        '';
+      };
+    in pkg;
+in self.inputs.nixpkgs.lib.nixos.runTest {
+  name = pname;
+  hostPkgs = pkgs;
+  nodes.server = { config, ... }: {
+    virtualisation = {
+      forwardPorts = [{
+        from = "host";
+        host.port = 13022;
+        guest.port = 22;
+      }];
+    };
+    services.openssh = { enable = true; };
+    users.users.root.openssh.authorizedKeys.keys = [
+      "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIIo+ulCUfJjnCVgfM4946Ih5Nm8DeZZiayYeABHGPEl7 jfroche"
+    ];
+
+    services.postgresql = {
+      enable = true;
+      package =
+        postgresqlWithExtension self.packages.${pkgs.system}.postgresql_15;
+    };
+
+    specialisation.postgresql17.configuration = {
+      services.postgresql = {
+        package = lib.mkForce
+          (postgresqlWithExtension self.packages.${pkgs.system}.postgresql_17);
+      };
+
+      systemd.services.postgresql-migrate = {
+        serviceConfig = {
+          Type = "oneshot";
+          RemainAfterExit = true;
+          User = "postgres";
+          Group = "postgres";
+          StateDirectory = "postgresql";
+          WorkingDirectory =
+            "${builtins.dirOf config.services.postgresql.dataDir}";
+        };
+        script = let
+          oldPostgresql =
+            postgresqlWithExtension self.packages.${pkgs.system}.postgresql_15;
+          newPostgresql =
+            postgresqlWithExtension self.packages.${pkgs.system}.postgresql_17;
+          oldDataDir = "${
+              builtins.dirOf config.services.postgresql.dataDir
+            }/${oldPostgresql.psqlSchema}";
+          newDataDir = "${
+              builtins.dirOf config.services.postgresql.dataDir
+            }/${newPostgresql.psqlSchema}";
+        in ''
+          if [[ ! -d ${newDataDir} ]]; then
+            install -d -m 0700 -o postgres -g postgres "${newDataDir}"
+            ${newPostgresql}/bin/initdb -D "${newDataDir}"
+            ${newPostgresql}/bin/pg_upgrade --old-datadir "${oldDataDir}" --new-datadir "${newDataDir}" \
+              --old-bindir "${oldPostgresql}/bin" --new-bindir "${newPostgresql}/bin"
+          else
+            echo "${newDataDir} already exists"
+          fi
+        '';
+      };
+
+      systemd.services.postgresql = {
+        after = [ "postgresql-migrate.service" ];
+        requires = [ "postgresql-migrate.service" ];
+      };
+    };
+
+  };
+  testScript = { nodes, ... }:
+    let
+      pg17-configuration =
+        "${nodes.server.system.build.toplevel}/specialisation/postgresql17";
+    in ''
+      versions = {
+        "15": [${lib.concatStringsSep ", " (map (s: ''"${s}"'') (versions "15"))}],
+        "17": [${lib.concatStringsSep ", " (map (s: ''"${s}"'') (versions "17"))}],
+      }
+
+      def run_sql(query):
+        return server.succeed(f"""sudo -u postgres psql -t -A -F\",\" -c \"{query}\" """).strip()
+
+      def check_upgrade_path(pg_version):
+        with subtest("Check ${pname} upgrade path"):
+          firstVersion = versions[pg_version][0]
+          server.succeed("sudo -u postgres psql -c 'DROP EXTENSION IF EXISTS ${pname};'")
+          run_sql(f"""CREATE EXTENSION ${pname} WITH VERSION '{firstVersion}';""")
+          installed_version = run_sql(r"""SELECT extversion FROM pg_extension WHERE extname = '${pname}';""")
+          assert installed_version == firstVersion, f"Expected ${pname} version {firstVersion}, but found {installed_version}"
+          for version in versions[pg_version][1:]:
+            run_sql(f"""ALTER EXTENSION ${pname} UPDATE TO '{version}';""")
+            installed_version = run_sql(r"""SELECT extversion FROM pg_extension WHERE extname = '${pname}';""")
+            assert installed_version == version, f"Expected ${pname} version {version}, but found {installed_version}"
+
+      start_all()
+
+      server.wait_for_unit("multi-user.target")
+      server.wait_for_unit("postgresql.service")
+
+      check_upgrade_path("15")
+
+      with subtest("Check ${pname} latest extension version"):
+        server.succeed("sudo -u postgres psql -c 'DROP EXTENSION ${pname};'")
+        server.succeed("sudo -u postgres psql -c 'CREATE EXTENSION ${pname};'")
+        installed_extensions=run_sql(r"""SELECT extname, extversion FROM pg_extension;""")
+        latestVersion = versions["15"][-1]
+        assert f"${pname},{latestVersion}" in installed_extensions
+
+      with subtest("switch to postgresql 17"):
+        server.succeed(
+          "${pg17-configuration}/bin/switch-to-configuration test >&2"
+        )
+
+      with subtest("Check ${pname} latest extension version"):
+        installed_extensions=run_sql(r"""SELECT extname, extversion FROM pg_extension;""")
+        latestVersion = versions["17"][-1]
+        assert f"${pname},{latestVersion}" in installed_extensions
+
+      check_upgrade_path("17")
+    '';
+}