Initial commit.

.gitignore

@@ -1,3 +1,6 @@
+# Created by https://www.gitignore.io/api/java,intellij,gradle
+
+### Java ###
 *.class
 
 # Mobile Tools for Java (J2ME)
@@ -10,3 +13,65 @@
 
 # virtual machine crash logs, see http://www.java.com/en/download/help/error_hotspot.xml
 hs_err_pid*
+
+
+### Intellij ###
+# Covers JetBrains IDEs: IntelliJ, RubyMine, PhpStorm, AppCode, PyCharm, CLion, Android Studio
+
+*.iml
+
+## Directory-based project format:
+.idea/
+# if you remove the above rule, at least ignore the following:
+
+# User-specific stuff:
+# .idea/workspace.xml
+# .idea/tasks.xml
+# .idea/dictionaries
+
+# Sensitive or high-churn files:
+# .idea/dataSources.ids
+# .idea/dataSources.xml
+# .idea/sqlDataSources.xml
+# .idea/dynamic.xml
+# .idea/uiDesigner.xml
+
+# Gradle:
+# .idea/gradle.xml
+# .idea/libraries
+
+# Mongo Explorer plugin:
+# .idea/mongoSettings.xml
+
+## File-based project format:
+*.ipr
+*.iws
+
+## Plugin-specific files:
+
+# IntelliJ
+/out/
+
+# mpeltonen/sbt-idea plugin
+.idea_modules/
+
+# JIRA plugin
+atlassian-ide-plugin.xml
+
+# Crashlytics plugin (for Android Studio and IntelliJ)
+com_crashlytics_export_strings.xml
+crashlytics.properties
+crashlytics-build.properties
+
+
+### Gradle ###
+.gradle
+build/
+
+# Ignore Gradle GUI config
+gradle-app.setting
+
+# Avoid ignoring Gradle wrapper jar file (.jar files are usually ignored)
+!gradle-wrapper.jar
+
+bintrayUpload.bat

build.gradle

@@ -0,0 +1,194 @@
+buildscript {
+    repositories {
+        jcenter()
+        mavenCentral()
+        maven {
+            url "https://plugins.gradle.org/m2/"
+        }
+
+    }
+    dependencies {
+        classpath 'com.gradle.publish:plugin-publish-plugin:0.9.1'
+        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.4.0'
+        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.2'
+        classpath 'nl.javadude.gradle.plugins:license-gradle-plugin:0.11.0'
+    }
+}
+
+
+plugins {
+    id "org.sonarqube" version "1.2"
+}
+
+apply plugin: 'org.sonarqube'
+
+
+allprojects {
+
+    apply plugin: 'jacoco'
+    apply plugin: 'com.github.kt3k.coveralls'
+    //Some plugins
+    apply plugin: 'base'
+    apply plugin: 'groovy'
+    apply plugin: 'java'
+    apply plugin: 'maven-publish'
+    apply plugin: 'com.gradle.plugin-publish'
+    apply plugin: 'com.jfrog.bintray'
+    apply plugin: 'com.github.hierynomus.license'
+
+    version '0.1'
+
+    group 'de.qaware.chronix'
+
+    repositories {
+        jcenter()
+        mavenCentral()
+        maven {
+            url "http://dl.bintray.com/chronix/maven"
+        }
+    }
+
+    jacoco {
+        toolVersion = '0.7.2.201409121644'
+    }
+
+    license {
+        includes(["**/*.java", "**/*.groovy", "*.gradle"])
+        mapping {
+            java = 'SLASHSTAR_STYLE'
+            groovy = 'SLASHSTAR_STYLE'
+        }
+    }
+
+
+    sonarqube {
+        properties {
+            property "sonar.sourceEncoding", "UTF-8"
+        }
+    }
+
+    sourceCompatibility = JavaVersion.VERSION_1_8
+    targetCompatibility = JavaVersion.VERSION_1_8
+
+    dependencies {
+        //Guava
+        compile 'com.google.guava:guava:18.0'
+        //Groovy for the win
+        compile 'org.codehaus.groovy:groovy-all:2.4.5'
+        compile 'org.apache.commons:commons-lang3:3.4'
+
+        //Logging
+        compile 'org.slf4j:slf4j-api:1.7.12'
+
+        //Logging framework for tests
+        testCompile 'org.apache.logging.log4j:log4j-api:2.4'
+        testCompile 'org.apache.logging.log4j:log4j-core:2.4'
+        testCompile 'org.apache.logging.log4j:log4j-slf4j-impl:2.4'
+
+        //Testing
+        testCompile 'junit:junit:4.12'
+        testCompile 'org.spockframework:spock-core:0.7-groovy-2.0'
+        testCompile 'cglib:cglib-nodep:3.1'
+
+    }
+
+    test {
+        reports {
+            junitXml.enabled = false
+            html.enabled = true
+        }
+    }
+
+    // This disables the pedantic doclint feature of JDK8
+    if (JavaVersion.current().isJava8Compatible()) {
+        tasks.withType(Javadoc) {
+            options.addStringOption('Xdoclint:none', '-quiet')
+        }
+    }
+
+    task sourcesJar(type: Jar, dependsOn: classes) {
+        classifier = 'sources'
+        from sourceSets.main.allSource
+    }
+
+    jacocoTestReport {
+        group = 'Coverage'
+        description = 'Generate Jacoco coverage report for subproject'
+
+        additionalSourceDirs = project.files(sourceSets.main.allSource.srcDirs)
+        sourceDirectories = project.files(sourceSets.main.allSource.srcDirs)
+        classDirectories = project.files(sourceSets.main.output)
+
+        reports {
+            xml.enabled = true
+            html.enabled = true
+        }
+
+        afterEvaluate {
+            classDirectories = files(classDirectories.files.collect {
+                fileTree(dir: it, exclude: ['de/qaware/chronix/converter/serializer/gen/**'])
+            })
+        }
+    }
+}
+
+task jacocoRootReport(type: JacocoReport, group: 'Coverage') {
+    description = 'Generates aggregate Jacoco coverage report from all subprojects'
+    dependsOn(subprojects.test)
+
+    additionalSourceDirs = files(subprojects.sourceSets.main.allSource.srcDirs)
+    sourceDirectories = files(subprojects.sourceSets.main.allSource.srcDirs)
+    classDirectories = files(subprojects.sourceSets.main.output)
+    executionData = files(subprojects.jacocoTestReport.executionData)
+
+    reports {
+        html.enabled = true
+        xml.enabled = true
+    }
+
+    doFirst {
+        executionData = files(executionData.findAll { it.exists() })
+    }
+}
+
+coveralls {
+    sourceDirs = subprojects.sourceSets.main.allSource.srcDirs.flatten()
+    jacocoReportPath = "${buildDir}/reports/jacoco/jacocoRootReport/jacocoRootReport.xml"
+}
+
+def isCI = System.env.'CI' == 'true'
+tasks.coveralls {
+    group = 'Coverage'
+    description = 'Upload aggregate Jacoco coverage report to Coveralls'
+
+    dependsOn jacocoRootReport
+    onlyIf { isCI }
+}
+
+task wrapper(type: Wrapper) {
+    gradleVersion = '2.10'
+}
+
+
+sonarqube {
+    def sonarUser = project.hasProperty('sonarUser') ? project.sonarUser : 'unknown'
+    def sonarPw = project.hasProperty('sonarPw') ? project.sonarPw : 'unknown'
+
+    def jdbcUser = project.hasProperty('jdbcUser') ? project.jdbcUser : 'unknown'
+    def jdbcPw = project.hasProperty('jdbcPw') ? project.jdbcPw : 'unknown'
+
+    properties {
+        property "sonar.sourceEncoding", "UTF-8"
+        property "sonar.host.url", "https://www.qaware.de/sonar"
+        property "sonar.login", "$sonarUser"
+        property "sonar.password", "$sonarPw"
+        property "sonar.jdbc.url", "jdbc:mysql://nio-prj-2.intern.qaware.de:3306/sonardb?useUnicode=true&characterEncoding=utf8"
+        property "sonar.jdbc.driverClassName", "com.mysql.jdbc.Driver"
+        property "sonar.jdbc.username", "$jdbcUser"
+        property "sonar.jdbc.password", "$jdbcPw"
+        property "sonar.projectName", "Chronix-Kassiopeia"
+        property "sonar.projectKey", "de.qaware.chronix:chronix.kassiopeia"
+        property "sonar.projectVersion", "$project.version"
+        property "sonar.exclusions", "src/main/generated/de/qaware/chronix/converter/serializer/gen/*"
+    }
+}

gradle/wrapper/gradle-wrapper.properties

@@ -0,0 +1,6 @@
+#Thu Feb 18 13:56:30 CET 2016
+distributionBase=GRADLE_USER_HOME
+distributionPath=wrapper/dists
+zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-2.10-bin.zip