WIP: NOT READY FOR REVIEW Slicer 2025 06 13 a2687828

.github/workflows/cmake.yml

@@ -0,0 +1,71 @@
+name: CMake CI
+
+on:
+  push:
+    branches:
+      - master
+
+jobs:
+  build-and-test:
+    runs-on: ${{ matrix.os }}
+    strategy:
+      matrix:
+        os: [ubuntu-latest, windows-latest]
+        qt_version: [5, 6]
+        python_version: ["3.8", "3.9", "3.10"]
+      fail-fast: false
+
+    steps:
+      - name: Checkout code
+        uses: actions/checkout@v3
+
+      - name: Set up Python
+        uses: actions/setup-python@v4
+        with:
+          python-version: ${{ matrix.python_version }}
+
+      - name: Install dependencies (Linux)
+        if: runner.os == 'Linux'
+        run: |
+          sudo apt-get update
+          if [ "${{ matrix.qt_version }}" = "5" ]; then
+            sudo apt-get install -y qtbase5-dev qtbase5-private-dev qtchooser qt5-qmake qtbase5-dev-tools \
+            libqt5svg5-dev qttools5-dev libqt5xmlpatterns5-dev qtmultimedia5-dev qtdeclarative5-dev \
+            qtwebengine5-dev libqt5webkit5-dev
+            echo "QTDIR=/usr/lib/x86_64-linux-gnu/qt5" | tee -a $GITHUB_ENV
+          else
+            sudo apt-get install -y qt6-base-dev qt6-base-private-dev qt6-5compat-dev qt6-base-dev-tools \
+            libqt6svg6-dev qt6-multimedia-dev qt6-declarative-dev qt6-webengine-dev
+            echo "QTDIR=/usr/lib/x86_64-linux-gnu/qt6" | tee -a $GITHUB_ENV
+          fi
+
+      - name: Install dependencies (Windows)
+        if: runner.os == 'Windows'
+        run: |
+          if ("${{ matrix.qt_version }}" -eq "5") {
+            pip install aqtinstall
+            aqt install-qt windows desktop 5.15.2 win64_msvc2019 -m all
+            $Qt5Dir = "$env:USERPROFILE\Qt\5.15.2\msvc2019_64"
+            echo "Qt5Dir=$Qt5Dir" | Out-File -FilePath $env:GITHUB_ENV -Encoding utf8 -Append
+            echo "$Qt5Dir\bin" | Out-File -FilePath $env:GITHUB_PATH -Encoding utf8 -Append
+            echo "QTDIR=$Qt5Dir" | Out-File -FilePath $env:GITHUB_ENV -Encoding utf8 -Append
+          } else {
+            choco install -y qt6-base-dev qt6-base-private-dev qt6-5compat-dev qt6-base-dev-tools `
+            libqt6svg6-dev qt6-multimedia-dev qt6-declarative-dev qt6-webengine-dev `
+            --params "/InstallationFolder C:/Qt/${{ matrix.qt_version }}"
+            echo "C:/Qt/${{ matrix.qt_version }}/bin" | Out-File -FilePath $env:GITHUB_PATH -Encoding utf8 -Append
+            echo "QTDIR=C:/Qt/${{ matrix.qt_version }}" | Out-File -FilePath $env:GITHUB_ENV -Encoding utf8 -Append
+          }
+
+      - name: Configure CMake
+        run: |
+          cmake -S . -B build -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=./install
+
+      - name: Build project
+        run: |
+          cmake --build build --parallel --target all install
+
+      - name: Run tests
+        run: |
+          cd build
+          ctest --output-on-failure

CMakeLists.txt

@@ -0,0 +1,87 @@
+cmake_minimum_required(VERSION 3.27)
+
+project(PythonQt LANGUAGES CXX VERSION 3.5.6)
+
+#-----------------------------------------------------------------------------
+# Set a default build type if none was specified
+if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
+  message(STATUS "Setting build type to 'Release' as none was specified.")
+  set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
+  mark_as_advanced(CMAKE_BUILD_TYPE)
+  # Set the possible values of build type for cmake-gui
+  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "RelWithDebInfo")
+endif()
+#-----------------------------------------------------------------------------
+
+enable_testing()
+
+set(CMAKE_CXX_STANDARD 11)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+# Force errors for dangerous operations
+add_compile_definitions( -DQT_NO_CAST_TO_ASCII )
+
+option(PythonQt_NO_IMPLICIT_CASTING "Disable implicit casts related to dangerous implicit conversions" OFF)
+if(PythonQt_NO_IMPLICIT_CASTING) # Definitions to force
+  # errors on dangerous implicit operations
+  # to be addressed at a later time
+add_compile_definitions( -DQT_NO_CAST_FROM_ASCII
+                         -DQT_NO_CAST_FROM_ASCII
+                         -DQT_NO_CAST_TO_BYTEARRAY
+                         -DQT_NO_CAST_FROM_BYTEARRAY
+                         -DQT_NO_CAST_TO_QSTRING
+                         -DQT_NO_CAST_FROM_QSTRING
+                         -DQT_NO_CAST_TO_QSTRINGREF
+                         -DQT_NO_CAST_FROM_QSTRINGREF
+                         -DQT_NO_CAST_TO_QVARIANT
+                         -DQT_NO_CAST_FROM_QVARIANT )
+endif()
+
+option(FORCE_BUILD_QT5 "Force Qt5 build instead of Qt6" OFF)
+
+if(FORCE_BUILD_QT5)
+  find_package(Qt5 NAMES Qt5 REQUIRED COMPONENTS Core Widgets Xml)
+  string(REPLACE "." ";" qt_version_list ${Qt5_VERSION})
+else()
+  find_package(Qt6 NAMES Qt6 REQUIRED COMPONENTS Core Widgets Xml Core5Compat)
+  string(REPLACE "." ";" qt_version_list ${Qt6_VERSION})
+endif()
+list(GET qt_version_list 0 QT_VERSION_MAJOR)
+list(GET qt_version_list 1 QT_VERSION_MINOR)
+list(GET qt_version_list 1 QT_VERSION_PATCH)
+message(STATUS "QT_VERSION_MAJOR = ${QT_VERSION_MAJOR}")
+
+find_package(Python3 COMPONENTS Development REQUIRED)
+
+# Set the environment as defined in Readme.md
+# Set environment variables for Python
+if(Python3_FOUND)
+  set(PYTHON_VERSION "${Python3_VERSION_MAJOR}.${Python3_VERSION_MINOR}")
+  set(PYTHON_PATH "${Python3_PREFIX}")
+  set(PYTHON_LIB "${Python3_PREFIX}/libs")
+  set(PYTHON_DIR "${Python3_PREFIX}")
+  set(ENV{PYTHON_VERSION} "${PYTHON_VERSION}")
+  set(ENV{PYTHON_PATH} "${PYTHON_PATH}")
+  set(ENV{PYTHON_LIB} "${PYTHON_LIB}")
+  set(ENV{PYTHON_DIR} "${PYTHON_DIR}")
+endif()
+
+# Set QTDIR environment variable to Qt installation root
+if(FORCE_BUILD_QT5)
+  if(DEFINED Qt5_DIR)
+    set(ENV{QTDIR} "${Qt5_DIR}")
+  endif()
+else()
+  if(DEFINED Qt6_DIR)
+    set(ENV{QTDIR} "${Qt6_DIR}")
+  endif()
+endif()
+
+
+set(PYTHONQT_SUFFIX Qt${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}-Python${Python3_VERSION_MAJOR}.${Python3_VERSION_MINOR})
+include_directories(src)
+add_subdirectory(generator)
+add_subdirectory(src)
+add_subdirectory(extensions)
+add_subdirectory(tests)
+# add_subdirectory(examples)

README.md

@@ -36,20 +36,22 @@ need to build and run the generator when you want to build additional wrappers
 or you want to upgrade/downgrade to another Qt version, but this requires
 updating the typesystems as well.
 
-# Building
+# Building 
 
-## General
+## Using qmake and manual steps
+
+### General
 
 Building PythonQt requires a couple of steps.
 Follow these instructions in order to get a correctly built PythonQt runtime and Qt bindings.
 
-### Recommendations
+#### Recommendations
 
 It is recommended to build the Qt bindings yourself instead of using the pregenerated ones.
 This ensures the bindings are compatible with your Qt version.
 Do not build `PythonQt.pro` directly because it will only use the pregenerated bindings!
 
-### Environment
+#### Environment
 
 First, you need to set a couple of environment variables, which depend on your Python and Qt installation.
 
@@ -74,7 +76,7 @@ First, you need to set a couple of environment variables, which depend on your P
 
   The absolute path to the root directory of your Qt installation.
 
-### Binding Generator
+#### Binding Generator
 
 1. cd into the `generator` directory
 2. Run qmake on `generator.pro`
@@ -93,7 +95,7 @@ First, you need to set a couple of environment variables, which depend on your P
 
    `<generator-executable> qtscript_masterinclude.h build_all.txt`
 
-### PythonQt Runtime
+#### PythonQt Runtime
 
 Next, we need the PythonQt runtime.
 
@@ -106,7 +108,7 @@ Next, we need the PythonQt runtime.
 
    Use `nmake` for MSVC (Visual Studio; make sure to have the environment variables set for Visual Studio beforehand). Otherwise, use `make`.
 
-### Extensions
+#### Extensions
 
 As a last step, we need to build the extensions.
 
@@ -121,6 +123,60 @@ As a last step, we need to build the extensions.
 
 After all these steps, you should now have a fully working PythonQt runtime and Qt bindings for your Python/Qt installation 🎉.
 
+
+## The CMake Build System replaces the qmake manual proceedure defined above
+
+Get the source code from the GitHub.
+```bash
+git clone [email protected]:MeVisLab/PythonQt.git
+cd PythonQt
+git checkout <desired_branch>
+```
+
+Build the PythonQt runtime and Qt bindings using CMake.
+```bash
+cmake -S $(pwd) -B ../PythonQt-build -GNinja -DCMAKE_EXPORT_COMPILE_COMMANDS:BOOL=ON -DCMAKE_BUILD_TYPE:STRING=Release
+cmake --build ../PythonQt-build --config Release
+```
+
+
+# Platform Notes
 ## MinGW
 
 It is possible to build PythonQt with MinGW on Windows instead of using MSVC.
+
+## Ubuntu 24.04 apt-get install QT6
+It is possible to build PythonQt on Ubuntu 24.04 using the `apt` package manager to install the required Qt6 packages.
+``` bash
+apt install qt6-base-dev qt6-tools-dev-tools libqt6* qt6-* qml6-module-qt*
+```
+
+## arm64 based MacOS
+It is possible to build PythonQt on arm64 based MacOS systems.
+
+Download and install qt6 from https://www.qt.io/download.  Install the desired Qt6.
+
+# Hints for developers
+
+## Upgrading Qt Versions
+
+### Use `clazy` for static analysis of Qt code
+```bash
+# NOTE: clazy uses the cmake output file generated when CMAKE_EXPORT_COMPILE_COMMANDS=ON
+export CLAZY_TEST="use-static-qregularexpression"
+
+clazy-standalone -p ../PythonQt-build \
+  --checks="${CLAZY_TEST}" \
+  --only-qt  \
+  $(find . -name "*.cpp" |fgrep -v "/examples/") \
+   2>&1 \
+  | fgrep -v "pragma-messages" \
+  | tee ../logger.${CLAZY_TEST}
+vim -q ../logger.${CLAZY_TEST}
+```
+
+
+# List clazy tests available
+```bash
+clazy-standalone -p ../PythonQt-build   --only-qt  generator/main.cpp     --list-checks >> ../MIGRATE_QT5_to_QT6
+```

examples/PyLauncher/main.cpp

@@ -78,7 +78,7 @@ int main( int argc, char **argv )
   }
   PythonQtScriptingConsole console(NULL, mainContext);
 
-  Q_FOREACH(QString file, files) {
+  for( QString file :  files ) {
     mainContext.evalFile(file);
   }
   if (showConsole || console.hadError()) {

extensions/CMakeLists.txt

@@ -0,0 +1 @@
+add_subdirectory(PythonQt_QtAll)

extensions/PythonQt_QtAll/CMakeLists.txt

@@ -0,0 +1,94 @@
+project(QtAll LANGUAGES CXX)
+
+set(CMAKE_AUTOMOC ON)
+
+file(GLOB SOURCES *.h *.cpp)
+
+if(BUILD_SHARED_LIBS)
+    add_library(${PROJECT_NAME} SHARED)
+    target_compile_definitions(${PROJECT_NAME} PRIVATE PYTHONQT_QTALL_EXPORTS)
+else()
+    add_library(${PROJECT_NAME} STATIC)
+    target_compile_definitions(${PROJECT_NAME} PUBLIC PYTHONQT_QTALL_STATIC)
+endif()
+
+target_sources(${PROJECT_NAME} PRIVATE ${SOURCES})
+
+target_link_libraries(${PROJECT_NAME} PUBLIC Core)
+
+target_include_directories(${PROJECT_NAME} PUBLIC ${CMAKE_CURRENT_LIST_DIR})
+
+list(APPEND QTMODULES Core Gui Svg Sql Network OpenGL Xml Multimedia Qml Quick UiTools WebEngineWidgets)
+if(${QT_VERSION_MAJOR} EQUAL 5) #QT5
+        list(APPEND QTMODULES XmlPatterns WebKit)
+endif()
+find_package(Qt${QT_VERSION_MAJOR} COMPONENTS ${QTMODULES})
+
+foreach(QtModule IN LISTS QTMODULES)
+    if(NOT TARGET "Qt${QT_VERSION_MAJOR}::${QtModule}")
+        continue()
+    endif()
+
+    string(TOUPPER ${QtModule} QTMODULE)
+    target_sources(${PROJECT_NAME} PRIVATE ${PYTHONQT_WRAPPER_${QTMODULE}_SOURCES})
+    target_link_libraries(${PROJECT_NAME} PUBLIC Qt${QT_VERSION_MAJOR}::${QtModule})
+    target_compile_definitions(${PROJECT_NAME} PRIVATE PYTHONQT_WITH_${QTMODULE})
+endforeach()
+
+if(TARGET "Qt${QT_VERSION_MAJOR}::Gui")
+    find_package(Qt${QT_VERSION_MAJOR} COMPONENTS Widgets PrintSupport REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC
+        Qt${QT_VERSION_MAJOR}::Widgets
+        Qt${QT_VERSION_MAJOR}::PrintSupport
+    )
+endif()
+
+if(TARGET "Qt${QT_VERSION_MAJOR}::Svg" AND QT_VERSION_MAJOR VERSION_GREATER_EQUAL 6)
+    find_package(Qt${QT_VERSION_MAJOR} COMPONENTS SvgWidgets REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC
+        Qt${QT_VERSION_MAJOR}::SvgWidgets
+    )
+endif()
+
+if(TARGET "Qt${QT_VERSION_MAJOR}::Multimedia")
+    find_package(Qt${QT_VERSION_MAJOR} COMPONENTS MultimediaWidgets REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC
+        Qt${QT_VERSION_MAJOR}::MultimediaWidgets
+    )
+endif()
+
+if(TARGET "Qt${QT_VERSION_MAJOR}::Quick")
+    find_package(Qt${QT_VERSION_MAJOR} COMPONENTS QuickWidgets REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC
+        Qt${QT_VERSION_MAJOR}::QuickWidgets
+    )
+endif()
+
+if(TARGET "Qt${QT_VERSION_MAJOR}::WebKit")
+    find_package(Qt${QT_VERSION_MAJOR} COMPONENTS WebKitWidgets REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC
+        Qt${QT_VERSION_MAJOR}::WebKitWidgets
+    )
+endif()
+
+file(GLOB PUBLIC_HEADER *.h)
+
+set_target_properties(${PROJECT_NAME} PROPERTIES
+    OUTPUT_NAME PythonQt-QtAll-${PYTHONQT_SUFFIX}
+    PUBLIC_HEADER "${PUBLIC_HEADER}"
+)
+
+if(MSVC)
+    target_compile_options(${PROJECT_NAME} PRIVATE "/bigobj")
+elseif(MINGW)
+    target_compile_options(${PROJECT_NAME} PRIVATE "-Wa,-mbig-obj")
+endif()
+
+include(GNUInstallDirs)
+install(TARGETS ${PROJECT_NAME}
+    BUNDLE DESTINATION .
+    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+)