sci-visualization/veusz: bump to 3.2

Closes: https://bugs.gentoo.org/show_bug.cgi?id=712920
Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Andrey Grozin <[email protected]>

Author: Andrey Grozin

sci-visualization/veusz/Manifest

@@ -1 +1,2 @@
 DIST veusz-3.1.tar.gz 2524607 BLAKE2B ca5c5a75e02c9461e1d81dc4d2cc09865ebd4424f072616bf0a231a1f592a5c1c5aad93f713ed9ec1d9e2ad39b877a36c236b615d904295608d7990eaf59d5fb SHA512 9b940d1cc224f4729f788abe1e29352d35e69d2f78bae7f072a783d339198a8171b0f0b0a5f5af82ef0f0693550a42409956a9cc3888aa46d110d777e81941a4
+DIST veusz-3.2.tar.gz 2528125 BLAKE2B 614488779d1c0e5d800f2b1c86b82615676b08af46831abd6c55653471b045f0c9d28a8cb7489cbb2391fd5f21ab2d40aa6bff4fc195426f3b07b91f6d4ee8d7 SHA512 01e1a030246a3d6811493968f2f30084b2c465195af166b7bdc4009de4c488350a4fba300acee1959310b318e8dc519f090bfca528491811ca52640c33d048bc

sci-visualization/veusz/veusz-3.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit desktop distutils-r1 virtualx xdg
+
+DESCRIPTION="Qt scientific plotting package with good Postscript output"
+HOMEPAGE="https://veusz.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="dbus doc hdf5 minuit"
+RESTRICT="!test? ( test )"
+
+CDEPEND="dev-python/PyQt5[widgets,svg,printsupport,${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]"
+RDEPEND="${CDEPEND}
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	hdf5? ( dev-python/h5py[${PYTHON_USEDEP}] )
+	minuit? ( dev-python/iminuit[${PYTHON_USEDEP}] )"
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/sip[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+src_prepare() {
+	distutils-r1_src_prepare
+	xdg_environment_reset
+}
+
+python_test() {
+	distutils_install_for_testing
+	VIRTUALX_COMMAND="${EPYTHON}" \
+		VEUSZ_RESOURCE_DIR="${S}" \
+		virtx tests/runselftest.py
+}
+
+python_install() {
+	distutils-r1_python_install
+	# symlink the license, bug #341653
+	rm "${D}/$(python_get_sitedir)"/${PN}/{COPYING,AUTHORS,ChangeLog} || die
+	mkdir -p "${D}/$(python_get_sitedir)" || die
+	cat >> "${D}/$(python_get_sitedir)"/${PN}/COPYING <<- EOF
+	Please visit
+
+	https://www.gnu.org/licenses/gpl-2.0.html
+
+	for the full license text.
+	EOF
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		dodoc Documents/manual/pdf/${PN}.pdf
+		docinto html
+		dodoc -r Documents/manual/html
+	fi
+
+	doicon icons/veusz.png
+	domenu "${FILESDIR}"/veusz.desktop
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}"/veusz.xml
+}