build.gradle

plugins {
    id 'org.asciidoctor.convert' version '2.2.0'
    id 'org.ajoberstar.git-publish' version '2.0.0'
}

wrapper {
    gradleVersion = '5.0'
}

def buildDate() {
    return new Date().format('yyyy-MM-dd')
}

asciidoctorj {
    version = "$asciidoctorjVersion"
}

asciidoctor {
    sourceDir = file('docs')
    outputDir = file('build/docs')
    attributes = ['revdate'           : "${buildDate()}",
                  'project-version'   : "$version",
                  'gh-repo-owner'     : "$githubRepositoryOwner",
                  'gh-repo-name'      : "$githubRepositoryName",
                  'source-highlighter': 'coderay',
                  'imagesdir'         : '',
                  'toc'               : 'left',
                  'icons'             : 'font',
                  'sectanchors'       : 'true',
                  'idprefix'          : '',
                  'idseparator'       : '-',
                  'docinfo1'          : 'true']

    repositories {
        mavenCentral()
    }
    dependencies {
        asciidoctor "fr.jmini.asciidoctorj:git-link:3.2.1"
    }
}

gitPublish {
    repoUri = 'git@github.com:' + "$githubRepositoryOwner" + '/' + "$githubRepositoryName" + '.git'
    branch = 'gh-pages'

    contents {
        from "${file('build/docs/html5')}"
    }

    preserve {
        include '.nojekyll'
    }

    commitMessage = "Update the 'gh-pages' branch."
}

task releaseBuild {
    dependsOn(
            'asciidoctor',
            'gitPublishPush'
    )
}