first commit

dev/main.tf

@@ -0,0 +1,3 @@
+module "dev" {
+    source = "../modules/blog"
+}

modules/blog/main.tf

@@ -0,0 +1,101 @@
+data "aws_ami" "app_ami" {
+  most_recent = true
+
+  filter {
+    name   = "name"
+    values = [var.ami_filter.name]
+  }
+
+  filter {
+    name   = "virtualization-type"
+    values = ["hvm"]
+  }
+
+  owners = [var.ami_filter.owner]
+}
+
+
+
+module "blog_vpc" {
+  source = "terraform-aws-modules/vpc/aws"
+
+  name = var.environment.name
+  cidr = "${var.environment.network_prefix}.0.0/16"
+
+  azs             = ["us-west-2a", "us-west-2b", "us-west-2c"]
+  public_subnets  = ["${var.environment.network_prefix}.101.0/24", "${var.environment.network_prefix}.102.0/24", "${var.environment.network_prefix}.103.0/24"]
+
+  tags = {
+    Terraform = "true"
+    Environment = var.environment.name
+  }
+}
+
+module "blog_asg" {
+  source  = "terraform-aws-modules/autoscaling/aws"
+
+  # Autoscaling group
+  name = "${var.environment.name}-blog"
+
+  min_size                  = var.asg_min_size
+  max_size                  = var.asg_max_size
+  vpc_zone_identifier       = module.blog_vpc.public_subnets
+  target_group_arns         = [module.blog_alb.target_groups["ex-instance"].arn]
+  security_groups           = [module.blog_sg.security_group_id]
+
+
+  image_id          = data.aws_ami.app_ami.id
+  instance_type     = var.instance_type
+
+}
+
+module "blog_alb" {
+  source  = "terraform-aws-modules/alb/aws"
+  version = "9.10.0"
+
+  name    = "blog-alb"
+  vpc_id  = module.blog_vpc.vpc_id
+  subnets = module.blog_vpc.public_subnets
+  security_groups = [module.blog_sg.security_group_id]
+
+
+  listeners = {
+    ex-http-https-redirect = {
+      port     = 80
+      protocol = "HTTP"
+      redirect = {
+        port        = "443"
+        protocol    = "HTTPS"
+        status_code = "HTTP_301"
+      }
+    }
+  }
+
+  target_groups = {
+    ex-instance = {
+      name_prefix      = "${var.environment.name}-"
+      protocol         = "HTTP"
+      port             = 80
+      target_type      = "instance"
+      create_attachment = false
+    }
+  }
+
+  tags = {
+    Environment = var.environment.name
+  }
+}
+
+module "blog_sg" {
+  source  = "terraform-aws-modules/security-group/aws"
+  version = "5.1.2"
+
+  name = "${var.environment.name}-blog"
+  vpc_id = module.blog_vpc.vpc_id
+
+  ingress_rules      = ["http-80-tcp", "https-443-tcp"]
+  ingress_cidr_blocks = ["0.0.0.0/0"]
+
+  egress_rules      = ["all-all"]
+  egress_cidr_blocks = ["0.0.0.0/0"]
+}

modules/blog/outputs.tf

@@ -0,0 +1,3 @@
+output "environment_url" {
+  value = module.blog_alb.dns_name
+}

modules/blog/variables.tf

@@ -0,0 +1,44 @@
+variable "instance_type" {
+  description = "Type of EC2 instance to provision"
+  default     = "t3.nano"
+}
+
+variable "ami_filter" {
+    description = "Name filter and owner of AMI"
+
+    type = object({
+      name  = string
+      owner = string
+    })
+
+    default = {
+      name = "bitnami-tomcat-*-x86_64-hvm-ebs-nami"
+      owner = "979382823631" # Bitnami
+    }
+
+}
+
+variable "environment" {
+    description = "Development environment"
+
+    type = object({
+      name           = string
+      network_prefix = string
+    })
+
+  default = {
+    name           = "dev"
+    network_prefix = "10.0"
+  }
+}
+
+
+variable "asg_min_size" {
+  description = "Minimum number of instances in ASG"
+  default     = 1
+}
+
+variable "asg_max_size" {
+  description = "Maximum number of instances in ASG"
+  default     = 2
+}

qa/main.tf

@@ -0,0 +1,12 @@
+module "qa" {
+    source = "../modules/blog"
+
+    environment = {
+        name          = "qa"
+        network_prefix = "10.1"
+    }
+
+    asg_min_size = 1
+    asg_max_size = 1
+
+}

qa/outputs.tf

@@ -0,0 +1,3 @@
+output "environment_url" {
+  value = module.qa.environment_url
+}

qa/providers.tf

@@ -0,0 +1,11 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+    }
+  }
+}
+
+provider "aws" {
+  region  = "us-west-2"
+}