nix: Add parameter for wlroots-version.

Add definition for [email protected] as it was dropped upstream.

Author: jsoo1

default.nix

@@ -1 +1,2 @@
-(import ./pin.nix).ocamlPackages.wlroots
+{ wlroots-version ? "0.12" }:
+(import ./pin.nix { inherit wlroots-version; }).ocamlPackages.wlroots

opam2nix-shell.nix

@@ -1 +1 @@
-let pkgs = import ./pin.nix; in { resolve = pkgs.opam2nix-resolve; }
+let pkgs = import ./pin.nix { }; in { resolve = pkgs.opam2nix-resolve; }

pin.nix

@@ -1,3 +1,4 @@
+{ wlroots-version ? "0.12" }:
 let
   nix-rev = "3ab8ce12c2db31268f579c11727d9c63cfee2eee"; # 2021-08-15
   nix-src = builtins.fetchTarball {
@@ -7,6 +8,9 @@ let
 in import nix-src {
   overlays = [
     (_: super: { ocamlPackages = super.ocaml-ng.ocamlPackages_4_08; })
+    (_: super: {
+      wlroots_0_13 = super.callPackage (import ./wlroots-13.nix) { };
+    })
     (self: super:
       let
         opam2nix = import (super.fetchFromGitHub {
@@ -51,7 +55,16 @@ in import nix-src {
                   pkgs.pixman
                   pkgs.wayland-protocols
                   pkgs.wayland
-                  pkgs.wlroots_0_12
+                  (if wlroots-version == "0.12" then
+                    pkgs.wlroots_0_12
+                  else if wlroots-version == "0.13" then
+                    pkgs.wlroots_0_13
+                  else if wlroots-version == "0.14" then
+                    pkgs.wlroots
+                  else
+                    throw ''
+                      wlroots-version must be one of 0.12, 0.13 or 0.14.  Got ${wlroots-version}
+                    '')
                 ];
               });
           };

shell.nix

@@ -1,5 +1,5 @@
 { wlroots-version ? "0.12" }:
-let pkgs = import ./pin.nix;
+let pkgs = import ./pin.nix { inherit wlroots-version; };
 in pkgs.mkShell {
   name = "wlroots-ocaml-shell";
   inputsFrom = [ pkgs.ocamlPackages.wlroots ];

wlroots-13.nix

@@ -0,0 +1,68 @@
+{ lib, stdenv, fetchFromGitHub, meson, ninja, pkg-config, wayland-scanner, libGL
+, wayland, wayland-protocols, libinput, libxkbcommon, pixman, xcbutilwm, libX11
+, libcap, xcbutilimage, xcbutilerrors, mesa, libpng, ffmpeg, libuuid
+, xcbutilrenderutil, xwayland }:
+
+stdenv.mkDerivation rec {
+  pname = "wlroots";
+  version = "0.13.0";
+
+  src = fetchFromGitHub {
+    owner = "swaywm";
+    repo = "wlroots";
+    rev = version;
+    sha256 = "01plhbnsp5yg18arz0v8fr0pr9l4w4pdzwkg9px486qdvb3s1vgy";
+  };
+
+  # $out for the library and $examples for the example programs (in examples):
+  outputs = [ "out" "examples" ];
+
+  nativeBuildInputs = [ meson ninja pkg-config wayland-scanner ];
+
+  buildInputs = [
+    libGL
+    wayland
+    wayland-protocols
+    libinput
+    libxkbcommon
+    pixman
+    xcbutilwm
+    libX11
+    libcap
+    xcbutilimage
+    xcbutilerrors
+    mesa
+    libpng
+    ffmpeg
+    libuuid
+    xcbutilrenderutil
+    xwayland
+  ];
+
+  mesonFlags = [ "-Dlogind-provider=systemd" "-Dlibseat=disabled" ];
+
+  postFixup = ''
+    # Install ALL example programs to $examples:
+    # screencopy dmabuf-capture input-inhibitor layer-shell idle-inhibit idle
+    # screenshot output-layout multi-pointer rotation tablet touch pointer
+    # simple
+    mkdir -p $examples/bin
+    cd ./examples
+    for binary in $(find . -executable -type f -printf '%P\n' | grep -vE '\.so'); do
+      cp "$binary" "$examples/bin/wlroots-$binary"
+    done
+  '';
+
+  meta = with lib; {
+    description = "A modular Wayland compositor library";
+    longDescription = ''
+      Pluggable, composable, unopinionated modules for building a Wayland
+      compositor; or about 50,000 lines of code you were going to write anyway.
+    '';
+    inherit (src.meta) homepage;
+    changelog = "https://github.com/swaywm/wlroots/releases/tag/${version}";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ ];
+  };
+}